collection.query( )

4D v19.8

collection.query( )


collection.query ( chaîneRecherche {; valeur}{; valeur2 ; ... ; valeurN}{; params}) -> Résultat

Paramètre	Type	Description
chaîneRecherche	Texte	Chaîne contenant le ou les critère(s) de recherche
valeur	Varié	Valeur(s) à comparer lors de l'utilisation de paramètre(s) dans la chaîne
params	Objet	Options de recherche : parameters, attributes
Résultat	Collection	Elément(s) répondant au(x) critère(s) de recherche

Description

La méthode collection.query( ) retourne tous les éléments de la collection d'objets répondant au(x) critère(s) de recherche définis dans le paramètre chaîneRecherche et, le cas échéant, valeur et params.

Si la collection d'origine est une collection partagée, la collection retournée est également une collection partagée.

Note : Cette méthode ne modifie pas la collection d'origine.

La syntaxe du paramètre chaîneRecherche doit être la suivante :

cheminPropriété comparateur valeur {opérateurLogique cheminPropriété comparateur valeur}

Pour une description détaillée de la construction de recherches à l'aide des paramètres chaîneRecherche, valeur et params, veuillez vous reporter à la description de la méthode dataClass.query( ).

Exemple 1

 C_COLLECTION($c)

 $c:=New collection

 $c.push(New object("name";"Cleveland";"zc";35049))

 $c.push(New object("name";"Blountsville";"zc";35031))

 $c.push(New object("name";"Adger";"zc";35006))

 $c.push(New object("name";"Clanton";"zc";35046))

 $c.push(New object("name";"Clanton";"zc";35045))

 $c2:=$c.query("name = :1";"Cleveland") //$c2=[{name:Cleveland,zc:35049}]

 $c3:=$c.query("zc > 35040") //$c3=[{name:Cleveland,zc:35049},{name:Clanton,zc:35046},{name:Clanton,zc:35045}]

Exemple 2

 C_COLLECTION($c)

 $c:=New collection

 $c.push(New object("name";"Smith";"dateHired";!22-05-2002!;"age";45))

 $c.push(New object("name";"Wesson";"dateHired";!30-11-2017!))

 $c.push(New object("name";"Winch";"dateHired";!16-05-2018!;"age";36))

 $c.push(New object("name";"Sterling";"dateHired";!10-5-1999!;"age";Null))

 $c.push(New object("name";"Mark";"dateHired";!01-01-2002!))

Cet exemple retourne les personnes dont le nom contient "in" :

 $col:=$c.query("name = :1";"@in@")

  //$col=[{name:Winch...},{name:Sterling...}]

Cet exemple retourne les personnes dont le nom ne débute pas par une certaine valeur, provenant d'une variable (saisie par l'utilisateur, par exemple) :

 $col:=$c.query("name # :1";$aString+"@")

  //if $astring="W"

  //$col=[{name:Smith...},{name:Sterling...},{name:Mark...}]

Cet exemple retourne les personnes dont l'âge est inconnu (propriété avec valeur null ou propriété indéfinie):

 $col:=$c.query("age=null") //caractères d'emplacement non autorisés avec "null"

  //$col=[{name:Wesson...},{name:Sterling...},{name:Mark...}]

Cet exemple retourne les personnes embauchées il y a plus de 90 jours :

 $col:=$c.query("dateHired < :1";(Current date-90))

  //$col=[{name:Smith...},{name:Sterling...},{name:Mark...}] si aujourd'hui est le 10/01/2018

Note : Ce dernier exemple nécessite que l'option de compatibilité "Utiliser le type date au lieu du format date ISO dans les objets" soit cochée (cf. Page Compatibilité).

Exemple 3

Plus d'exemples de requêtes peuvent être trouvés dans la page dataClass.query( ).

Voir aussi

collection.indices( )
dataClass.query( )
entitySelection.query( )