SMTP_QuickSend

4D v19

SMTP_QuickSend


SMTP_QuickSend ( nomServeur ; msgDe ; msgA ; msgObjet ; message {; paramSession}{; port}{; nomUtilisateur ; motDePasse} ) -> Résultat

Paramètre	Type	Description
nomServeur	Chaîne	Nom ou adresse IP du serveur
msgDe	Texte	Adresse électronique ou Liste d'adresses
msgA	Texte	Adresse électronique ou Liste d'adresses
msgObjet	Texte	Objet du message (UTF-8 par défaut)
message	Texte	Message (UTF-8 par défaut)
paramSession	Entier long	0 ou omis = Ne pas utiliser SSL mais bascule permise, 1 = Utiliser SSL, 2 = Ne jamais utiliser SSL (bascule non permise), 4 = Envoyer texte HTML sans SSL, 5 = Envoyer texte HTML avec SSL, 8 = Envoyer Mime HTML sans SSL/TLS, 9 = Envoyer Mime HTML avec SSL/TLS
port	Entier long	Numéro de port à utiliser
nomUtilisateur	Texte	Nom d’utilisateur pour l’authentification
motDePasse	Texte	Mot de passe pour l’authentification
Résultat	Entier	Code d'erreur

Description

La commande SMTP_QuickSend vous permet de créer et d'envoyer un message en une seule commande. Si vous avez besoin d'un plus grand contrôle sur votre message, ou s'il est plus complexe, utilisez plutôt la commande SMTP_New.

Note : Cette commande ne peut être utilisée dans les bases de données converties fonctionnant en mode "non-unicode".

Le paramètre nomServeur contient le nom ou l'adresse IP du serveur SMTP auquel le message sera envoyé pour distribution.

Le paramètre msgDe contient une ou plusieurs adresses électroniques complètes indiquant l'expéditeur initial du message. Toutes les adresses figurant dans l'en-tête Emetteur (From) sont visibles par tous les destinataires du message.

Le paramètre msgA contient une ou plusieurs adresses électroniques complètes. Les adresses figurant dans l'en-tête msgA recevront chacune une copie originale du message. Chaque destinataire du message pourra visualiser les autres adresses électroniques auxquelles le message a été envoyé.

Le paramètre objet contient un texte concis décrivant l'objet du message. Le paramètre message contient le corps du message électronique.

Note : Par défaut, l'objet et le corps du message sont encodés en UTF-8, ce qui garantit que les caractères envoyés seront correctement interprétés par la quasi totalité des clients de messagerie. Si vous souhaitez utiliser un jeu de caractères spécifique, reportez-vous aux commandes SMTP_SetPrefs et SMTP_Charset.

Le paramètre optionnel paramSession vous permet de définir le format du message (texte standard, HTML ou Mime HTML) et le mode d'activation du protocole SSL pour la connexion :

si vous passez 0 ou omettez ce paramètre, le message sera formaté en texte et envoyé en mode standard non sécurisé. Si le serveur propose une mise à jour en SSL/TLS après l'authentification, la bascule est effectuée automatiquement (fonctionnement du SSL/TLS en mode explicite).
si vous passez 1, le message sera formaté en texte et envoyé en SSL (mode synchrone),
si vous passez 2, le message sera formaté en texte et envoyé en mode standard mais sans prise en charge de la mise à jour en SSL/TLS,
si vous passez 4, le message sera formaté en HTML et envoyé en mode standard,
si vous passez 5, le message sera formaté en HTML et envoyé en mode SSL/TLS,
si vous passez 8, le message sera formaté en Mime HTML et envoyé en mode standard,
si vous passez 9, le message sera formaté en Mime HTML et envoyé en mode SSL/TLS.
Note : Le Mime HTML (extension de fichier .mht ou .mhtml) est un format d'archive de page Web qui peut combiner du code HTML et des ressources externes telles que des images dans un seul document. Il est pris en charge par de nombreux navigateurs Web ainsi que par MS Word, par exemple. Comme ce format est également pris en charge par les zones 4D Write Pro, vous pouvez facilement enregistrer et envoyer des documents 4D Write Pro par mail avec toutes leurs ressources.

