EXPORTER DONNEES

4D v20 R7

EXPORTER DONNEES


EXPORTER DONNEES ( nomFichier {; projet {; *}} )

Paramètre	Type	Description
nomFichier	Chaîne	Chemin d’accès et nom du fichier d’export
projet	Variable texte, Variable BLOB	Contenu du projet d’export (XML ou référence d'élément DOM ou BLOB)
		Nouveau contenu du projet d’export (si le paramètre * a été passé)
*	Opérateur	Affichage de la boîte de dialogue d’export et mise à jour du projet

Description

La commande EXPORTER DONNEES permet d’exporter des données dans le fichier nomFichier. 4D peut exporter des données au format Texte, Texte de longueur fixe, XML, SYLK, DIF, DBF (dBase), et 4D.

Si vous passez une chaîne vide dans le nomFichier, EXPORTER DONNEES provoque l’affichage d’une boîte de dialogue standard d’enregistrement de fichiers, permettant à l’utilisateur de définir le nom, le type et l’emplacement du fichier d’export. Une fois la boîte de dialogue validée, la variable système Document contient le chemin d’accès et le nom de ce fichier. Si l’utilisateur clique sur le bouton Annuler, l’exécution est stoppée et la variable système OK prend la valeur 0.

Le paramètre optionnel projet vous permet d'utiliser un projet pour l'export des données. Lorsque vous passez ce paramètre, l’export s’effectue directement, sans intervention de l’utilisateur (sauf si vous utilisez l'option *, cf. ci-dessous). Si vous ne passez pas ce paramètre, la boîte de dialogue de paramétrage d’export s’affiche, permettant à l’utilisateur de définir ses paramètres d’export ou de charger un projet d’export existant.

Un projet d’export contient tous les paramètres de l’export, tels que les tables et champs exportés, les délimiteurs, etc. Vous pouvez passer dans projet soit une variable texte contenant du XML, soit une variable texte contenant la référence à un élément DOM préexistant, soit un BLOB. Les projets peuvent avoir été créés par programmation (projets au format XML uniquement) ou être issus du chargement de paramètres préalablement définis dans la boîte de dialogue d’export. Dans ce dernier cas, vous disposez de deux solutions :

utiliser la commande EXPORTER DONNEES avec un paramètre projet vide et le paramètre optionnel * (cf. ci-dessous), puis stocker le paramètre projet résultant dans un champ Texte ou BLOB. Cette solution permet notamment de conserver le projet avec le fichier de données.
sauvegarder le projet sur disque, puis le charger par exemple à l’aide de la commande DOM Analyser source XML et passer sa référence dans le paramètre projet.

Note de compatibilité : A compter de la version 12 de 4D, les projets d'export sont encodés en XML. 4D peut ouvrir les projets d'export générés avec des versions précédentes de 4D (format BLOB), mais les projets créés à compter de la v12 ne peuvent plus être rouverts avec une v11 ou antérieure. Il est désormais conseillé d'utiliser des variables Texte pour manipuler les fichiers d'export.

Le paramètre optionnel *, s’il est est spécifié, provoque l’affichage de la boîte de dialogue de paramétrage d’export avec les paramétrages définis dans le projet. Ce fonctionnement permet d’utiliser un projet prédéfini, tout en ayant la possibilité de modifier un ou plusieurs paramètres. En outre, le paramètre projet contient, après la fermeture de la boîte de dialogue d’export, les paramètres du “nouveau” projet au format XML. Vous pouvez alors le stocker dans un champ Texte, dans un fichier sur disque, etc.

Si l’export se déroule correctement, la variable système OK prend la valeur 1.

Exemple 1

Cet exemple illustre l'utilisation de la commande EXPORTER DONNEES pour exporter en format binaire les données d'une base.

Cette méthode effectue une boucle sur toutes les tables de la base et appelle la méthode ExportBinary :

 C_TEXTE($ExportPath)

 C_ENTIER LONG($i)

 $ExportPath:=Selectionner dossier("Veuillez sélectionner le dossier d'export :")

 Si(Ok=1)

    Boucle($i;1;Lire numero derniere table)

       Si(Est un numero de table valide($i))

          ExportBinary(Table($i);$ExportPath+Nom de la table($i);Vrai)

       Fin de si

    Fin de boucle

 Fin de si

Voici le code de la méthode ExportBinary :

 C_POINTEUR($1) //table

 C_TEXTE($2) //chemin du fichier de destination

 C_BOOLEEN($3) //exporter tous les enregistrements

 C_ENTIER LONG($i)

 C_TEXTE($ref)

 $ref:=DOM Creer ref XML("settings-import-export")

  // Exporter la table "$1" au format binaire '4D', tous les enregistrements ou uniquement la sélection courante

 DOM ECRIRE ATTRIBUT XML($ref;"table_no";Table($1);"format";"4D";"all_records";$3)

  // Définition des champs à exporter

 Boucle($i;1;Lire numero dernier champ($1))

    Si(Est un numero de champ valide($1;$i))

       $elt:=DOM Creer element XML($ref;"field";"table_no";Table($1);"field_no";$i)

    Fin de si

 Fin de boucle

 EXPORTER DONNEES($2;$ref)

 Si(Ok=0)

    ALERTE("Erreur lors de l'export de la table "+Nom de la table($1))

 Fin de si

 DOM FERMER XML($ref)

Exemple 2

Cet exemple crée un projet vide et y stockera les paramètres définis par l'utilisateur dans la boîte de dialogue d’export :

 C_TEXTE($exportParams)

 EXPORTER DONNEES("DocExport.txt";$exportParams;*) //Affichage de la boîte de dialogue d'export

Variables et ensembles système

Si l'utilisateur clique sur Annuler dans une des boîtes de dialogue (d'enregistrement de projet ou de paramétrage d'export), la variable système OK prend la valeur 0. Si l’export se déroule correctement, la variable système OK prend la valeur 1.

Voir aussi

ECRITURE DIF
ECRITURE SYLK
EXPORTER TEXTE
IMPORTER DONNEES