New object

Home

4D v20.6

New object


New object {( Eigenschaft ; Wert {; Eigenschaft2 ; Wert2 ; ... ; EigenschaftN ; WertN} )} -> Funktionsergebnis

Parameter	Typ	Beschreibung
Eigenschaft	Text	Name der anzulegenden Eigenschaft
Wert	Mixed	Wert der Eigenschaft
Funktionsergebnis	Objekt	Neues Objekt der Programmiersprache

Beschreibung

Die Funktion New object erstellt ein neues leeres oder vorab gefülltes Objekt und gibt seine Referenz zurück.

Übergeben Sie keine Parameter, erstellt New object ein leeres Objekt und gibt seine Referenz zurück. Sie müssen diese Referenz einer 4D Variablen übergeben, die mit C_OBJECT oder über ein 4D Objektfeld deklariert ist.

Hinweis: C_OBJECT deklariert eine Variable vom Typ Objekt, erstellt aber kein Objekt.

Optional können Sie das neue Objekt vorab füllen, indem Sie ein oder mehrere Eigenschaft/Wert Paare als Parameter übergeben:

Im Parameter Eigenschaft übergeben Sie die Bezeichnung der zu erstellenden Eigenschaft. Beachten Sie, dass dieser Parameter zwischen Groß- und Kleinschreibung unterscheidet.
Übergeben Sie im Parameter value den Wert, den Sie für die Eigenschaft festlegen möchten. Es werden Werte der folgenden Typen unterstützt:
- Zahl (Real, Ganzzahl...) Zahlenwerte werden immer als Realwerte gespeichert.
- Text
- Boolean (boolesch)
- Zeiger (pointer)
- blob (4D.Blob)
- Datum
- Zeit
- null
- Bild
- Objekt
- Collection

Beachten Sie das:

wenn Sie einen Zeiger übergeben, wird dieser unverändert beibehalten; er wird ausgewertet, wenn Sie Befehle wie JSON Stringify verwenden,
Datumsangaben als "yyyy-mm-dd" Datumsangaben oder Strings im Format "YYYY-MM-DDTHH:mm:ss.SSSZ" gespeichert werden, entsprechend der aktuellen Datenbank-Einstellung "Datumsangaben in Objekten" (siehe Seite Kompatibilität). Bei der Konvertierung von 4D Datumsangaben in Text, bevor sie im Objekt gespeichert werden, berücksichtigt das Programm standardmäßig die lokale Zeitzone. Sie können dieses Verhalten mit dem Selector Dates inside objects des Befehls SET DATABASE PARAMETER ändern.
wenn Sie eine Zeit angeben, wird diese als Anzahl von Millisekunden (Real) gespeichert.

Beispiel 1

Dieser Code kann leere oder gefüllte Objekte erstellen:

 C_OBJECT($obj1)

 C_OBJECT($obj2)

 C_OBJECT($obj3)

 $obj1:=New object

  // $obj1 = {}

 $obj2:=New object("name";"Smith")

  // $obj2 = {name:Smith}

 $obj3:=New object("name";"Smith";"age";40)

  // $obj3 = {name:Smith,age:40}

Beispiel 2

Ein neues Objekt mit einem Objekt als Parameter Wert erstellen:

 C_OBJECT($Children;$Contact)

 

  //Ein Objekt Array erstellen

 ARRAY TEXT($arrChildren;3)

 $arrChildren{1}:="Richard"

 $arrChildren{2}:="Susan"

 $arrChildren{3}:="James"

 OB SET ARRAY($Children;"Children";$arrChildren)

 

  //Das Objekt initialisieren

 $Contact:=New object("FirstName";"Alan";"LastName";"Parker";"age";30;"Children";$Children)

  // $Contact = {FirstName:Alan,LastName:Parker,age:30,Children:{Children:[Richard,Susan,James]}}

Beispiel 3

Dieser Code übergibt Objekte als Parameter:

 C_OBJECT($measures)

 $measures:=Get database measures(New object("path";"DB.cacheReadBytes";"withHistory";True;"historyLength";120))

Beispiel 4

Mit diesem Code können Sie Objekte in Schleifen einfach verwalten:

 ARRAY OBJECT($refs;0)

 C_LONGINT(vCounter)

 

 For(vCounter;1;100)

    APPEND TO ARRAY($refs;New object("line";"Line number "+String(vCounter)))

 End for

Siehe auch

Download HDI database
New shared object