Evénements formulaire 4D View Pro

4D v19

Présentation

Les événements formulaire suivants sont disponibles dans la Liste de Propriétés des zones 4D View Pro :

Certains événements sont des événements formulaire standard (disponibles pour tous les objets actifs) et certains sont des événements formulaire 4D View Pro spécifiques. Les événements formulaire 4D View Pro spécifiques fournissent des informations supplémentaires dans l'objet retourné par la commande FORM Evenement lorsqu'elles sont générées pour les zones 4D View Pro. Le tableau suivant liste les événements standards ainsi que les formulaires événements 4D View Pro spécifiques :

Evénements 4D standard (voir Evenement formulaire code)	Evénements 4D View Pro spécifiques
Sur chargement	Sur VP prêt
Sur gain focus	Sur clic
Sur perte focus	Sur double clic
Sur libération	Sur clic entête
	Sur après modification
	Sur nouvelle sélection
	Sur redimensionnement colonne
	Sur redimensionnement ligne

Sur VP prêt

Tout code d'initialisation d'une zone 4D View Pro, pour le chargement ou la lecture de valeurs à partir de la zone ou dans la zone, doit être introduit dans l'événement formulaire Sur VP prêt de la zone. Cet événement formulaire est exécuté une fois que la zone est entièrement chargée. En testant l'événement, vous êtes sûr que le code sera exécuté dans un contexte valide. Une erreur est retournée si une commande 4D View Pro est appelée avant que l'événement Sur VP prêt soit généré.

Note : Les zones 4D View Pro sont chargées de façon asynchrone dans les formulaires 4D. Cela signifie que l'événement formulaire standard Sur chargement ne peut pas être utilisé pour le code d'initialisation de 4D View Pro, car il pourrait être exécuté avant que le chargement de la zone ne soit terminé. Sur VP prêt est toujours généré après Sur chargement.

Sur clic

Si vous cliquez n'importe où dans un document 4D View Pro, l'événement Sur clic est généré. L'objet retourné par la commande FORM Evenement contient :

Propriété	Type	Description
code	entier long	Sur clic
description	texte	"Sur clic"
objectName	texte	nom de zone 4D View Pro
sheetName	texte	Nom de la feuille de l'événement
range	objet	Plage de cellules

Exemple :

 Si(FORM Evenement.code=Sur clic)

    VP SET CELL STYLE(FORM Evenement.range;Creer objet("backColor";"green"))

 Fin de si

Sur double clic

Lorsqu'un utilisateur clique n'importe où dans un document 4D View Pro, l'événement Sur double clic est généré. L'objet retourné par la commande FORM Evenement contient :

Propriété	Type	Description
code	entier long	Sur double clic
description	texte	"Sur double clic"
objectName	texte	nom de zone 4D View Pro
sheetName	texte	Nom de la feuille de l'événement
range	objet	Plage de cellules

Exemple:

 Si(FORM Evenement.code=Sur double clic)

    $value:=VP Get value(FORM Evenement.range)

 Fin de si

Sur clic entête

Lorsqu'un utilisateur clique sur un en-tête de colonne ou de ligne dans un document 4D View Pro, l'événement Sur clic entête est généré. L'objet retourné par la commande FORM Evenement contient :

Propriété	Type	Description
code	entier long	Sur clic entête
description	texte	"Sur clic entête"
objectName	texte	nom de zone 4D View Pro
sheetName	texte	Nom de la feuille de l'événement
range	objet	Plage de cellules
sheetArea	entier long	L'emplacement de la feuille dans lequel s'est produit l'événement : 0 : La zone où les en-têtes de lettre et de numéro de colonnes se croisent (zone supérieure gauche de la feuille) 1 : Les en-têtes de colonne (zone indiquant les numéros et lettres de colonnes) 2 : Les en-têtes de ligne (zone indiquant les numéros de ligne)

