OB SET ARRAY

Home

4D v20 R7

OB SET ARRAY


OB SET ARRAY ( Objekt ; Eigenschaft ; Array )

Parameter	Typ	Beschreibung
Objekt	Objektfeld, Objekt	Strukturiertes Objekt
Eigenschaft	Text	Name der zu setzenden Eigenschaft
Array	Array, Variable	Array zum Speichern in Eigenschaft

Beschreibung

Der Befehl OB SET ARRAY definiert das Array, das der Eigenschaft im Objekt, definiert im Parameter Objekt, zugeordnet ist.

Objekt muss zuvor über den Befehl _O_C_OBJECT definiert werden oder ein 4D Objektfeld angeben.

Im Parameter Eigenschaft übergeben Sie die Bezeichnung der Eigenschaft zum Erstellen oder Ändern. Ist die Eigenschaft bereits in Objekt vorhanden, wird ihr Wert aktualisiert. Ist sie noch nicht vorhanden, wird sie angelegt. Beachten Sie, dass Eigenschaft Groß- und Kleinschreibung berücksichtigt.

Im Parameter Array übergeben Sie das Array, das als Wert der Eigenschaft übergeben werden muss. Unterstützt werden die Array-Typen Zahl, Lange Ganzzahl, Text, Boolean, Objekt, Zeiger und Bild.

Hinweise:

Array unterstützt einfache Variablen; es wird eine Variable mit einem einzigen Wert angelegt und der Eigenschaft zugewiesen.
Zweidimensionale Arrays lassen sich hier nicht verwenden.

Beispiel 1

Ein Array Text verwenden:

 C_OBJECT($Children)

 ARRAY TEXT($arrChildren;3)

 $arrChildren{1}:="Richard"

 $arrChildren{2}:="Susan"

 $arrChildren{3}:="James"

 

 OB SET ARRAY($Children;"Children";$arrChildren)

  // Value of $Children = {"Children":["Richard","Susan","James"]}

Beispiel 2

In einem Array ein Element hinzufügen:

 ARRAY TEXT($arrText;2)

 $arrText{1}:="Smith"

 $arrText{2}:="White"

 C_OBJECT($Employees)

 OB SET ARRAY($Employees;"Employees";$arrText)

 APPEND TO ARRAY($arrText;"Brown") // Add to the 4D array

  // $Employees = {"Employees":["Smith","White"]}

 

 OB SET ARRAY($Employees;"Employees";$arrText)

  // $Employees = {"Employees":["Smith","White","Brown"]}

Beispiel 3

Ein Array Text mit Auswahl eines Elements verwenden:

  // $Employees = {"Employees":["Smith","White","Brown"]}

 OB SET ARRAY($Employees ;"Manager";$arrText{1})

  // $Employees = {"Employees":["Smith","White","Brown"],"Manager":["Smith"]}

Beispiel 4

Ein Array Objekt verwenden:

 C_OBJECT($Children;$ref_richard;$ref_susan;$ref_james)

 ARRAY OBJECT($arrChildren;0)

 OB SET($ref_richard;"nom";"Richard";"age";7)

 APPEND TO ARRAY($arrChildren;$ref_richard)

 OB SET($ref_susan;"name";"Susan";"age";4)

 APPEND TO ARRAY($arrChildren;$ref_susan)

 OB SET($ref_james;"name";"James";"age";3)

 

 APPEND TO ARRAY($arrChildren;$ref_james)

 

  // $arrChildren {1} = {"name":"Richard","age":7}

  // $arrChildren {2} = {"name":"Susan","age":4}

  // $arrChildren {3} = {"name":"James","age":3}

 

 OB SET ARRAY($Children;"Children";$arrChildren)

 

  // $Children = {"Children":[{"name":"Richard","age":7},{"name":"Susan",

  // "age":4},{"name":"James","age":3}]}

Hier sehen Sie, wie das Objekt im Debugger erscheint:

Beispiel 5

Ein Objektfeld verwenden

 ARRAY TEXT($arrGirls;3)

 $arrGirls{1}:="Emma"

 $arrGirls{2}:="Susan"

 $arrGirls{3}:="Jamie"

 OB SET ARRAY([People]Children;"Girls";$arrGirls)

Beispiel 6

Ein Array vom Typ Bild verwenden:

 ARRAY PICTURE($arrPhotos;3)

 READ PICTURE FILE("pict1.jpg";$arrPhotos{1})

 READ PICTURE FILE("pict2.jpg";$arrPhotos{2})

 READ PICTURE FILE("pict3.jpg";$arrPhotos{3})

 

 OB SET ARRAY([Cities]Places;"Photoset";$arrPhotos)

Siehe auch

OB GET ARRAY
OB SET
Typkonvertierung zwischen Collections und 4D Arrays