IT_PPPStatus

4D v20 R7

IT_PPPStatus


IT_PPPStatus ( pppProfil ) -> 戻り値

引数	型	説明
pppProfil	文字	ダイアルアップ名 = Mac OSでは空文字, Windowsの場合オプション
戻り値	整数	1: 接続中; 0: 接続処理中; -1: エラー

説明

IT_PPPStatus コマンドを使用して、IT_PPPConnect コマンドを使用してまたは手動で開いた接続のステータスを取得できます。

pppProfil はチェックを行う開かれた接続を指定するテキストです。

Windowsでは、この引数はオプションですが、指定することで、ネットワーク設定にかかわらず正しく動作することが期待できます。

Windowsの場合

有効なpppProfilが渡された場合、指定した接続のステータスが返されます。
pppProfilが省略されたか空文字の場合、IT_PPPStatusは以下を返します:
- 複数の接続が開かれている場合、-1。
- 接続が一つだけ開かれている場合、その接続のステータス。

Mac OSの場合

この引数は考慮されません。

IT_PPPStatusは接続のステータスを示す整数値を返します:

接続している場合、1。
接続処理中の場合、0。
接続失敗または接続されていない場合、-1。

例題

  //GetMessagesメソッド (このメソッドはプロセス内で実行される)

 If(mPPPConnect($vPPPProfil;120))

    $vErrCode:=IT_MacTCPInit

    If($vErrCode=0)

       $vErrCode:=POP3_Login...

       ...

    Else

       ALERT("Connection failed")

    End if

 End if

 

  //mPPPConnectメソッド

 C_BOOLEAN($0) //接続したらTrueが、失敗したらFalseが返される

 C_TEXT($1) //Mac OSでは空文字, Windowsでは接続名を入力

 C_LONGINT($2) //タイムアウト秒数

 

 If(IT_PPPStatus=1)

    $0:=True //すでに接続している

 Else

    $vTimeoutLength:=$2

    $vTimeout:=False

    $vErr:=IT_PPPConnect($1)

    If($vErr=0)

       $vStart:=Current time

       Repeat

          DELAY PROCESS(Current process;30)

          $vStatus:=IT_PPPStatus($1)

          $vTimeout:=((Current time-$vStart)>$vTimeoutLength)

       Until(($vStatus=1)|$vTimeout) //接続したかタイムアウトした

       If(Not($vTimeout))

          $0:=True //接続した

       End if

    End if //… $Err = 0

 End if

参照

IT_PPPConnect
IT_PPPDisconnect