A noter que ces valeurs correspondent à des combinaisons usuelles, le paramètre paramSession étant en fait un "champ de bits" (bit field), il permet de définir toute combinaison personnalisée à l'aide des SET AUTOMATIC RELATIONS :

Numéro de bit	Format utilisé si le bit est à 1
0	Utiliser SSL ou le paramétrage par défaut, connexion en clair et mise à niveau en SSL si possible.
1	Ne jamais mettre à niveau, rester en mode non encrypté même si SSL possible. Ce bit est ignoré si SSL (bit 0) est sélectionné.
2	Body du message en HTML, définir l'en-tête de façon appropriée.
3	Message MHTML, le bit 2 (HTML) est ignoré. L'utilisateur doit définir tous les en-têtes sauf "A", "De", "Date", et "Objet"

Le paramètre optionnel port vous permet de spécifier le numéro de port SMTP à utiliser pour la connexion avec le serveur. Les valeurs les plus fréquemment utilisées sont :

25 = port SMTP standard non sécurisé (port par défaut si le paramètre est omis)
465 = port SMTPS (SSL/TLS)
587 = port SMTP standard mais sécurisé ; passez ce port pour les connexions avec un serveur MS Exchange (mode explicite).

Les paramètres optionnels nomUtilisateur et motDePasse permettent d'authentifier l'émetteur auprès du serveur de messagerie. Ces paramètres doivent être passés ensemble. A noter que le mode d'authentification le plus sécurisé pris en charge par le serveur sera utilisé (à l'image du mode par défaut de la commande SMTP_Auth).

Exemple 1

Exemple d'utilisation de cette commande :

 $NomServeur:="www.4d.com"

 $MsgÀ:="adupont@4d.fr"

 $MsgDe:="jsmith@4d.com"

 $Objet:="Rapport de ventes"

 $Message:="Pouvez-vous m'envoyer le rapport des ventes de janvier 2009 ? Merci."

 $Erreur:=SMTP_QuickSend($NomServeur;$MsgDe;$MsgÀ;$Objet;$Message;1)

 If($Erreur#0)

    ALERT("Erreur: SMTP_QuickSend"+Char(13)+IT_ErrorText($Erreur))

 End if

Exemple 2

Exemple d'utilisation de la commande pour un envoi de message sécurisé via un serveur MS Exchange:

 $NomServeur:="exchange.4d.com"

 $MsgA:="adupont@gmail.com"

 $MsgDe:="un.utilisateur@4d.com"

 $Objet:="Message de test"

 $Message:="Ceci est un test d'envoi en mode sécurisé. Merci de ne pas répondre."

 $Erreur:=SMTP_QuickSend($NomServeur;$MsgDe;$MsgA;$Objet;$Message;0;587;"un.utilisateur";"@!motdepasse@!")

Exemple 3

Envoi d’un message en HTML avec SSL/TLS :

 $Host:="smtp.gmail.com"

 $ToAddress:="john@4d.com"

 $FromAddress:="jeanmarc@gmail.com"

 $Subject:="Message HTML"

 $Message:="Rendez-vous au <b>café du monde</b> !!"

 $Param:=5 //HTML avec SSL

 $Port:=465 //Port SSL de gmail

 $User:="jeanmarc@gmail.com"

 $Password:="xyz&@!&@"

 $Error:=SMTP_QuickSend($Host;$FromAddress;$ToAddress;$Subject;$Message;$Param;$Port;$User;$Password)

Exemple 4

Vous avez enregistré un document .mht sur votre disque et souhaitez l'envoyer par email. Pour cela, vous pouvez écrire :

 $Message:=Document to text("c:\\documents\\invitation.mht")

 $Host:="smtp.gmail.com"

 $ToAddress:="john@4d.com"

 $FromAddress:="harry@gmail.com"

 $Subject:="Faisons la fête"

 $Param:=9 //MHTML avec SSL

 $Port:=465 //Port SSL de gmail

 $User:="harry@gmail.com"

 $Password:="xyz&@!&@"

 $Error:=SMTP_QuickSend($Host;$FromAddress;$ToAddress;$Subject;$Message;$Param;$Port;$User;$Password)

Voir aussi

SMTP_Charset
SMTP_New
SMTP_SetPrefs