WP EXPORT DOCUMENT

4D v20 R7

WP EXPORT DOCUMENT


WP EXPORT DOCUMENT ( docWP ; rutaArchivo {; format {; opciones}} )

Parámetro	Tipo	Descripción
docWP	Objeto	Variable 4D Write Pro
rutaArchivo	Cadena	Ruta del archivo exportado
format	Entero largo	Formato de salida del documento
opciones	Objeto, Entero largo	Opciones de exportar

Descripción

El comando WP EXPORT DOCUMENT exporta el objeto 4D Write Pro docWP en un documento en el disco definido por el parámetro rutaArchivo así como también los parámetros opcionales.

En docWP, pase el objeto 4D Write Pro que desea exportar.

En rutaArchivo, pase la ruta de destino y el nombre del documento a exportar. Si pasa sólo el nombre del documento, se guardará en el mismo nivel que el archivo de estructura de 4D.

Puede omitir el parámetro formato, en cuyo caso deberá especificar la extensión en rutaArchivo. También puede pasar una constante del tema Constantes 4D Write Pro en el parámetro format. En este caso, 4D añade la extensión correspondiente al nombre de archivo si es necesario. Los siguientes formatos son soportados:

Constante	Valor	Comentario
wk 4wp	4	El documento 4D Write Pro se guarda en un formato de archivo nativo (HTML comprimido con imágenes almacenadas en una carpeta separada). Las expresiones 4D no se calculan y las etiquetas 4D especificas se incluyen. Este formato es especialmente adecuado para guardar y archivar documentos 4D Write Pro en el disco sin ninguna pérdida.
wk docx	7	Extensión .docx. El documento 4D Write Pro se guarda en formato Microsoft Word (certificado para Microsoft Word 2010 y posteriores). Las partes del documento exportadas son: Cuerpo / encabezados / pies de página / secciones Configuración de página / impresión (márgenes, color / imagen de fondo, bordes, relleno, tamaño / orientación del papel) Imágenes: patrón en línea, anclado y de fondo (definido con wk background image) Variables y expresiones compatibles (número de página, número de páginas, fecha, hora, metadatos). Las variables y expresiones no compatibles se evaluarán y congelarán antes de la exportación. Marcadores Tenga en cuenta que algunas configuraciones de 4D Write Pro pueden no estar disponibles o pueden comportarse de manera diferente en Microsoft Word.
wk mime html	1	El documento 4D Write Pro se guarda como MIME HTML con documentos los documentos html y las imágenes embebidas como partes MIME (codificado en base 64). Las expresiones se calculan ylas etiquetas 4D específicas se eliminan. Este formato es especialmente adecuado para el envío de mensajes de correo electrónico HTML con el comando .
wk pdf	5	Extensión .pdf. El documento 4D Write Pro se guarda en formato PDF, en función del modo de vista Página. Los siguientes metadatos se exportan en un documento PDF: Título Autor Asunto Creador de contenido Notas: Las expresiones se congelan automáticamente cuando se exporta el documento Los enlaces a los métodos NO se exportan
wk svg	8	La página del documento 4D Write Pro se guarda en formato SVG, según el modo de vista Página. Nota: al exportar a SVG, sólo puede exportar una página a la vez. Utilice el botón wk page index para especificar la página a exportar.
wk web page complete	2	Extensión .htm o .html. El documento se guarda como HTML estándar y sus recursos se guardan por separado. Las etiquetas 4D específicas se eliminan y las expresiones se calculan. Este formato es especialmente adecuado cuando se quiere mostrar un documento 4D Write Pro en un navegador web.

Notas:

"Etiquetas 4D específicas" significa el XHTML 4D con namespace y estilos CSS 4D.
Para mayor información sobre el formato 4D Write Pro, consulte Formato del documento .4wp
Para ver una lista de diferencias conocidas o incompatibilidad al utilizar el formato .docx, ver Importar y Exportar al formato .docx.

