File and folder object pathnames

Home

4D v19.8

Overview

Commands, methods, and properties of this theme allow you to handle files and folders as objects. This makes file and folder management powerful and flexible. For example, to create a new file in the current user's Documents folder, you can write:

$new:=Folder(fk documents folder).file("Archives/John4D.prefs").create()

In addition, file and folder objects support fileSystems, which provide contextual path to main application folders.

Filesystem pathnames

4D accepts several "filesystem" pathnames that designate specific 4D folders with variable location on macOS and Windows. Filesystem pathnames are useful for two main reasons:

Independence: You can move your solution from one place to another regardless of the OS, without having to worry about paths,
Security: No code can access elements located above the file system root on the disk (sandboxing).

The following filesystem pathnames are supported:

filesystem	Designates
"/RESOURCES"	Current database resources folder
"/DATA"	Current data folder
"/PACKAGE"	Database folder (with or without 4dbase extension)
"/LOGS"	Logs folder of the database

Note: In some cases, the current database resources folder can be resolved as "/SOURCES" and the database folder can be resolved as "/PROJECT". It does not change the actual filesystem target.

POSIX syntax

The POSIX syntax is supported on all platforms. POSIX syntax is recommended since it is the most flexible. It is used by default (returned by file.path and folder.path properties).

With this syntax:

folders are separated by "/"
absolute pathnames start with a "/"
to move up one folder in a relative path, use "../" in front of the pathname (for security, you cannot move up the filesystem).

In POSIX syntax, you will generally use "filesystem" pathnames with File and Folder commands, for example:

 $pathFile:=File("/DATA/Archives/file 2.txt")

 $pathFolder:=Folder("/RESOURCES/Pictures")

Platform-specific syntax

Platform-specific syntax depends on the operating system on which the command is executed. Note that when creating a file or folder object with this syntax, you must declare it using the fk platform path constant as parameter.

Windows
The following patterns are supported:

folder separators are "\"
the text contains ':' and '\' as the second and third character,
the text starts with "\\".

Examples with Folder:

 $myFolder:=Folder("C:\\Monday";fk platform path).create()

 $myFolder:=Folder("\\\\svr-internal\\tempo";fk platform path).create()

Note: See the Entering Windows pathnames and escape sequences paragraph for information about the double "\\'.

macOS
The following patterns are supported (HFS+ syntax):

folder separators are ":"
the path must not start with a ":"

Examples with Folder:

 $myFolder:=Folder("macintosh hd:";fk platform path).create()

 $myFolder:=Folder("Monday:Tuesday";fk platform path).create() //a volume must be called Monday

Absolute and relative pathnames

File and Folder constructors
File and Folder commands only accept absolute pathnames. Relative pathnames are not supported and will return errors. For example, the following code is not allowed:

  //ERROR

 $myFolder:=Folder("myFolder").create() //relative pathname with constructor

If you want to handle files or folders in various locations (database folder, system folders, etc.), you can use filesystems (see above). For example, you can write:

 $myFolder:=Folder("/PACKAGE";"myFolder").create() //folder created at the .4db level

 $myFile:=File("/DATA/Prefs/tempo.txt").create() //file created in the data folder

.file() and .folder() folder methods
Methods of file and folder objects such as folder.file( ) and folder.folder( ) expect relative POSIX pathnames. For example:

  //to reference a "Picture" folder within the user documents folder

 $userImages:=Folder(fk documents folder).folder("Pictures")

  //to create a folder on the desktop

 $myFolder2:=Folder(fk desktop folder).folder("myFolder").create()

Absolute pathnames are not supported and will return errors.

Examples

The flexibility of commands and methods of this theme, combined with object notation, offers you various possibilities for handling files and folders, like in the following examples:

 $f:=Folder(fk desktop folder).folder("archive/jan2019")

 

 $f2:=Folder("/DATA/archive/jan2019").file("total.txt")

 

 $f3:=Folder("/DATA/archive/jan2019")

 

 $f4:=File("/DATA/info.txt")

 

 $f5:=File("c:\\archives\\local\\jan2019.txt";fk platform path)

 

 $f6:=File(fk backup log file)