Choose

Home

4D v20 R7

Choose


Choose ( Kriterium ; Wert {; Wert2 ; ... ; WertN} ) -> Funktionsergebnis

Parameter	Typ	Beschreibung
Kriterium	Boolean, Ganzzahl	Zu testender Wert
Wert	Ausdruck	Mögliche Werte
Funktionsergebnis	Ausdruck	Wert des Kriteriums

Beschreibung

Die Funktion Choose gibt einen der Werte im Parameter Wert zurück, je nach dem im Kriterium übergebenen Wert.

Im Parameter Kriterium können Sie einen Wert vom Typ Boolean oder Ganzzahl übergeben:

Ist Kriterium ein Boolean Wert, gibt Choose Wert1 zurück, wenn Boolean Wahr ist und Wert2, wenn Boolean Falsch ist.
In diesem Fall erwartet die Funktion genau drei Parameter: Kriterium, Wert1 und Wert2.
Ist Kriterium eine Ganzzahl, gibt Choose den Wert zurück, dessen Position dem Parameter Kriterium entspricht. Beachten Sie, dass die Nummerierung der Werte mit 0 beginnt, d.h. die Position von Wert1 ist 0 (Null).
In diesem Fall erwartet die Funktion mindestens zwei Parameter: Kriterium und Wert1.

Die Funktion erlaubt in Wert alle Datentypen bis auf Bilder, Zeiger, BLOBS und Arrays. Sie müssen jedoch sicherstellen, dass alle übergebenen Werte vom gleichen Typ sind. 4D führt hier keine Überprüfung durch.
Entspricht kein Wert Kriterium, gibt Choose einen “Null” Wert zurück in Bezug auf den in Wert übergebenen Typ (z.B. 0 für Zahl, “” für String, etc).

Mit dieser Funktion können Sie Code mit „Case of“ verkürzen, der mehrere Zeilen einnimmt (siehe 2. Beispiel). Sie ist auch sehr hilfreich an Stellen, wo Formeln ausführbar sind, z.B. Sucheditor, Anwendung einer Formel, Schnellberichteditor, in Listbox berechnete Spalte, usw.

Warnung: Choose bewertet jeden Parameter Wert vor seiner Ausführung. Das bedeutet folgendes:

Ist Wert ein dynamischer Ausdruck, hat das in allen Fällen Nebeneffekte, wie Update des Zählers, Änderung jeglicher Art
Ist Wert ein ungültiger Ausdruck, gibt Choose in allen Fällen einen Fehler zurück. Hierzu ein Beispiel:
$res:=Choose(True;"red1";"blue"+2) //Fehler

Beispiel 1

Hier ein Beispiel für eine typische Verwendung mit dem Typ Booelan im Parameter Kriterium:

vTitle:=Choose([Person]Masculine;"Mr";"Ms")

Dieser Code entspricht exakt:

 If([Person]Masculine)

    vTitle:="Mr"

 Else

    vTitle:="Ms"

 End if

Beispiel 2

Hier ein Beispiel für eine typische Verwendung mit dem Typ Zahl im Parameter Kriterium:

vStatus:=Choose([Person]Status;"Ledig";"Verheiratet";"Verwitwet";"Geschieden")

Dieser Code entspricht exakt:

 Case of

    :([Person]Status=0)

       vStatus:="Ledig"

    :([Person]Status=1)

       vStatus:="Verheiratet"

    :([Person]Status=2)

       vStatus:="Verwitwet"

    :([Person]Status=3)

       vStatus:="Geschieden"

 End case