entitySelection.refresh( )

4D v19.8


	entitySelection.refresh ()

	Este comando não requer parâmetros

Descrição

Nota: este método só funciona com um armazém de dados remoto (cliente/servidor ou conexão Open datastore).

O método entitySelection.refresh( ) "invalida" imediatamente os dados da seleção de entidades na caché ORDA local, de modo que a próxima vez que 4D exigir a seleção de entidades, se voltará a carregar desde o banco de dados.

Como padrão, a caché ORDA local se invalida depois de 30 segundos. No contexto das aplicações cliente/servidor que utilizam ORDA e a lingagem clássica, este método lhe permite ter certeza de que uma aplicação remota sempre funcione com os dados mais recentes.

Exemplo 1

Neste exemplo, as linguagens clássica e ORDA modificam os mesmos dados simultaneamente:

  //Em um 4D remoto

 

 C_OBJECT($selection;$student)

 

 $selection:=ds.Students.query("lastname=:1";"Collins")

  //A primeira entidade é carregada na cache ORDA

 $student:=$selection.first()

 

  //Atualização com 4D clássico, a caché ORDA não sabe se

 QUERY([Students];[Students]lastname="Collins")

 [Students]lastname:="Colin"

 SAVE RECORD([Students])

 

  //para obter a última versão, se deve invalidar a caché ORDA

 $selection.refresh()

  // Mesmo se a memória caché não tiver caducado, a primeira entidade volta a carregar desde o disco

 $student:=$selection.first()

 

  //$student.lastname contains "Colin"

Exemplo 2

Uma list box mostra a seleção de entidades Form.students e vários clientes trabalham nela.

  // Método de formulário:

 Case of

    :(Form event code=On Load)

       Form.students:=ds.Students.all()

 End case

  //

  //

  // No cliente #1, o usuário carrega, atualiza e salva a primeira entidade

  // No cliente #2, o usuário carrega, atualiza e salva a mesma entidade

  //

  //

  // No cliente #1:

 Form.students.refresh() //  Invalida a cache ORDA para a seleção de entidades Form.students

  //O conteúdo de list box é atualizado desde o banco de dados com a atualização realizada pelo cliente #2