entitySelection.refresh

Home

4D v19.8


	entitySelection.refresh ()

	Dieser Befehl benötigt keine Parameter

Beschreibung

Hinweis: Die Methode funktioniert nur mit einem remote Datastore (Client/Server oder Open datastore Verbindung).

Die Methode entitySelection.refresh macht die Daten der Entity-Selection im lokalen ORDA Cache sofort ungültig, so dass 4D beim nächsten Anfordern der Entity-Selection die Daten erneut aus der Anwendung lädt.

Der lokale ORDA Cache wird standardmäßig nach 30 Sekunden ungültig. Bei Anwendungen im Client/Server Betrieb, die ORDA und die klassische Programmiersprache verwenden, stellt diese Methode sicher, dass eine remote Anwendung immer die neuesten Daten verwendet.

Beispiel 1

In diesem Beispiel ändern die klassische Programmiersprache und ORDA dieselben Daten gleichzeitig:

  //In remote 4D

 

 C_OBJECT($selection;$student)

 

 $selection:=ds.Students.query("lastname=:1";"Collins")

  //Die erste Entity wird in den ORDA Cache geladen

 $student:=$selection.first()

 

  //Update mit klassischem 4D, ORDA Cache ist nicht betroffen

 QUERY([Students];[Students]lastname="Collins")

 [Students]lastname:="Colin"

 SAVE RECORD([Students])

 

  //Zum Abfragen der neuesten Version muss der ORDA Cache ungültig gemacht werden

 $selection.refresh()

  // Auch wenn der Cache noch nicht abgelaufen ist, wird die erste Entity von der Festplatte geladen

 $student:=$selection.first()

 

  //$student.lastname enthält "Colin"

Beispiel 2

Eine Listbox zeigt die Entity Selection Form.students an und mehrere Clients arbeiten damit.

  // Formularmethode:

 Case of

    :(Form event code=On Load)

       Form.students:=ds.Students.all()

 End case

  //

  //

  // Auf Client #1 lädt, aktualisiert und speichert der Benutzer die erste Entity

  // Auf Client #2 lädt, aktualisiert und speichert der Benutzer dieselbe Entity

  //

  //

  // Auf Client #1:

 Form.students.refresh() // Macht den ORDA Cache für die Entity Selection Form.students ungültig

  // Der Inhalt der Listbox wird mit dem von Client #2 gemachten Update neu aus der Anwendung geladen