entitySelection.drop( )

4D v19.8


entitySelection.drop ( {mode} ) -> Résultat

Paramètre	Type	Description
mode	Entier long	dk stop dropping on first error : stoppe l'exécution de la méthode au niveau de la première entité non-supprimable
Résultat	EntitySelection	Sélection d'entités vide si exécutée avec succès, sinon sélection d'entités contenant la ou les entité(s) non supprimée(s)

Description

La méthode entitySelection.drop( ) supprime les entités appartenant à la sélection d'entités de la table liée à sa dataclass dans le datastore. La sélection d'entités reste en mémoire.

Note : La suppression d'entités est permanente et ne peut pas être annulée. Il est recommandé d'appeler cette action dans une transaction afin d'avoir une possibilité de récupération.

Si une entité verrouillée est rencontrée lors de l'exécution de entitySelection.drop( ), elle n'est pas supprimée. Par défaut, la méthode traite toutes les entités de la sélection d'entités et renvoie des entités non supprimables dans la sélection d'entités. Si vous souhaitez que la méthode arrête l'exécution au niveau de la première entité non supprimable rencontrée, passez la constante dk stop dropping on first error dans le paramètre mode.

Exemple

Exemple sans l'option dk stop dropping on first error :

 C_OBJECT($employees;$notDropped)

 $employees:=ds.Employee.query("firstName=:1";"S@")

 $notDropped:=$employees.drop() // $notDropped est une sélection d'entités contenant toutes les entités non-supprimées

 If($notDropped.length=0) //La suppression est un succès, toutes les entités ont été supprimées

    ALERT("Vous avez supprimé "+String($employees.length)+" employés") //La sélection d'entités supprimées reste en mémoire

 Else

    ALERT("Problème durant la suppression, réessayez plus tard")

 End if

Exemple avec l'option dk stop dropping on first error :

 C_OBJECT($employees;$notDropped)

 $employees:=ds.Employee.query("firstName=:1";"S@")

 $notDropped:=$employees.drop(dk stop dropping on first error) //$notDropped est une sélection d'entités contenant la première entité non-supprimée

 If($notDropped.length=0) //La suppression est un succès, toutes les entités ont été supprimées

    ALERT("Vous avez supprimé "+String($employees.length)+" employés") //a sélection d'entités supprimées reste en mémoire

 Else

    ALERT("Problème durant la suppression, réessayez plus tard")

 End if

Voir aussi

entitySelection.add( )