QR ETAT

4D v19.8

QR ETAT


QR ETAT ( {laTable ;} nomFichier {; nomMéthode}{; *} )

Paramètre	Type	Description
laTable	Table	Table à utiliser ou Table par défaut si ce paramètre est omis
nomFichier	Chaîne	Document d'état rapide à charger
nomMéthode	Chaîne	Nom de la méthode à appeler
*	Opérateur	Suppression des boîtes de dialogue d'impression

Description

La commande QR ETAT imprime un état pour laTable, à l'aide de l'Editeur d'états rapides de 4D. Cet éditeur permet à l'utilisateur de construire en totalité son propre état. Pour plus d'informations sur la création d'états à l'aide de l'Editeur d'états rapides, reportez-vous à la section Etats rapides dans le manuel Mode Développement de 4D.

Notes :

L'éditeur n'apparaît pas si la laTable a été déclarée “Invisible”.
Lorsque l'éditeur est appelé via la commande QR ETAT, les liens entre les tables conservent leur statut manuel, le cas échéant. Ce principe permet au développeur de gérer lui-même ce statut à l'aide des commandes FIXER LIENS AUTOMATIQUES et FIXER LIEN CHAMP. Toutefois, n'oubliez pas que les automatismes sont désactivés lorsque les tables liées sont visualisées dans un formulaire liste affiché à l'aide de VISUALISER SELECTION, MODIFIER SELECTION ou d'un sous-formulaire. Voir Liens manuels et automatiques.
L'éditeur est appelé dans une fenêtre externe, il n'est pas possible d'utiliser la commande QR APPELER SUR COMMANDE dans ce contexte. Vous pouvez cependant utiliser le paramètre nomMéthode afin d'exécuter du code personnalisé lorsqu'une commande d'interface est activée (cf. ci-dessous).

Le paramètre nomFichier désigne un modèle d'état créé dans l'éditeur d'états rapides et sauvegardé sur disque. Le document stocke les paramètres de l'état, pas les enregistrements. Si une chaîne vide ("") est passée dans nomFichier, QR ETAT affiche une boîte de dialogue d'ouverture de fichiers, dans laquelle l'utilisateur peut choisir un modèle d'état à imprimer.
Si le paramètre nomFichier spécifie un document qui n'existe pas (si vous passez, par exemple, Caractere(1) dans nomFichier), l'éditeur d'états rapides s'affiche.

Le paramètre nomMéthode désigne une méthode projet 4D qui sera exécutée chaque fois qu'une commande de gestion de documents de l'éditeur d'états rapides sera appelée via un clic sur un bouton. L'utilisation de ce paramètre équivaut à l'utilisation de QR APPELER SUR COMMANDE dans la fenêtre de l'éditeur d'états rapides (QR APPELER SUR COMMANDE fonctionne uniquement pour une une zone intégrée). Par exemple, vous pouvez utiliser ce paramètre pour modifier le jeu de caratètres utilisé par l'état rapide. La méthode nomMéthode reçoit deux paramètres :

Paramètre

Type

Description

Entier long

Référence de la zone

Entier long

Numéro de la commande sélectionnée. À comparer avec les constantes suivantes du thème QR Commandes (seuls les événements listés sont pris en charge) :

Constante	Valeur	Comment
qr cmd apercu	2007
qr cmd enregistrer	2002
qr cmd enregistrer sous	2003
qr cmd executer	2008	Utilisation de la commande QR EXECUTER conseillée
qr cmd mise en page	2006
qr cmd ouvrir	2001

Note : Si vous souhaitez compiler votre base de données, vous devez déclarer explicitement les paramètres $1 et $2 comme entiers longs, même si vous ne les utilisez pas.

Si vous souhaitez exécuter la commande initiale choisie par l'utilisateur, saisissez l'instruction suivante dans la méthode nomMéthode :

QR EXECUTER COMMANDE($1;$2)

Si le paramètre nomMéthode est une chaîne vide ("") ou est omis, aucune méthode n'est appelée et l'opération standard de QR ETAT est appliquée.

Une fois qu'un fichier d'état est sélectionné, les boîtes de dialogue d'impression s'affichent, sauf si le paramètre * a été spécifié — dans ce cas, elles ne s'affichent pas. L'état est alors imprimé.

Lorsque l'Editeur d'états rapides n'est pas affiché, la variable système OK prend la valeur 1 si un état est imprimé ; sinon elle prend la valeur 0 (zéro) — par exemple si l'utilisateur a cliqué sur Annuler dans les boîtes de dialogue d'impression.

4D Server : Cette commande peut être exécutée sur 4D Server dans le cadre d'une procédure stockée. Dans ce contexte :

Veillez à ce qu’aucune boîte de dialogue n’apparaisse sur le poste serveur (sauf besoin spécifique). Pour cela, il est nécessaire d’appeler la commande avec le paramètre *.
La syntaxe faisant apparaître l‘éditeur d'états rapide ne fonctionne pas avec 4D Server, dans ce cas la variable système OK prend la valeur 0.
En cas de problème sur l’imprimante (plus de papier, imprimante déconnectée, etc.), aucun message d'erreur n'est généré.

Exemple 1

L'exemple suivant permet à l'utilisateur d'effectuer une recherche dans la table [Personnes], puis imprime automatiquement l'état "Liste détaillée" :

 CHERCHER([Personnes])

 Si(OK=1)

    QR ETAT([Personnes];"Liste détaillée";*)

 Fin de si

Exemple 2

L'exemple suivant permet à l'utilisateur d'effectuer une recherche dans la table [Personnes], puis de sélectionner le document d'état qui sera ensuite utilisé pour l'impression :

 CHERCHER([Personnes])

 Si(OK=1)

    QR ETAT([Personnes];"")

 Fin de si

Exemple 3

L'exemple suivant permet à l'utilisateur d'effectuer une recherche dans la table [Personnes], puis affiche l'Editeur d'états rapides afin que l'utilisateur puisse construire, charger, sauvegarder ou imprimer tout état :

 CHERCHER([Personnes])

 Si(OK=1)

    QR ETAT([Personnes];Caractere(1))

 Fin de si

Exemple 4

Reportez-vous à l'exemple de la commande FIXER LIEN CHAMP.

Exemple 5

Vous souhaitez convertir le jeu de caractères utilisé dans un état rapide appelé via QR ETAT en Mac Roman :

QR ETAT([MaTable];Caractere(1);"maCallbackMeth")

La méthode maCallbackMeth convertit l’état lorsqu’il est généré :

 C_ENTIER LONG($1;$2)

 Si($2=qr cmd executer) //si on a généré un état

    C_BLOB($myblob)

    C_TEXTE($path;$text)

    C_ENTIER LONG($type)

    QR EXECUTER COMMANDE($1;$2) //exécution de la commande

    QR LIRE DESTINATION($1;$type;$path) //récupération de la destination

    Si(($type=qr fichier HTML)|$type=qr fichier texte))

       DOCUMENT VERS BLOB($path;$myblob)

  //conversion vers un texte en utilisant UTF-8

       $text:=Convertir vers texte($myblob;"UTF-8")

  //utilisation du jeu MacRoman

       CONVERTIR DEPUIS TEXTE($text;"MacRoman";$myblob)

  //Renvoi de l’état converti

       BLOB VERS DOCUMENT($path;$myblob)

    Fin de si

 Sinon //sinon exécution de la commande

    QR EXECUTER COMMANDE($1;$2)

 Fin de si

Voir aussi

FIXER METHODES AUTORISEES
IMPRIMER ETIQUETTES
IMPRIMER SELECTION