On Mobile App Action database method

4D v19.8


$1 -> On Mobile App Action database method -> Résultat

Paramètre	Type	Description
$1	Objet	Information passée par l'application mobile
Résultat	Objet	Statut de l'action & synchronisation des données

Description

La On Mobile App Action database method gère les actions requises par l'application mobile pour une session spécifique.

Note : L'application mobile doit avoir été authentifiée via On Mobile App Authentication database method.

Cette méthode base est appelée par 4D lorsqu'une application mobile envoie une requête d'action.

Note : Pour plus d'informations, veuillez consulter la documentation de 4D for iOS.

La méthode base reçoit les informations requises à partir de l'application mobile dans le paramètre $1 (objet), et doit retourner le statut de l'action dans le paramètre $0 (objet). Vous devez déclarer et initialiser ces paramètres comme suit :

  // méthode base Sur une action app mobile

 C_OBJECT($0;$1)

  // ...Code pour la méthode

 $0:=New object // Ne pas oublier de créer l'objet à retourner

Les propriétés suivantes sont reçues dans le paramètre objet $1 :

Propriété		Type	Description
action		Texte	Nom de l'action
session		Objet	Informations sur la session
	id	Texte	Identifiant de la session
	ip	Texte	IP de la session
application		Objet	Informations sur l'application mobile
	id	Texte	ID de l'application
userInfo		Texte	Informations utilisateur
context		Objet	Paramètres de contexte correspondant à l'action requise
	dataClass	Texte	Nom de la dataclass 4D
	entity.primaryKey	Texte \| Entier long	(optionnel, retourné si l'action est relative à une entité sélectionnée) Clé primaire de l'entité.
	entity.relationName	Texte	(optionnel, retourné si l'action est relative à une entité liée) Nom du lien N vers 1 (lien aller)
	parent.primaryKey	Texte \| Entier long	(optionnel, retourné si l'action est relative à une entité liée) Clé primaire de l'entité parente.
	parent.relationName	Texte	(optionnel, retourné si l'action est relative à une entité liée) Nom du lien 1 vers N (lien retour)
	parent.dataClass	Texte	(optionnel, retourné si l'action est relative à une entité liée) Nom de la dataclass 4D parente

Après avoir traité les informations, la méthode base doit retourner un objet avec les propriétés suivantes contenues dans $0 :

Propriété	Type	Description
success	Booléen	Vrai si l'action a été traitée avec succès, sinon Faux.
statusText	Texte	(Optionnel) Message à afficher dans l'application mobile. Si success=vrai, affiche le message; si success=faux, peut servir à fournir une explication à l'utilisateur
dataSynchro	Booléen	Vrai si la sélection d'entité ou de table doit être actualisée, sinon Faux. Si Vrai, l'application mobile déclenchera automatiquement une synchronisation des données

Exemple

  // Sur une action app mobile

  // 2 actions sont définies : "done" et "postponeAll"

 

 C_OBJECT($0)

 C_OBJECT($1)

 

 C_OBJECT($o;$context;$request;$result)

 

 $request:=$1 //Information fournie par l'application mobile

 $context:=$request.context

 

 Case of

 

    :($request.action="done")

       $o:=New object(\

       "dataClass";$context.dataClass;\

       "ID";$context.entity.primaryKey;\

       "CompletePercentage";100)

 

       $result:=modifyStatus($o) //appelle la méthode de votre projet pour modifier le statut de l'entité

 

    :($request.action="postponeAll")

 

       $o:=Creer objet("dataClass";$context.dataClass)

 

       $result:=postponeAll($o) //appelle la méthode de votre projet pour reporter toutes les entités de la dataClass

 

    Else //requête inconnue

       $result:=New object("success";False) 

 

 End case

 

 $0:=$result  //Information retournée sur l'application mobile

Voir aussi

On Mobile App Authentication database method