WA Run offscreen area

4D v20 R7


WA Run offscreen area ( paramètres ) -> Résultat

Paramètre	Type	Description
paramètres	Objet	Objet contenant les attributs de la zone web
Résultat	Varié	Valeur retournée par la méthode callback (ou méthode de rétro-appel)

Description

La commande WA Run offscreen area crée une zone web dans la mémoire qui peut être utilisée pour charger et parser automatiquement des pages web.

Note : Cette commande utilise le moteur de rendu web intégré.

Dans l'objet paramètres, passez l'un des propriétés optionnelles suivantes pour la zone web. Ces propriétés seront disponibles via la commande This dans la méthode onEvent et référencent cette instance :

Propriété	Type	Description
url	objet texte \| fichier	L'URL ou le fichier à charger dans la zone web. S'il est omis, une page blanche est chargée.
area	texte	Le nom de la zone web. S'il est omis ou null, un nom générique est attribué (ex : OffscreenArea1).
onEvent	objet (formule)	Une méthode callback qui est lancée lorsque la zone web est prête. Elle peut être soit : une fonction onEvent d'une classe, ou un objet Formula Par défaut, la méthode callback est appelée sur les événements On Load, On Unload, On End URL Loading, On URL Loading Error, ou On Timer.
autoQuit	booléen	Vrai (valeur par défaut) si la commande doit stopper l'exécution de la formule lorsque les événement On End URL Loading ou On URL Loading Error se produisent. Si faux, vous devez utiliser les commandes CANCEL ou ACCEPT dans la méthode callback ou les méthodes projet appelées avec l'objet $4d pour fermer la zone web.
timeout	réel	Durée maximale (en secondes) avant la fermeture automatique de la zone, si aucun événément n'est généré. Si elle est définie sur 0, aucune limitation n'est appliquée. Valeur par défaut : 60
result	mixte	Résultat du traitement à retourner (le cas échéant)
<customProperty>	mixte	Un attribut personnalisé disponible dans la méthode callback ou $4d.

La propriété suivante est automaiquement ajoutée par la commande, si nécessaire :

Propriété	Type	Description
timeoutReached	booléen	Ajoutée avec la valeur true si le timeout s'est écoulé

Si une valeur null est passée dans paramètres, une zone web vide sera créée puis automatiquement fermée.

Notes :

La zone web hors écran est disponible uniquement durant l'exécution de la commande WA Run offscreen area. Elle sera automatiquement détruite une fois que l'exécution est terminée.
Les méthodes 4D peuvent être appelées avec le code JavaScript qui est exécuté dans une zone web. Voir Accéder aux méthodes 4D.

Les commandes suivantes peuvent être utilisées dans la méthode callback :

Exemple

Vous souhaitez créer et gérer une zone web hors écran à l'aide d'une fonction de votre classe OffscreenArea :

 $config:=cs.OffscreenArea.new()

 $result:=WA Run offscreen area($config)

 If($config.timeoutReached) //retourné automatiquement en cas de timeout

    ALERT("Timeout écoulé")

 End if

dans la classe OffscreenArea :

 Class constructor

 This.url:=File("/RESOURCES/compute.html")

 This.area:="myWAOffscreen"

 

 Function onEvent

 Case of

    :(FORM Event.code=On End URL Loading)

       This.result:=WA Evaluate JavaScript(*;This.area;"myJSMethod();")

 End case

Variables et ensembles système

La variable système OK est définie sur 0 si le timeout a été atteint ou si la commande CANCEL a été appelée dans onEvent, sinon elle est définie sur 1.

Voir aussi

FORM Event
Gestion programmée des zones Web
WA OPEN WEB INSPECTOR