Parámetro opcion

Pase un objeto en la opcion que contiene los valores para definir las propiedades del documento exportado. Las siguientes propiedades están disponibles:

Constante	Valor	Comentario
wk CID host domain name	cidHostDomain	Nombre de dominio host CID: dominio de host que se agregará a las URLs CID generadas, incluida una '@' como separador. Disponible solo cuando se utiliza el formato wk mime html.
wk embedded pictures	embeddedPictures	Sólo para la exportación SVG. Define si las imágenes se anidan en el archivo .svg exportado cuando se llama a WP EXPORT DOCUMENT. Valores disponibles: true (por defecto): las imágenes se anidan en el archivo .svg exportado false: las imágenes se exportan en una carpeta llamada "filename_images" al nivel del archivo .svg exportado, siendo "filename" el nombre pasado al comando para el archivo, sin la extensión. Las imágenes no están anidadas, sino referenciadas en el archivo .svg. Tenga en cuenta que: Si la carpeta ya existe, se vacía antes de exportar el archivo Si no hay ninguna imagen en la página exportada, la carpeta se borra
wk factur x	facturX	Sólo para exportación a PDF. Valor: objeto que configura una exportación PDF "Factur-X (ZUGFeRD)" (ver objectwk factur x ).
wk files	files	Sólo para exportación a PDF. Valor: colección de objetos, cada uno de los cuales describe un archivo que se integrará en el documento final (ver colección wk files ). Esta funcionalidad sólo se soporta en documentos PDF/A-3: cuando se utiliza el atributo wk files, se establece automáticamente la versión "PDF/A-3" (se ignora el atributo wk pdfa version). En el caso de una exportación Factur-X PDF ( ver más abajo), el primer objeto de la colección debe contener el archivo Factur-X xml.
wk google fonts tag	googleFontsTag	Sólo para la exportación SVG. Define la regla de importación para las fuentes de Google en el SVG exportado. Valores posibles: false (por defecto): no se añade ninguna regla de importación de Google fonts. true: añade la regla de @importación al archivo exportado. Es útil si quiere utilizar fuentes que no están disponibles por defecto en Windows o macOS. Nota: esta propiedad está definida como falsa por defecto porque cuando está activa, las fuentes de Google anulan las fuentes nativas, y las fuentes nativas generalmente se renderizan mejor en el navegador.
wk HTML pretty print	htmlPrettyPrint	El código HTML está formateado para facilitar su lectura.
wk max picture DPI	maxPictureDPI	Se utiliza para volver reajustar (reducir) las imágenes a la resolución preferida. Para imágenes SVG en Windows, utilizadas para rasterización. Valores predeterminados: 300 (for wk optimized for = wk print) 192 (for wk optimized for = wk screen) Valor máximo posible: 1440
wk optimized for	optimizedFor	Define cómo se optimiza un documento exportado según su soporte. Valores posibles: wk print (valor predeterminado para wk pdf y wk svg) Las imágenes mapa de bits pueden reducirse utilizando el DPI definido por wk max picture DPI o 300 (valor predeterminado) y pueden convertirse a PNG si el códec no es compatible con el tipo de exportación. Las imágenes vectoriales se convierten a PNG utilizando el DPI definido por wk max picture DPI o 300 (Windows únicamente) Si una imagen contiene más de un formato, se utiliza el mejor formato para imprimir (por ejemplo, .tiff o .jpg) wk screen (valor predeterminado para wk web page complete y wk mime html) Las imágenes mapa de bits pueden reducirse utilizando el DPI definido por wk max picture DPI o 192 (valor predeterminado) y pueden convertirse a JPEG (imágenes opacas) o PNG (imágenes transparentes) si el códec no es soportado por el tipo de exportación. Las imágenes vectoriales se convierten a PNG utilizando el DPI definido por wk max picture DPI o 192 (Windows únicamente) Si una imagen contiene más de un formato, se utilizará el mejor formato para la representación en pantalla Nota: los documentos exportados en formato wk docx siempre se optimizan para wk print (se ignora la opción wk optimized for).
wk page index	pageIndex	Sólo para la exportación SVG. Índice de la página a exportar a formato svg (por defecto es 1). El índice de la página comienza en 1 para la primera página del documento. Nota: el índice de páginas es independiente de la numeración de páginas.
wk pdfa version	pdfaVersion	Exporta PDF conforme a una versión PDF/A. Para más información sobre las propiedades y versiones de PDF/A, consulte la página PDF/A en Wikipedia. Valores posibles: wk pdfa2: exporta a la versión "PDF/A-2" wk pdfa3: exporta a la versión "PDF/A-3" Nota: en macOS, wk pdfa2 puede exportar a PDF/A-2 o PDF/A-3 o superior, dependiendo de la implementación de la plataforma. Además, wk pdfa3 significa "exporta al menos a PDF/A-3". En Windows, el archivo PDF de salida siempre será igual a la conformidad deseada.
wk recompute formulas	recomputeFormulas	Define si las fórmulas deben recalcularse cuando se exportan. Valores posibles: true - Valor por defecto. Todas las fórmulas son recalculadas false- No recalcula las fórmulas
wk visible background and anchored elements	visibleBackground	Muestra o exporta imágenes/color de fondo, imágenes ancladas y cajas de texto (para visualización, efecto visible solo en el modo de vista de página o anidado). Valores posibles: True/False
wk visible empty images	visibleEmptyImages	Muestra o exporta un rectángulo negro por defecto para las imágenes que no pueden ser cargadas o calculadas (imágenes vacías o en un formato no soportado). Valores posibles: True/False. Valor por defecto: True Si el valor es False, los elementos imagen que falten no se mostrarán en absoluto aunque tengan bordes, ancho, alto o fondo; esto puede afectar al diseño de la página para las imágenes en línea.
wk visible footers	visibleFooters	Muestra los pies de página (efecto visible solo en el modo de visualización de página). Valores posibles: Verdadero/Falso
wk visible headers	visibleHeaders	Muestra los encabezados (efecto visible solo en el modo de visualización de página). Valores posibles: Verdadero/Falso
wk visible references	visibleReferences	Muestra todas las expresiones 4D insertadas en el documento como referencias. Valores posibles: Verdadero/Falso

