WP EXPORT DOCUMENT

4D v20 R7

WP EXPORT DOCUMENT


WP EXPORT DOCUMENT ( docWP ; cheminFichier {; format {; options}} )

Paramètre	Type	Description
docWP	Objet	Variable 4D Write Pro
cheminFichier	Chaîne	Chemin du fichier d'export
format	Entier long	Format de sortie du document
options	Objet, Entier long	Options d'export

Description

La commande WP EXPORT DOCUMENT exporte l'objet 4D Write Pro docWP dans un document sur disque défini par le paramètre cheminFichier ainsi que des paramètres optionnels.

Dans docWP, passez l'objet 4D Write Pro que vous voulez exporter.

Dans cheminFichier, passez le chemin de destination et le nom du document à exporter. Si vous passez uniquement un nom de fichier, il sera enregistré au même niveau que le fichier de structure de 4D. Par défaut, si vous omettez le paramètre format, la commande utilise l'extension du fichier pour déterminer le format d'export du document.

Vous pouvez également passer une constante du thème Constantes 4D Write Pro dans le paramètre format. Dans ce cas, 4D ajoute l'extension appropriée au nom de fichier si nécessaire. Les formats suivants sont pris en charge :

Constante	Valeur	Comment
wk 4wp	4	Le document 4D Write Pro est sauvegardé dans un format d'archive natif (HTML zippé avec images stockées dans un dossier séparé). Les expressions 4D ne sont pas calculées et les balises 4D spécifiques sont incluses. Ce format est particulièrement approprié pour la sauvegarde et l'archivage de documents 4D Write Pro sur disque sans aucune perte d'informations.
wk docx	7	Extension .docx. Le document 4D Write Pro est sauvegardé sous format Microsoft Word (certifié pour Microsoft Word 2010 et versions plus récentes). Les éléments du document exportés sont les suivants : Corps / en-têtes / pieds de page / sections Page / paramètres d'impression (marges, couleur d'arrière-plan / image, bordures, marges intérieures, taille du papier / orientation) Images - en ligne, ancrée, et format d'image d'arrière-plan (défini avec wk background image) Variables et expressions compatibles (numéro de page, nombre de pages, date, heure, metadonnées). Les variables et expressions non compatibles seront évaluées et figées avant l'export. Signets Notez que certains paramètres de 4D Write Pro peuvent être non disponibles ou fonctionner différemment dans Microsoft Word.
wk mime html	1	Le document 4D Write Pro est sauvegardé au format MIME HTML avec les documents html et les images embarqués en tant que parties MIME (encodées en base64). Les expressions sont calculées et les balises 4D spécifiques sont supprimées. Ce format est particulièrement adapté à l'envoi de mails au format HTML à l'aide de la commande .
wk pdf	5	Extension .pdf. Le document 4D Write Pro est sauvegardé au format PDF, selon le mode de vue Page. Les métadonnées suivantes sont exportées dans un document PDF : Titre Auteur Sujet Créateur de contenu Notes : Les expressions sont automatiquement figées lorsque le document est exporté Les liens vers les méthodes ne sont PAS exportés
wk svg	8	La page du document 4D Write Pro est enregistrée au format SVG, défini sur le mode d'affichage Page. Note : Lors de l'export au format SVG, vous pouvez exporter une seule page à la fois uniquement. Utilisez wk page index pour renseigner la page à exporter.
wk web page complete	2	Extension .htm ou .html. Le document est sauvegardé au format HTML standard et ses ressources sont sauvegardées séparément. Les balises 4D spécifiques sont supprimées et les expressions sont calculées. Ce format est particulièrement adapté à l'affichage d'un document 4D Write Pro dans un navigateur Web.

Notes :

"Balises 4D spécifiques" désigne le XHTML 4D avec namespace 4D et styles CSS 4D.
Pour plus d'informations sur le format de document 4D Write Pro, veuillez vous reporter au paragraphe Format de document .4wp.
Pour consulter la liste des différences ou des incompatibilités connues liées à l'utilisation du format .docx, veuillez lire Exporter au format .docx.
Pour plus d'informations sur l'exportation au format SVG, voir Exporter au format SVG.