Exemple:

 Si(FORM Evenement.code=Sur clic entête)

    Au cas ou

       :(FORM Evenement.sheetArea=1)

          $values:=VP Get values(FORM Evenement.range)

       :(FORM Evenement.sheetArea=2)

          VP SET CELL STYLE(FORM Evenement.range;Creer objet("backColor";"gray"))

       :(FORM Evenement.sheetArea=0)

          VP SET CELL STYLE(FORM Evenement.range;Creer objet("borderBottom";Creer objet("color";"#800080";"style";vk line style thick)))

    Fin de cas

 Fin de si

Sur après modification

A la suite de toute modification apportée par l'utilisateur à un document 4D View Pro, l'événement Sur après modification est généré. L'objet retourné par la commande FORM Evenement contient :

Propriété	Type	Description
code	entier long	Sur après modification
description	texte	"Sur après modification"
objectName	texte	nom de zone 4D View Pro
sheetName	texte	Nom de la feuille de l'événement
action	texte	"editChange", "valueChanged", "DragDropBlock", "DragFillBlock", "formulaChanged", "clipboardPasted"

Note : Voir également l'événement Sur VP Plage changée.

En fonction de la valeur de la propriété action, l'objet contiendra des propriétés supplémentaires.

action = editChange

La modification de texte génère les propriétés supplémentaires suivantes :

Propriété	Type	Description
range	objet	Plage de cellules
editingText	variant	Valeur depuis l'éditeur courant

action = valueChanged

La modification de valeur(s) génère les propriétés supplémentaires suivantes :

Propriété	Type	Description
range	objet	Plage de cellules
oldValue	variant	Valeur de la cellule avant modification
newValue	variant	Valeur de la cellule après modification

action = DragDropBlock

Les actions de glisser-déposer génèrent l'intégration des propriétés supplémentaires suivantes :

Propriété	Type	Description
fromRange	objet	Plage de la cellule source (glissée)
toRange	objet	Plage de la cellule cible (déposée)
copy	booléen	Indique si la plage source est copiée ou non
insert	booléen	Indique si la plage source est insérée ou non

action = DragFillBlock

Faire glisser le contenu pour remplir les cellules adjacentes génère les propriétés supplémentaires suivantes :

Propriété	Type	Description
fillRange	objet	Plage utilisée pour le remplissage
autoFillType	entier long	Valeur utilisée pour le remplissage. 0 : Les cellules sont remplies par toutes les données (valeurs, formatage, et formules) 1 : Les cellules sont remplies par des données séquentielles automatiques 2 : Les cellules sont remplies uniquement par du formatage 3 : Les cellules sont remplies par des valeurs mais pas par du formatage 4 : Les valeurs des cellules sont supprimées 5 : Les cellules sont remplies automatiquement
fillDirection	entier long	Direction du remplissage. 0 : Les cellules de gauche sont remplies 1 : Les cellules de droite sont remplies 2 : Les cellules du haut sont remplies 3: Les cellules du bas sont remplies

action = formulaChanged

La saisie de formule(s) génère les propriétés supplémentaires suivantes :

Propriété	Type	Description
range	objet	Plage de cellules
formula	texte	La formule saisie

action = clipboardPasted

Coller du contenur à partir du presse-papiers génère les propriétés supplémentaires suivantes :

Propriété

Type

Description

range

objet

Plage de cellules recevant le contenu

pasteOption

entier long

Indique ce qui collé à partir du presse-papiers :

0 : Tout est collé (valeurs, formatage et formules)

1 : Seules les valeurs sont collées

2 : Seul le formatage est collé

3 : Seules les formules sont collées

4 : Les valeurs et le formatage sont collés (pas les formules)

5 : Les formules et le formatage sont collés (pas les valeurs)

pasteData

objet

Les données du presse-papiers à coller

Propriété	Type	Description
text	texte	Le texte du presse-papiers
html	texte	Le HTML du presse-papiers

Exemple

Voici un exemple de gestion d'événement Sur après modification :

 Si(FORM Evenement.code=Sur après modification)

    Si(FORM Evenement.action="valueChanged")

       ALERTE("ATTENTION : Vous êtes en train de modifier la valeur de "+Chaine(FORM Evenement.oldValue)+" en "+Chaine(FORM Evenement.newValue)+"!")

    Fin de si

 Fin de si

