WP Tableau ajouter ligne

4D v20 R7


WP Tableau ajouter ligne ( refTableau ; valeur {; valeur2 ; ... ; valeurN} ) -> Résultat

Paramètre	Type	Description
refTableau	Objet	Référence de tableau
valeur	Texte, Numérique, Heure, Date, Image	Valeur(s) à fixer dans la ligne
Résultat	Objet	Objet plage ligne

Description

La commande WP Tableau ajouter ligne ajoute une ligne au tableau refTableau, le remplit avec les valeur(s) et retourne l'objet correspondant à la plage de la ligne.

La commande ajoute autant de cellules dans la ligne qu'il y a de valeurs dans le paramètre valeur. Vous pouvez ajouter n'importe quel nombre de valeurs de différents types ; l'alignement par défaut dans la cellule dépend du type de la valeur :

texte : aligné à gauche
image : centrée
autres type (nombres, date, et heure) : alignés à droite.

Note : Les valeurs de type Tableau ne sont pas supportées.

La commande retourne la nouvelle ligne en tant qu'objet plage de ligne.

Exemple 1

Vous souhaitez créer un tableau vide et y ajouter plusieurs lignes de taille différente. Vous pouvez écrire :

 C_OBJET($wpTable;$wpRange;$wpRow1;$wpRow2;$wpRow3)

 $wpRange:=WP Plage texte(WParea;wk start text;wk end text)

 $wpTable:=WP Insérer tableau($wpRange;wk append)

 $wpRow1:=WP Tableau ajouter ligne($wpTable;"Paul";"Smith";25)

 $wpRow2:=WP Tableau ajouter ligne($wpTable;"John";"Richmond";40)

 $wpRow3:=WP Tableau ajouter ligne($wpTable;"Mary";"Trenton";18;"New!")

Exemple 2

Dans une facturation, vous souhaitez créer un tableau automatiquement rempli avec la sélection les lignes facture :

 C_OBJET($wpTable;$wpRange)

 

 $wpRange:=WP Plage texte(4DWPArea;wk start text;wk end text)

 

 $wpTable:=WP Insérer tableau($wpRange;wk append) //création du tableau

 

  // on ajoute la ligne d'en-tête

 $row:=WP Tableau ajouter ligne ($wpTable;"Name";"Quantity";"Unit Price";"Discount Rate";"Total")

 WP FIXER ATTRIBUTS($row;wk font bold;wk true;wk text align;wk center)

 

  //on utilise simplement un appliquer à sélection

 APPLIQUER A SELECTION([INVOICE_LINES];WP Tableau ajouter ligne($wpTable;[INVOICE_LINES]ProductName;[INVOICE_LINES]Quantity;[INVOICE_LINES]ProductUnitPrice;[INVOICE_LINES]DiscountRate;[INVOICE_LINES]Total))

 

  //on ajoute une ligne pour le pied

 $row:=WP Tableau ajouter ligne($wpTable;"Total:";Somme([INVOICE_LINES]Quantity);"";"";Somme([INVOICE_LINES]Total))

 

  //on formate le tableau

 $range:=WP Tableau lire colonne($wpTable;1;5)

 WP FIXER ATTRIBUTS($range;wk width;"80pt")

 WP FIXER ATTRIBUTS($wpTable;wk font size;10)

Voir aussi

WP Inserer tableau
WP Tableau lire lignes