Paramètre option

Passez un objet dans option contenant les valeurs définissant les propriétés du document exporté. Les propriétés suivantes sont disponibles :

Constante	Valeur	Comment
wk CID host domain name	cidHostDomain	Nom de domaine hôte : domaine hôte qui sera ajouté aux URLs CID générés comprenant un '@' comme séparateur. Disponible uniquement lorsque le format wk mime html est utilisé.
wk embedded pictures	embeddedPictures	Pour l'export SVG uniquement. Définit si les images sont incorporées dans le fichier .svg exporté lorsque vous appelez WP EXPORT DOCUMENT. Valeurs disponibles : true (par défaut) : les images sont intégrées dans le fichier .svg exporté false : les images sont exportées dans un dossier nommé "filename_images" au niveau du fichier .svg exporté, "filename" étant le nom passé à la commande pour le fichier, sans l'extension. Les images ne sont pas intégrées, mais référencées dans le fichier .svg. A noter que : Si le dossier existe déjà, il est vidé avant l'export du fichier S'il n'y a pas d'image sur la page exportée, le dossier est supprimé
wk factur x	facturX	Uniquement pour l'exportation PDF. Valeur : objet configurant un export PDF "Factur-X (ZUGFeRD)" (voir wk factur x object).
wk files	files	Uniquement pour l'exportation PDF. Valeur : collection d'objets, chacun d'entre eux décrivant un fichier à incorporer dans le document final (voir wk files collection). Cette fonctionnalité n'est prise en charge que dans les documents PDF/A-3 : lorsque l'attribut wk files est utilisé, la version "PDF/A-3" est automatiquement définie (l'attribut wk pdfa version est ignoré). Dans le cas d'un export PDF Factur-X (voir ci-dessous), le premier objet de la collection doit contenir le fichier Factur-X xml.
wk google fonts tag	googleFontsTag	Pour l'export SVG uniquement. Définit la règle d'import pour les polices Google dans le SVG exporté. Valeurs possibles : false (par défaut) : aucune règle d'import de polices Google n'est ajoutée. true : ajoute la règle @import au fichier exporté. Utile si vous souhaitez utiliser des polices qui ne sont pas disponibles par défaut sous Windows ou macOS. Note : Cette propriété est définie sur false par défaut, car lorsqu'elle est activée, les polices Google remplacent les polices natives, et les polices natives ont généralement un meilleur rendu dans le navigateur.
wk HTML pretty print	htmlPrettyPrint	Le code HTML est formaté pour faciliter sa lecture.
wk max picture DPI	maxPictureDPI	Utilisé pour réajuster (réduire) les images à une résolution souhaitée. Pour les images SVG sur Windows, elles sont utilisées pour le tramage. Valeurs par défaut : 300 (pour wk optimized for = wk print) 192 (pour wk optimized for = wk screen) Valeur maximale possible : 1440
wk optimized for	optimizedFor	Définit comment un document exporté est optimisé selon son support. Valeurs possibles : wk print (valeur par défaut pour wk pdf) Les images bitmap peuvent être réajustées à l'aide du DPI défini par wk max picture DPI ou 300 (valeur par défaut) et peuvent être converties en PNG si le codec n'est pas pris en charge par le type d'export. Les images vectorielles sont converties en PNG à l'aide du DPI défini par wk max picture DPI ou 300 (Windows uniquement) Si une image contient plus d'un format, le meilleur format pour l'impression sera utilisé (ex : .tiff au lieu de .jpg) wk screen (valeur par défaut pour wk web page complete et wk mime html) Les images bitmap peuvent être réajustées à l'aide du DPI défini par wk max picture DPI ou 192 (valeur par défaut) et peuvent être converties en JPEG (images opaques) ou en PNG (images transparentes) si le codec n'est pas pris en charge par le type d'export. Les images vectorielles sont converties en PNG à l'aide du DPI défini par wk max picture DPI ou 192 (Windows uniquement) Si une image contient plus d'un format, le meilleur format pour le rendu écran sera utilisé
wk page index	pageIndex	Pour l'export SVG uniquement. Index de la page à exporter au format svg (la valeur par défaut est 1). L'index des pages commence à 1 pour la première page du document. Note : l'index des pages est indépendant de la numérotation des pages.
wk pdfa version	pdfaVersion	Exporte un fichier PDF conforme à une version du format PDF/A. Pour plus d'informations sur les propriétés et les versions du PDF/A, veuillez consulter la page PDF/A sur Wikipedia. Valeurs possibles : wk pdfa2 : Exporte vers la version "PDF/A-2" wk pdfa3 : Exporte vers la version "PDF/A-3" Note : Sur macOS, wk pdfa2 peut exporter vers PDF/A-2 ou PDF/A-3 ou plus, en fonction de la mise en œuvre de la plateforme. Ainsi, wk pdfa3 veut dire "exporte au moins au format PDF/A-3". Sous Windows, le fichier PDF de sortie sera toujours conforme à la norme souhaitée.
wk recompute formulas	recomputeFormulas	Définit si les formules doivent être recalculées lorsqu'elles sont exportées. Valeurs possibles : vrai- Valeur par défaut. Toutes les formules sont recalculées faux- Ne recalcule pas les formules
wk visible background and anchored elements	visibleBackground	Affiche ou exporte les images de fond, la couleur de fond, les images ancrées et les zones de texte (pour l'affichage, effet visible uniquement en mode d'affichage Page ou Inclus). Valeurs possibles : True/False
wk visible empty images	visibleEmptyImages	Affiche ou exporte un rectangle noir par défaut pour les images qui ne peuvent pas être chargées ou calculées (images vides ou images sous un format non pris en charge). Valeurs possibles : True/False. Valeur par défaut : True Si la valeur est False, les éléments d'image manquants ne seront pas affichés du tout, même s'ils ont des bordures, une largeur, une hauteur ou un arrière-plan ; cela peut avoir une incidence sur la mise en page des images en ligne.
wk visible footers	visibleFooters	Affiche ou exporte les pieds de page (pour l'affichage, effet visible uniquement en mode d'affichage Page). Valeurs possibles : True/False
wk visible headers	visibleHeaders	Affiche ou exporte les en-têtes (pour l'affichage, effet visible uniquement en mode d'affichage Page). Valeurs possibles : True/False
wk visible references	visibleReferences	Affiche ou exporte toutes les expressions 4D insérées dans le document en tant que références. Valeurs possibles : True/False