L'exemple ci-dessus pourrait générer un objet événement (voir FORM Evenement) comme ceci :


{
"code":45;
"description":"On After Edit";
"objectName":"ViewProArea"
"sheetname":"Sheet1";
"action":"valueChanged";
"range": {area:ViewProArea,ranges:[{column:1,row:2,sheet:1}]};
"oldValue":"The quick brown fox";
"newValue":"jumped over the lazy dog";
}

Sur nouvelle sélection

La modification de la sélection courante de lignes ou de colonnes dans un document 4D View Pro génère l'événement Sur nouvelle sélection. L'objet retourné par la commande FORM Evenement contient :

Propriété	Type	Description
code	entier long	Sur nouvelle sélection
description	texte	"Sur nouvelle sélection"
objectName	texte	Nom de la zone 4D View Pro
sheetName	texte	Nom de la feuille de l'événement
oldSelections	objet	Plage de cellules avant modification.
newSelections	objet	Plage de cellules après modification

Exemple:

 Si(FORM Evenement.code=Sur nouvelle sélection)

    VP SET CELL STYLE(FORM Evenement.oldSelections;Creer objet("backColor";Null))

    VP SET CELL STYLE(FORM Evenement.newSelections;Creer objet("backColor";"red"))

 Fin de si

Sur redimensionnement colonne

La modification de la largeur d'une colonne dans un document 4D View Pro document par un utilisateur génère l'événement Sur redimensionnement colonne. L'objet retourné par la commande FORM Evenement comprend :

Propriété	Type	Description
code	entier long	Sur redimensionnement colonne
description	texte	"Sur redimensionnement colonne"
objectName	texte	Nom de zone 4D View Pro
sheetName	texte	Nom de la feuille de l'événement
range	objet	Plage des colonnes dont la largeur a été modifiée
header	booléen	Vrai si la colonne de l'en-tête de la ligne (première colonne) est redimensionnée, sinon faux

Exemple:

 Si(FORM Evenement.code=Sur redimensionnement colonne)

    VP SET CELL STYLE(FORM Evenement.range;Creer objet("hAlign";vk horizontal align right))

 Fin de si

Sur redimensionnement ligne

La modification de la hauteur d'une ligne dans un document 4D View Pro document par un utilisateur génère l'événement Sur redimensionnement ligne. L'objet retourné par la commande FORM Evenement comprend :

Propriété	Type	Description
code	entier long	Sur redimensionnement ligne
description	texte	"Sur redimensionnement ligne"
objectName	texte	Nom de zone 4D View Pro
sheetName	texte	Nom de la feuille de l'événement
range	objet	Plage des lignes dont la hauteur a été modifiée
header	booléen	Vrai si la ligne de l'en-tête de la colonne (première ligne) est redimensionnée, sinon faux

Exemple:

 Si(FORM Evenement.code=Sur redimensionnement ligne)

    VP SET CELL STYLE(FORM Evenement.range;Creer objet("vAlign";vk vertical align top))

 Fin de si

Sur VP Plage changée

Lorsqu'un changement se produit dans une plage de cellules du document 4D View Pro, l'événement Sur VP Plage changée est généré. L'objet retourné par la commande FORM Evenement contient :

Propriété	Type	Description
objectName	texte	Nom de zone 4D View Pro
code	entier long	Sur VP Plage changée
description	texte	"Sur VP Plage Changée"
sheetName	texte	Nom de la feuille de l'événement
range	objet	Plage de cellule de la modification
changedCells	objet	Plage contenant uniquement les cellules modifiées. Il peut s'agir d'une plage combinée.
action	texte	Le type d’opération générant l’événement : "clear" - Une opération de valeur de plage claire "dragDrop" - Une opération de glisser-déposer "dragFill" - Une opération de remplissage par glisser "evaluateFormula" - Définir une formule dans une plage de cellules spécifiée "paste" - Une opération de collage "setArrayFormula" - Définir une formule dans une plage de cellules spécifiée "sort" - Trier une plage de cellules

Note : Voir également Sur après modification.