collection.countValues( )

4D v19.8


collection.countValues ( valeur {; cheminPropriété} ) -> Résultat

Paramètre	Type	Description
valeur	Texte, Numérique, Booléen, Date, Objet, Collection	Valeur à compter
cheminPropriété	Texte	Chemin de propriété d'objet pour les valeurs à compter
Résultat	Entier long	Nombre d'occurrences de la valeur

Description

La méthode collection.countValues( ) retourne le nombre d'occurrences de valeur dans la collection.

Vous pouvez passer dans valeur :

une valeur scalaire (texte, numérique, booléen, date),
une référence d'objet ou de collection.

Pour qu'un élément soit comptabilisé, le type de valeur doit être égal à celui de l'élément ; la méthode utilise l'opérateur d'égalité.

Le paramètre optionnel cheminPropriété vous permet de compter des valeurs à l'intérieur d'une collection d'objets : passez dans cheminPropriété le chemin de la propriété dont vous souhaitez comptabiliser le nombre de valeurs.

Note : Cette méthode ne modifie pas la collection d'origine.

Exemple 1

 C_COLLECTION($col)

 C_LONGINT($vCount)

 $col:=New collection(1;2;5;5;5;3;6;4)

 $vCount:=$col.countValues(5) // $vCount=3

Exemple 2

 C_COLLECTION($col)

 C_LONGINT($vCount)

 $col:=New collection

 $col.push(New object("name";"Smith";"age";5))

 $col.push(New object("name";"Wesson";"age";2))

 $col.push(New object("name";"Jones";"age";3))

 $col.push(New object("name";"Henry";"age";4))

 $col.push(New object("name";"Gross";"age";5))

 $vCount:=$col.countValues(5;"age") //$vCount=2

Exemple 3

 C_COLLECTION($numbers)

 C_COLLECTION($letters)

 C_LONGINT($vCount)

 

 $letters:=New collection("a";"b";"c")

 $numbers:=New collection(1;2;$letters;3;4;5)

 

 $vCount:=$numbers.countValues($letters) //$vCount=1