La siguiente tabla indica la opcion disponible por formato de exportación:

	wk 4wp	wk docx	wk mime html	wk pdf	wk web page html 4D	wk svg
wk CID host domain name	-	-		-	-	-
wk HTML pretty print	(default: false)	-	(por defecto: False)	(por defecto: False)	(por defecto: False)	(por defecto: false)
wk max picture DPI	-	siempre 300		(por defecto: 300)	-	(por defecto: 300)
wk optimized for	-	siempre wk print	(por defecto: wk screen)	siempre wk print	-	(por defecto: wk print)
wk recompute formulas	-	(por defecto: true)	(por defecto: true)	(por defecto: true)	-	(por defecto: true)
wk visible background and anchored elements	-	siempre true	siempre true	(por defecto: true)	-	(por defecto: true)
wk visible footers	-	siempre true	siempre false	(por defecto: true)	-	(por defecto: true)
wk visible headers	-	siempre true	siempre false	(por defecto: true)	-	(por defecto: true)
wk visible empty images	-	(por defecto: true)	(por defecto: true)	(por defecto: true)	-	(por defecto: true)
wk visible references	-	-	-	(por defecto: false)	-	(por defecto: false)
wk pdfa version	-	-	-		-	-
wk factur x	-	-	-		-	-
wk files	-	-	-		-	-
wk page index	-	-	-	-	-	(por defecto: 1)
wk embedded pictures	-	-	-	-	-	(por defecto: true)
wk google fonts tag	-	-	-	-	-	(por defecto: false)

colección wk files

