JSON Stringify tableau

4D v20.6

JSON


JSON Stringify tableau ( tab {; *} ) -> Résultat

Paramètre	Type	Description
tab	Tableau texte, Tableau réel, Tableau booléen, Tableau pointeur, Tableau objet	Tableau dont le contenu doit être sérialisé
*	Opérateur	Améliorer le formatage
Résultat	Texte	Chaîne contenant le tableau JSON sérialisé

Description

La commande JSON Stringify tableau convertit le tableau 4D tab en un tableau JSON sérialisé. Cette commande effectue l’action inverse de la commande JSON PARSE TABLEAU.

Passez dans tab un tableau 4D contenant les données à sérialiser. Le tableau peut être de type texte, réel, booléen, pointeur ou objet.

Note : Si vous passez une variable scalaire ou un champ dans tab, la commande retournera simplement la valeur du paramètre entre "[ ]".

Vous pouvez passer le paramètre optionnel * afin d’inclure des caractères de formatage dans la chaîne résultante. Cette option permet d’améliorer la présentation des données JSON lorsqu’elles sont affichées dans une page Web (pretty formatting).

Exemple 1

Conversion d’un tableau texte :

 C_TEXTE($jsonString)

 TABLEAU TEXTE($ArrayFirstname;2)

 $ArrayFirstname{1}:="John"

 $ArrayFirstname{2}:="Jim"

 $jsonString :=JSON Stringify tableau($ArrayFirstname)

 

     // $jsonString = "["John","Jim"]"

Exemple 2

Conversion d’un tableau texte contenant des nombres :

 TABLEAU TEXTE($phoneNumbers;0)

 AJOUTER A TABLEAU($phoneNumbers ;"555-0100")

 AJOUTER A TABLEAU($phoneNumbers ;"555-0120")

 $string :=JSON Stringify tableau($phoneNumbers)

     // $string = "["555-0100","555-0120"]"

Exemple 3

Conversion d’un tableau objet :

 C_OBJET($ref_john)

 C_OBJET($ref_jim)

 TABLEAU OBJET($myArray;0)

 OB FIXER($ref_john;"name";"John";"age";35)

 OB FIXER($ref_jim;"name";"Jim";"age";40)

 AJOUTER A TABLEAU($myArray ;$ref_john)

 AJOUTER A TABLEAU($myArray ;$ref_jim)

 $JsonString :=JSON Stringify tableau($myArray)

     // $JsonString = "[{"name":"John","age":35},{"name":"Jim","age":40}]"

 

     // Si vous souhaitez visualiser le résultat dans une page Web, passez

     // le paramètre optionnel * :

 $JsonStringPretty :=JSON Stringify tableau($myArray;*)

Exemple 4

Conversion d’une sélection 4D dans un tableau objet :

 C_OBJET($jsonObject)

 C_TEXTE($jsonString)

 

 CHERCHER([Company];[Company]Company Name="a@")

 OB FIXER($jsonObject;"company name";->[Company]Company Name)

 OB FIXER($jsonObject;"city";->[Company]City)

 OB FIXER($jsonObject;"date";[Company]Date_input)

 OB FIXER($jsonObject;"time";[Company]Time_input)

 TABLEAU OBJET($arraySel;0)

 

 Tant que(Non(Fin de selection([Company])))

       $ref_value:=OB Copier($jsonObject;Vrai)

           // Si vous ne les copiez pas, les valeurs seront des chaînes vides

       AJOUTER A TABLEAU($arraySel;$ref_value)

           // Chaque élément contient les valeurs sélectionnées, par exemple :

           // $arraySel{1} = // {"company name":"APPLE","time":43200000,"city":

           // "Paris","date":"2012-08-02T00:00:00Z"}

       ENREGISTREMENT SUIVANT([Company])

 Fin tant que

 

 $jsonString:=JSON Stringify tableau($arraySel)

     // $jsonString = "[{"company name":"APPLE","time":43200000,"city":

     //"Paris","date":"2012-08-02T00:00:00Z"},{"company name":

     //"ALMANZA",...}]"

Voir aussi

JSON PARSE TABLEAU
JSON Stringify