Le tableau suivant indique l'option disponible par format d'export :

	wk 4wp	wk docx	wk mime html	wk pdf	wk web page html 4D	wk svg
wk CID host domain name	-	-		-	-	-
wk HTML pretty print	(par défaut : faux)	-	(par défaut : Faux)	(par défaut : Faux)	(par défaut : Faux)	(par défaut : faux)
wk max picture DPI	-	toujours 300		(par défaut : 300)	-	(par défaut : 300)
wk optimized for	-	toujours wk print	(par défaut :wk screen)	toujours wk print	-	(par défaut : wk print)
wk recompute formulas	-	(par défaut : vrai)	(par défaut : vrai)	(par défaut : vrai)	-	(par défaut : vrai)
wk visible background and anchored elements	-	(par défaut : vrai)	toujours vrai	(par défaut : vrai)	-	(par défaut : vrai)
wk visible footers	-	toujours vrai	toujours faux	(par défaut : vrai)	-	(par défaut : vrai)
wk visible headers	-	toujours vrai	toujours faux	(par défaut : vrai)	-	(par défaut : vrai)
wk visible empty images		(par défaut : vrai)	(par défaut : vrai)	(par défaut : vrai)		(par défaut : vrai)
wk visible references	-	-	-	(par défaut : faux)	-	(par défaut : faux)
wk pdfa version	-	-	-		-	-
wk factur x	-	-	-		-	-
wk files	-	-	-		-	-
wk page index	-	-	-	-	-	(par défaut : 1)
wk embedded pictures	-	-	-	-	-	(par défaut : vrai)
wk google fonts tag	-	-	-	-	-	(par défaut : faux)

