Imprimer objet

4D v20 R7

Imprimer objet


Imprimer objet ( {* ;} objet {; posX {; posY {; largeur {; hauteur}}}} ) -> Résultat

Paramètre	Type	Description
*	Opérateur	Si spécifié, objet est un nom d'objet (chaîne) Si omis, objet est une variable
objet	Objet de formulaire	Nom d'objet (si * spécifié) ou Variable (si * omis)
posX	Entier long	Emplacement horizontal de l'objet
posY	Entier long	Emplacement vertical de l'objet
largeur	Entier long	Largeur de l'objet (pixels)
hauteur	Entier long	Hauteur de l'objet (pixels)
Résultat	Booléen	Vrai = objet entièrement imprimé, Faux sinon

Description

La commande Imprimer objet vous permet d’imprimer le ou les objet(s) de formulaire désigné(s) par les paramètres objet et *, à l’emplacement défini par les paramètres posX et posY.

Avant d’appeler la commande Imprimer objet, vous devez désigner le formulaire table ou projet contenant les objets à imprimer, à l’aide de la commande FORM CHARGER.

Si vous passez le paramètre optionnel *, vous indiquez que le paramètre objet est un nom d'objet (une chaîne de caractères). Si vous ne passez pas le paramètre *, vous indiquez que objet est une variable. Dans ce cas, vous ne passez pas une chaîne mais une référence de variable (de type objet uniquement).

Les paramètres posX et posY définissent le point de départ de l’impression du ou des objet(s). Ces valeurs doivent être exprimées en pixels. Si ces paramètres sont omis, l’objet sera imprimé en fonction de son emplacement dans le formulaire.

Les paramètres largeur et hauteur vous permettent de définir la largeur et la hauteur de l’objet de formulaire. La commande Imprimer objet ne gère pas les objets de taille variable. Vous devez utiliser la commande OBJET LIRE TAILLE OPTIMALE pour prendre en charge la taille des objets. Vous pouvez également utiliser la commande OBJET LIRE TAILLE OPTIMALE pour connaître la taille la plus adéquate pour les objets contenant du texte. De même, Imprimer objet ne provoque pas de sauts de page automatiques. Vous devez les gérer en fonction de vos besoins.

Vous pouvez utiliser les commandes de 4D pour modifier à la volée les propriétés des objets (couleur, taille...).

La commande retourne Vrai si l’objet a été imprimé entièrement et Faux dans le cas contraire, c’est-à-dire si l’intégralité des données associées à l’objet n’a pas pu être imprimée dans le cadre imposé. Typiquement, la commande retourne Faux lors de l’impression d’une list box, si toutes les lignes de la list box n’ont pas pu être imprimées. Dans ce cas, il suffit d’appeler la commande Imprimer objet de façon répétée, jusqu’à ce qu’elle retourne Vrai : un mécanisme spécifique provoque automatiquement le défilement du contenu de l’objet après chaque appel. Si l'utilisateur annule l'impression, une erreur -128 est générée et peut être interceptée à l'aide de APPELER SUR ERREUR.

Notes :

Dans la version actuelle de 4D, seuls les objets de type list box bénéficient de ce mécanisme (la commande retourne toujours Vrai pour tous les autres types d’objets).
La commande LISTBOX LIRE INFORMATION IMPRESSION permet de contrôler le statut de l’impression durant l’opération.

La commande Imprimer objet peut être utilisée uniquement dans le contexte d’une tâche d’impression préalablement ouverte avec la commande OUVRIR TACHE IMPRESSION. Si elle n’est pas appelée dans ce contexte, la commande ne fait rien. Plusieurs commandes Imprimer objet peuvent être appelées dans la même tâche d’impression.

Note : Les listes hiérarchiques, les sous-formulaires et les zones Web ne sont pas imprimables.

Exemple 1

Exemple d’impression de dix objets dans un formulaire :

 PARAMETRES IMPRESSION

 Si(OK=1)

       OUVRIR TACHE IMPRESSION

       Si(OK=1)

          FORM CHARGER("PrintForm")

          x:=100

          y:=50

          LIRE ZONE IMPRESSION(hpaper;wpaper)

          Boucle($i;1;10)

             OBJET LIRE TAILLE OPTIMALE(*;"Obj"+Chaine($i);bestwidth;bestheight)

             $fin:=Imprimer objet(*;"Obj"+Chaine($i))

             y:=y+bestheight+15

             Si(y>hpaper)

                SAUT DE PAGE(>)

                y:=50

             Fin de si

          Fin de boucle

       Fin de si

       FERMER TACHE IMPRESSION

 Fin de si

Exemple 2

Exemple d’impression d’une list box complète :

 OUVRIR TACHE IMPRESSION

 FORM CHARGER("myForm")

 $Over:=Faux

 gError:=0

 APPELER SUR ERREUR("err")

 Repeter

    $Total:=Imprimer objet(*;"List_Box")

    LISTBOX LIRE INFORMATION IMPRESSION(*;"List_Box";lk impression terminée;$Over)

    SAUT DE PAGE

    Si(gError=-128) //l'utilisateur a annulé l'opération

       $Over:=Vrai

    Fin de si

 Jusque($Over)

 FERMER TACHE IMPRESSION

 APPELER SUR ERREUR("")

Voir aussi

FORM CHARGER