La propiedad wk files permite exportar un PDF con archivos adjuntos. Esta propiedad debe contener una colección de objetos que describan los archivos que se anidarán en el documento final. Cada objeto de la colección puede contener las siguientes propiedades:

Propiedad	Tipo	Descripción
name	Text	Nombre del archivo. Opcional si se utiliza la propiedad file, en cuyo caso el nombre se infiere por defecto a partir del nombre del archivo. Obligatorio si se utiliza la propiedad data ((excepto para el primer archivo de una exportación Factur-X, en cuyo caso el nombre del archivo es automáticamente "factur-x.xml", ver más abajo).
description	Text	Opcional. Si se omite, el valor por defecto para el primer archivo de exportación a Factur-X es "Factur-X/Factura ZUGFeRD", en caso contrario estará vacío.
mimeType	Text	Opcional. Si se omite, el valor predeterminado se puede adivinar normalmente a partir de la extensión del archivo; de lo contrario, se utiliza "application/octet-stream". Si se pasa, asegúrese de utilizar un tipo mime ISO, de lo contrario el archivo exportado podría no ser válido.
data	Text o BLOB	Obligatorio si falta la propiedad file
file	Objeto 4D.File	Obligatorio si falta la propiedad data, ignorado en caso contrario.
relationship	Text	Opcional. Si se omite, el valor predeterminado es "Data". Valores posibles para el primer archivo Factur-X: para perfiles BASIC, EN 16931 o EXTENDED: "Alternative", "Source" o "Data" ("Alternative" solo para factura German ) para perfiles MINIMUM y BASIC WL: "Data" únicamente. para otros perfiles: "Alternative", "Source" o "Data" (con restricciones, quizás dependiendo del país: consulte la especificación del perfil para obtener más información sobre otros perfiles (por ejemplo, para el perfil RECHNUNG solo se permite "Alternative") para otros archivos (excepto el archivo xml de factura Factur-X): "Alternative", "Source", "Data", "Supplement" o "Unspecified" cualquier otro valor genera un error.

Si el parámetro opcion también contiene una propiedad wk factur x, entonces el primer elemento de la colección wk files debe ser el archivo xml de factura Factur-X (ZUGFeRD) (ver más abajo).

Nota: los archivos adjuntos en PDF solo son compatibles con la versión PDF/A-3. Cuando pasa la propiedad wk files, la versión "PDF/A-3" se utiliza automáticamente.

objectwk factur x

La propiedad wk factur x es un objeto que puede contener hasta dos propiedades:

Propiedad	Tipo	Descripción
profile	Text	Opcional para perfiles estándar, de lo contrario obligario. Si se omite, el perfil (profile) se determina a partir del texto o del archivo xml suministrado (que debe utilizar un perfil estándar). Si se pasa, puede ser un nombre de perfil no estándar (para utilizar otros perfiles - por ejemplo RECHNUNG). Nota: los nombres de perfil estándar son:: MINIMUM, BASIC WL, BASIC, EN 16931 (alias COMFORT), EXTENDED.
version	Text	Opcional. El valor por defecto es "1.0"

Acerca de documentos PDF Factur-X / ZUGFeRD

Factur-X / ZUGFeRD es un estándar europeo para facturas electrónicas híbridas (PDF para usuarios y datos XML para automatización de procesos). Para más información, por favor lea esta entrada de blog.

Para activar una exportación PDF "Factur-X", pase las propiedades wk factur x y wk files en el parámetro opcion (ver el Ejemplo 5). En este caso:

se genera un PDF Factur-X (ZUGFeRD),
el primer elemento de la colección wk files se utiliza como archivo xml Factur-X,
si la propiedad wk files falta o contiene una colección vacía, o si su primer elemento no es un archivo xml, se genera un error.

Nota: para ver un ejemplo detallado de la implementación de la exportación Factur-X / ZUGFeRD, puede descargar este proyecto HDI 4D.

Ejemplo 1

Desea exportar el contenido del objeto myArea 4D Write Pro en formato HTML y PDF:

  // exportar HTML

 var $option : Object

 $option:=New object

 

 $option[wk recompute formulas]:=False

 $option[wk HTML pretty print]:=False

 $option[wk optimized for]:=wk print

 $option[wk max picture DPI]:=600 //remplazar el valor predeterminado para la impresión (300 DPI)

 

 WP EXPORT DOCUMENT(myArea;$path;wk web page complete;$option)

 

  //exportar PDF

 var $option : Object

 $option:=New object

 

 $option[wk visible headers]:=True

 $option[wk visible footers]:=True

 $option[wk visible background]:=True

 $option[wk max picture DPI]:=96 //remplazar el valor predeterminado para la pantalla (192 DPI) para limitar el tamaño del documento

 $option[wk optimized for]:=wk screen

 $option[wk recompute formulas]:=True

 

 WP EXPORT DOCUMENT(myArea;$path;wk pdf;$option)

Ejemplo 2

Usted quiere exportar los contenidos del objeto 4D Write Pro myArea en el formato .4wp:

 C_TEXT($path)

 C_LONGINT($docRef)

 

 Case of

    :(Form event code=On Clicked)

 

       $path:=Get 4D folder(Database folder)+"Export"+Folder separator

       $path:=Select document($path;".4wp";" title";File name entry)

 

       If($path#"")

          WP EXPORT DOCUMENT(myArea;document;wk 4wp)

       End if

 End case

Ejemplo 3

Para exportar la segunda página del documento como SVG y exportar las imágenes del documento:

 var $options : Object

 

 $options:=New object

 $options[wk embedded pictures]:=False

 $options[wk page index]:=2

 

 WP EXPORT DOCUMENT(WPArea;"my exported document";wk svg;$options)

Ejemplo 4

Exportar un documento PDF con conformidad PDF/A-2:

 var $options: Object:={}

 $options[wk visible empty images] :=False

 $options[wk pdfa version]:=wk pdfa2 // conformidad "PDF/A-2"

 WP EXPORT DOCUMENT(wpDoc;"invoice.pdf";wk pdf;$options)

Ejemplo 5

Ejemplos de exportaciones Factur-X PDF:

  //BASIC (perfil estándar)

 var $options;$fileInfo : Object

 $options:={}

 $options[wk factur x]:={}

 $options[wk factur x].profile:="BASIC"

 $options[wk factur x].version:="1.0"

 

 $fileInfo:={}

 $fileInfo.file:=$file  //$file es un 4D.File con un archivo .xml como objetivo

 $options[wk files]:=[$fileInfo]

 

 WP EXPORT DOCUMENT(wpDoc;"facturX_basic.pdf";wk pdf;$options)

 

  //RECHNUNG profile (custom profile)

 $options:={}

 $options[wk factur x]:={}

 $options[wk factur x].profile:="RECHNUNG"

 $options[wk factur x].version:="2.1" //última versión para RECHNUNG

 

 $fileInfo:={}

 $fileInfo.file:=$file  //$file es un 4D.File con un archivo .xml como objetivo

 $fileInfo.name:="rechnung.xml" //nombre de archivo obligatorio en PDF para RECHNUNG 

 $fileInfo.relationship:="Alternative" //obligatorio para Alemania

 $fileInfo.description:="ZUGFeRD Rechnung"

 $options[wk files]:=[$fileInfo]

 

 WP EXPORT DOCUMENT(wpDoc;"facturX_rechnung.pdf";wk pdf;$options)

Ver también

Exportación a formatos HTML y MIME HTML
4D QPDF (Component) - PDF Get attachments
Blog post - 4D Write Pro: Electronic invoice generation
Blog post - 4D Write Pro: Export to PDF with enclosures
Exportar a formato SVG
Importar y Exportar al formato .docx
WP EXPORT VARIABLE