collection.countValues( )

4D v19.8


collection.countValues ( valor {; rotaProp} ) -> Resultado

Parâmetro	Tipo	Descrição
valor	Texto, Número, Booleano, Data, Objeto, Collection	Valor a contar
rotaProp	Texto	Rota da propriedade de objeto para valores a contar
Resultado	Inteiro longo	Número de ocorrências do valor

Descrição

A função collection.countValues( ) devolve o número de vezes que se encontra o valor na coleção.

Pode passar em valor:

um valor escalar (texto, número, booleano, data),
um objeto ou uma referência de coleção

Para um elemento a encontrar, o tipo de valor deve ser equivalente ao tipo de elemento; a função usa o operador de igualdade.

O parâmetro opcional rotaProp lhe permite contar valores dentro de uma coleção de objetos: passar em rotaProp a rota da propriedade cujos valores deseja contar.

Nota: esta função não modifica a coleção original.

Exemplo 1

 C_COLLECTION($col)

 C_LONGINT($vCount)

 $col:=New collection(1;2;5;5;5;3;6;4)

 $vCount:=$col.countValues(5) // $vCount=3

Exemplo 2

 C_COLLECTION($col)

 C_LONGINT($vCount)

 $col:=New collection

 $col.push(New object("name";"Smith";"age";5))

 $col.push(New object("name";"Wesson";"age";2))

 $col.push(New object("name";"Jones";"age";3))

 $col.push(New object("name";"Henry";"age";4))

 $col.push(New object("name";"Gross";"age";5))

 $vCount:=$col.countValues(5;"age") //$vCount=2

Exemplo 3

 C_COLLECTION($numbers)

 C_COLLECTION($letters)

 C_LONGINT($vCount)

 

 $letters:=New collection("a";"b";"c")

 $numbers:=New collection(1;2;$letters;3;4;5)

 

 $vCount:=$numbers.countValues($letters) //$vCount=1