Attente relachement clic

4D v20 R7


Attente relachement clic -> Résultat

Paramètre	Type	Description
Résultat	Booléen	Vrai si l'objet est en attente d'un relâchement souris, Faux sinon

Description

La commande Attente relachement clic retourne Vrai si l'objet courant a été cliqué et que le bouton de la souris n'a pas été relâché, alors que la fenêtre contenant l'objet a le focus. Sinon la commande retourne Faux, en particulier si la fenêtre contenant l'objet a perdu le focus avant que le bouton soit relâché.

Cette commande doit être appelée dans le contexte de l'objet courant. Elle est destinée à être utilisée conjointement avec l'événement formulaire Sur relâchement bouton, disponible pour les champs et variables Image. Elle permet de gérer par programmation les cas où l'utilisateur clique et commence à effectuer un glisser dans une zone image (champ ou variable), et que cette action est interrompue par un événement extérieur, comme par exemple l'affichage d'une boîte de dialogue d'alerte. Dans ce cas, l'état interne de l'objet peut être suspendu indéfiniment car il attend l'événement Sur relâchement bouton qui n'arrive jamais. Pour éviter ce problème, vous devez protéger votre code de déplacement de souris à l'aide de la commande Attente relachement clic qui vous assure de son exécution dans un contexte valide.

Exemple

Le code suivant peut être utilisé pour gérer le suivi de la souris dans un objet image :

  //Méthode objet de l'objet image

 C_ENTIER LONG(vLtracking) //drapeau du mode Suivi

 Au cas ou

    :(Evenement formulaire code=Sur clic)

       Si(Attente relâchement clic) // le bouton de la souris n'a pas été relâché

          vLtracking:=1 //nous sommes en mode Suivi

  //... Ecrivez ici le code d'initialisation pour la fonction de Suivi

       Fin de si

    :(Evenement formulaire code=Sur survol)

       Si(vLtracking=1) //nous sommes en mode Suivi

          Si(Non(Attente relachement clic)) // on n'aura jamais le relâchement de la souris

             vLtracking:=0 // on stoppe le mode Suivi

  //... Ecrivez ici le code pour le traitement ou l'annulation de l'action de suivi

          Sinon //l'objet est toujours en attente du relâchement de la souris

  //... Ecrivez ici le code pour le suivi

          Fin de si

       Fin de si

    :(Evenement formulaire code=Sur relâchement bouton) // le bouton de la souris a été relâché

  //... Ecrivez ici le code pour le suivi du relâchement souris

       vLtracking:=0 //Fin du suivi

 Fin de cas

Voir aussi

Evenement formulaire code