entitySelection.minus( )

4D v19.8


entitySelection.minus ( entidad \| seleccionEntidad ) -> Resultado

Parámetro	Tipo	Descripción
entidad \| seleccionEntidad	Entity, EntitySelection	Selección de entidad o entidad a restar
Resultado	EntitySelection	Nueva selección de entidad o una nueva referencia en la selección de entidad existente

Descripción

El método entitySelection.minus( ) excluye de la selección de entidad a la que se aplica la entidad o las entidades de seleccionEntidad y devuelve la selección de entidad resultante.

Si pasa entidad como parámetro, el método crea una nueva selección de entidad sin entidad (si entidad pertenece a la selección de entidad). Si entidad no se incluyó en la selección de la entidad original, se devuelve una nueva referencia a la selección de la entidad.
Si pasa seleccionEntidad como parámetro, el método devuelve una selección de entidad que contiene las entidades que pertenecen a la selección de entidad original de la que se han eliminado las entidades que pertenecen a seleccionEntidad.

Nota: puede comparar selecciones de entidades ordenadas y/o no ordenadas. La selección resultante siempre está desordenada. Para más información, consulte el párrafo Ordenadas vs No ordenadas en la Guía del desarrollador 4D.

Si la selección de entidad original o ambos la selección de entidad original y el parámetro seleccionEntidad están vacíos, se devuelve una selección de entidad vacía.
Si seleccionEntidad está vacía o si entidad es Null, se devuelve una nueva referencia a la selección de la entidad original.

Si la selección de entidad original y el parámetro no están relacionados con la misma clase de datos, se genera un error.

Ejemplo 1

 C_OBJECT($employees;$employee;$result)

 

 $employees:=ds.Employee.query("lastName = :1";"H@") // La selección de entidad $employees contiene la entidad con la llave primaria 710 y otras entidades

  // por ej. "Colin Hetrick", "Grady Harness", "Sherlock Holmes" (primary key 710)

 

 $employee:=ds.Employee.get(710) // Devuelve "Sherlock Holmes"

 

 $result:=$employees.minus($employee) //$result contiene "Colin Hetrick", "Grady Harness"

Ejemplo 2

Queremos tener una selección de empleadas llamadas "Jones" que vivan en Nueva York:

 C_OBJECT($sel1;$sel2;$sel3)

 $sel1:=ds.Employee.query("name =:1";"Jones")

 $sel2:=ds.Employee.query("city=:1";"New York")

 $sel3:=$sel1.and($sel2).minus(ds.Employee.query("gender='male'"))

Ver también

DIFFERENCE
entitySelection.add( )