Note de compatibilité : Passer une valeur entier long dans option est pris en charge pour des raisons de compatibilité, mais il est recommandé d'utiliser un paramètre objet.

collection wk files

La propriété wk files permet d'exporter un PDF avec des pièces jointes. Cette propriété doit contenir une collection d'objets décrivant les fichiers à inclure dans le document final. Chaque objet de la collection peut contenir les propriétés suivantes :

Propriété	Type	Description
name	Texte	Nom du fichier. Facultatif si la propriété file est utilisée, auquel cas le nom est déduit par défaut du nom du fichier. Obligatoire si la propriété data est utilisée (sauf pour le premier fichier d'une exportation Factur-X, auquel cas le nom du fichier est automatiquement "factur-x.xml", voir ci-dessous).
description	Texte	Facultatif. Si elle est omise, la valeur par défaut du premier fichier d'exportation vers Factur-X est "Factur-X/ZUGFeRD Invoice", sinon elle est vide.
mimeType	Texte	Facultatif. Si elle est omise, la valeur par défaut peut généralement être devinée à partir de l'extension du fichier ; sinon, "application/octet-stream" est utilisé. Si cette option est activée, assurez-vous d'utiliser un type mime ISO, sinon le fichier exporté risque d'être invalide.
data	Texte ou BLOB	Obligatoire si la propriété file est manquante
file	objet 4D.File	Obligatoire si la propriété data est manquante, sinon ignorée.
relationship	Texte	Facultatif. Si elle est omise, la valeur par défaut est "Data". Valeurs possibles pour le premier fichier de Factur-X : pour les profils BASIC, EN 16931 ou EXTENDED : "Alternative", "Source" ou " Data" ("Alternative" uniquement pour la facture allemande) pour les profils MINIMUM et BASIC WL : " Data " uniquement. pour les autres profils : "Alternative", "Source" ou " Data" (avec des restrictions éventuelles en fonction du pays : voir la spécification du profil pour plus d'informations sur les autres profils - par exemple, pour le profil RECHNUNG, seul le profil "Alternative" est autorisé). pour les autres fichiers (sauf le fichier xml de la facture Factur-X) : "Alternative", "Source", " Data", "Supplement" ou "Unspecified". toute autre valeur génère une erreur.

Si le paramètre option contient également une propriété wk factur x, le premier élément de la collection wk files doit être le fichier xml de la facture Factur-X (ZUGFeRD) (voir ci-dessous).

Note : Les pièces jointes en format PDF ne sont prises en charge que par la version "PDF/A-3". Lorsque vous transmettez la propriété wk files, la version "PDF/A-3" est automatiquement utilisée.

objet wk factur x

La propriété wk factur x est un objet qui peut contenir jusqu'à deux propriétés :

Propriété	Type	Description
profile	Texte	Facultatif pour les profils standard, obligatoire sinon. S'il est omis, le profil (profile) est déterminé à partir du texte ou du fichier xml fourni (qui doit utiliser un profil standard). S'il est passé, il peut s'agir d'un nom de profil non standard (pour utiliser d'autres profils - par exemple RECHNUNG). Note : Les noms de profil standard sont : MINIMUM, BASIC WL, BASIC, EN 16931 (alias COMFORT), EXTENDED.
version	Texte	Facultatif. La valeur par défaut est "1.0"

À propos des documents PDF Factur-X / ZUGFeRD

Factur-X / ZUGFeRD est une norme européenne pour les factures électroniques hybrides (PDF pour les utilisateurs et données XML pour l'automatisation des processus). Pour plus d'informations, veuillez lire cet article de blog.

Pour déclencher une exportation PDF "Factur-X", passez les propriétés wk factur x et wk files dans le paramètre option (voir exemple 5). Dans ce cas :

un PDF Factur-X (ZUGFeRD) est généré,
le premier élément de la collection wk files est utilisé comme fichier xml Factur-X,
si la propriété wk files est manquante ou contient une collection vide, ou si son premier élément n'est pas un fichier xml, une erreur est générée.

Note : Pour un exemple détaillé de la mise en œuvre de l'exportation Factur-X / ZUGFeRD, vous pouvez télécharger ce projet HDI 4D.

Exemple 1

Vou souhaitez exporter le contenu de l'objet 4D Write Pro myArea aux formats HTML et PDF :

  // exporter HTML

 var $option : Object

 $option:=Creer object

 

 $option[wk recompute formulas]:=False

 $option[wk HTML pretty print]:=False

 $option[wk optimized for]:=wk print

 $option[wk max picture DPI]:=600 //remplacer la valeur par défaut pour l'impression (300 DPI)

 

 WP EXPORT DOCUMENT(myArea;$path;wk web page complete;$option)

 

  //exporter PDF

 var $option : Object

 $option:=Creer object

 

 $option[wk visible headers]:=True

 $option[wk visible footers]:=True

 $option[wk visible background]:=True

 $option[wk max picture DPI]:=96 //remplacer la valeur par défaut pour l'écran (192 DPI) pour limiter la taille du document

 $option[wk optimized for]:=wk screen

 $option[wk recompute formulas]:=True

 

 WP EXPORT DOCUMENT(myArea;$path;wk pdf;$option)

Exemple 2

Vous souhaitez exporter le contenu de l'objet 4D Write Pro myArea dans le format .4wp :

 C_TEXT($path)

 C_LONGINT($docRef)

 

 Case of

    :(Form event code=On Clicked)

 

       $path:=Get 4D folder(Database folder)+"Export"+Séparateur dossier

       $path:=Select document($path;".4wp";" title";Saisie nom de fichier)

 

       If($path#"")

          WP EXPORT DOCUMENT(myArea;document;wk 4wp;wk normal)

       Else

          ALERT("An error occurred.")

       End if

 End case

Exemple 3

Pour exporter la deuxième page du document en SVG et exporter les images depuis le document :

 var $options : Object

 

 $options:=New object

 $options[wk embedded pictures]:=false

 $options[wk page index]:=2

 

 WP EXPORT DOCUMENT(WPArea;"my exported document";wk svg;$options)

Exemple 4

Exportation d'un document PDF conforme à la norme PDF/A-2 :

 var $options: Object:={}

 $options[wk visible empty images] :=False

 $options[wk pdfa version]:=wk pdfa2 // conformité "PDF/A-2"

 WP EXPORT DOCUMENT(wpDoc;"invoice.pdf";wk pdf;$options)

Exemple 5

Exemples d'exportations PDF de Factur-X :

  //BASIC (profil standard)

 var $options;$fileInfo : Object

 $options:={}

 $options[wk factur x]:={}

 $options[wk factur x].profile:="BASIC"

 $options[wk factur x].version:="1.0"

 

 $fileInfo:={}

 $fileInfo.file:=$file  //$file est un 4D.File avec un fichier .xml comme cible

 $options[wk files]:=[$fileInfo]

 

 WP EXPORT DOCUMENT(wpDoc;"facturX_basic.pdf";wk pdf;$options)

 

  //Profil RECHNUNG (profil personnalisé)

 $options:={}

 $options[wk factur x]:={}

 $options[wk factur x].profile:="RECHNUNG"

 $options[wk factur x].version:="2.1" //dernière version pour RECHNUNG

 

 $fileInfo:={}

 $fileInfo.file:=$file  //$file est un 4D.File avec un fichier .xml comme cible

 $fileInfo.name:="rechnung.xml" //Nom de fichier obligatoire dans le PDF pour RECHNUNG

 $fileInfo.relationship:="Alternative" //obligatoire pour l'Allemagne

 $fileInfo.description:="ZUGFeRD Rechnung"

 $options[wk files]:=[$fileInfo]</p><p>WP EXPORT DOCUMENT(wpDoc;"facturX_rechnung.pdf";wk pdf;$options)

Voir aussi

4D QPDF (Component) - PDF Get attachments
Blog post - 4D Write Pro: Electronic invoice generation
Blog post - 4D Write Pro: Export to PDF with enclosures
Exporter au format .docx
Exporter au format SVG
Exporter aux formats HTML et MIME HTML
WP EXPORT VARIABLE