WP Tableau lire lignes

4D v19


WP Tableau lire lignes ( objCible ) \| ( refTableau ; debutLigne {; nbLignes} ) -> Résultat

Paramètre	Type	Description
objCible	Objet	Plage ou élément ou document 4D Write Pro
refTableau	Objet	Référence de tableau
debutLigne	Entier long	Position de la première ligne
nbLignes	Entier long	Nombre de lignes à lire
Résultat	Objet	Nouvelle plage contenant les lignes sélectionnées

Description

La commande WP Tableau lire lignes retourne un nouvel objet plage cellule contenant la sélection de lignes de objCible ou de refTableau (définies par debutLigne et nbLignes).

Passez soit :

objCible :
- une plage, ou
- un élément (ligne / paragraphe / corps / en-tête / pied / image en ligne / section / sous-section), ou
- un document 4D Write Pro

Si objCible n'intersecte pas une plage de tableau ou de texte là où une sélection de lignes peut être récupérée, la commande retourne Null.

refTableau - la référence du tableau contenant la sélection de colonnes à lire.
debutLigne - pointe vers la première ligne du tableau à retourner, et
(optionnel) nbLignes - indique le nombre de colonnes à retourner. Si nbLignes est omis, l'unique colonne de debutLigne est retournée.

Si debutLigne plus nbLignes excède le nombre de lignes dans refTableau, ou si debutLigne est plus grand que le nombre de lignes dans refTableau, la plage retournée contient le maximum de lignes.

Exemple 1

Vous souhaitez fixer une couleur d'arrière-plan spécifique pour les deux premières lignes d'un tableau, et modifier la bordure de la troisième ligne :

 C_OBJET($wpTable;$wpRange;$wpRow1;$wpRow2;$wpRow3;$wpRow4;$wpRow5;$rows;$rows2)

 $wpRange:=WP Creer plage(WParea;wk start text;wk end text)

 

 $wpTable:=WP Inserer tableau($wpRange;wk append)

 $wpRow1:=WP Tableau ajouter ligne($wpTable;"Paul";"Smith";25)

 $wpRow2:=WP Tableau ajouter ligne($wpTable;"John";"Richmond";40)

 $wpRow3:=WP Tableau ajouter ligne($wpTable;"Mary";"Trenton";18)

 $wpRow4:=WP Tableau ajouter ligne($wpTable;"Christopher";"Lee";53)

 $wpRow5:=WP Tableau ajouter ligne($wpTable;"Henry";"Cartier";42)

 

 $rows:=WP Tableau lire lignes($wpTable;1;2)

 WP FIXER ATTRIBUTS($rows;wk background color;0x00E0F0FF)

 $rows2:=WP Tableau lire lignes($wpTable;3)

 WP FIXER ATTRIBUTS($rows2;wk border style;wk solid)

 WP FIXER ATTRIBUTS($rows2;wk border width;4)

Exemple 2

Vous souhaitez obtenir une plage de lignes à compter de la 10e jusqu'à la dernière :

WP Tableau lire lignes(tableRef;10;MAXLONG)

Exemple 3

Vous souhaitez récupérer les lignes sélectionnées par un utilisateur :

 C_OBJET($userSelection;$rows)

 

 $userSelection:=WP Plage selection(myWPArea)

 

 $rows:=WP Tableau lire lignes($userSelection)

Voir aussi

WP Inserer tableau
WP Tableau ajouter ligne
WP Tableau lire cellules
WP Tableau lire colonnes