OB LIRE NOMS PROPRIETES

4D v20 R7


OB LIRE NOMS PROPRIETES ( objet ; tabPropriétés {; tabTypes} )

Paramètre	Type	Description
objet	Objet	Objet structuré
tabPropriétés	Tableau texte	Noms des propriétés
tabTypes	Tableau entier long	Types des propriétés

Description

La commande OB LIRE NOMS PROPRIETES retourne dans tabPropriétés les noms des propriétés contenues dans l’objet de langage désigné par le paramètre objet.

objet doit avoir été défini via la commande _O_C_OBJET ou désigner un champ objet 4D.

Passez dans le paramètre tabPropriétés un tableau texte. Si le tableau n’existe pas, la commande le crée et le dimensionne automatiquement.

Optionnellement, vous pouvez passer dans tabTypes un tableau entier long. Pour chaque élément de tabPropriétés, la commande retournera dans tabTypes le type de la valeur stockée dans la propriété. Vous pouvez comparer les valeurs reçues aux constantes suivantes du thème Types champs et variables :

Constante	Type	Valeur
Est un booléen	Entier long	6
Est un null	Entier long	255
Est un numérique	Entier long	1
Est un objet	Entier long	38
Est un tableau objet	Entier long	39
Est un texte	Entier long	2
Est une collection	Entier long	42

Note : Pour les propriétés d'un tableau, la commande retourne Est une collection.

Exemple 1

Vous souhaitez tester qu’un objet n’est pas vide :

 TABLEAU TEXTE(tabNoms;0)

 TABLEAU ENTIER LONG(tabTypes;0)

 C_OBJET($ref_richard)

 OB FIXER($ref_richard;"nom";"Richard";"age";7)

 OB LIRE NOMS PROPRIETES($ref_richard;tabNoms;tabTypes)

     //tabNoms{1}="nom", tabNoms{2}="age"

     //tabTypes{1}=2, tabTypes{2}=1

 Si(Taille tableau(tabNoms)#0)

        //...

 Fin de si

Exemple 2

Utilisation d’un élément de tableau d’objets :

 C_OBJET($Children;$ref_richard;$ref_susan;$ref_james)

 TABLEAU OBJET($arrayChildren;0)

 

 OB FIXER($ref_richard;"nom";"Richard";"age";7)

 AJOUTER A TABLEAU($arrayChildren;$ref_richard)

 OB FIXER($ref_susan;"nom";"Susan";"age";4;"fille";Vrai) //attribut supplémentaire

 AJOUTER A TABLEAU($arrayChildren;$ref_susan)

 OB FIXER($ref_james;"nom";"James")

 OB FIXER NULL($ref_james;"age") //attribut null

 AJOUTER A TABLEAU($arrayChildren;$ref_james)

 

 OB LIRE NOMS PROPRIETES($arrayChildren{1};$tabNoms;$tabTypes)

  // $arrayChildren{1} = {"nom":"Richard","age":7}

  // $tabNoms{1}="nom"

  // $tabNoms{2}="age"

  // $tabTypes{1}=2

  // $tabTypes{2}=1

 

 OB LIRE NOMS PROPRIETES($arrayChildren{2};$tabNoms;$tabTypes)

  // $arrayChildren{3} = {"nom":"Susan","age":4,"fille":true}

  // $tabNoms{1}="nom"

  // $tabNoms{2}="age"

  // $tabNoms{3}="fille"

  // $tabTypes{1}=2

  // $tabTypes{2}=1

  // $tabTypes{3}=6

 

 OB LIRE NOMS PROPRIETES($arrayChildren{3};$tabNoms;$tabTypes)

  // $arrayChildren{3} = {"nom":"James","age":null}

  // $tabNoms{1}="nom"

  // $tabNoms{2}="age"

  // $tabTypes{1}=2

  // $tabTypes{2}=255

Voir aussi

OB FIXER NULL
OB Lire type