WP Table get rows

4D v19

WP Table get rows


WP Table get rows ( objTarget ) \| ( refTabla ; filaIni {; numFilas} ) -> Resultado

Parámetro	Tipo	Descripción
objTarget	Objeto	Rango o elemento o documento 4D Write Pro
refTabla	Objeto	Referencia de tabla
filaIni	Entero largo	Posición de la primera fila
numFilas	Entero largo	Número de filas a obtener
Resultado	Objeto	Nuevo rango de tablas que contiene las filas seleccionadas

Descripción

El comando WP Table get rows devuelve un nuevo objeto de rango de celdas que contiene la selección de las filas de objTarget o refTabla (definidas por filaIni y numFilas)

Pase:

objTarget:
- un rango, o
- un elemento (fila / párrafo / cuerpo / encabezado / pie de página / imagen en línea / sección / subsección), o
- un documento 4D Write Pro

Si objTarget no se cruza con una tabla o rango de texto donde se puede recuperar una selección de filas, el comando devuelve Null.

refTabla - la referencia de la tabla cuya selección de filas desea obtener.
filaIni - apunta a la primera fila de la tabla a devolver y
(opcional) numFilas - especifica cuántas filas se devuelven. Si se omite numFilas, se devuelve la fila filaIni.

Si filaIni más numFilas exceden el número de filas en refTabla, o si filaIni es mayor que el número de filas en refTabla, el rango devuelto contiene el máximo número de filas posible.

Ejemplo 1

Desea establecer un color de fondo específico para las dos primeras filas de una tabla y modificar el borde de la tercera fila:

 C_OBJECT($wpTable;$wpRange;$wpRow1;$wpRow2;$wpRow3;$wpRow4;$wpRow5;$rows;$rows2)

 $wpRange:=WP Get range(WParea;wk start text;wk end text)

 

 $wpTable:=WP Insert table($wpRange;wk append)

 $wpRow1:=WP Table append row($wpTable;"Paul";"Smith";25)

 $wpRow2:=WP Table append row($wpTable;"John";"Richmond";40)

 $wpRow3:=WP Table append row($wpTable;"Mary";"Trenton";18)

 $wpRow4:=WP Table append row($wpTable;"Christopher";"Lee";53)

 $wpRow5:=WP Table append row($wpTable;"Henry";"Cartier";42)

 

 $rows:=WP Table get rows($wpTable;1;2)

 WP SET ATTRIBUTES($rows;wk background color;0x00E0F0FF)

 $rows2:=WP Table get rows($wpTable;3)

 WP SET ATTRIBUTES($rows2;wk border style;wk solid)

 WP SET ATTRIBUTES($rows2;wk border width;4)

Ejemplo 2

Para obtener un rango de líneas desde el 10 hasta el final:

WP Table get rows(tableRef;10;MAXLONG)

Ejemplo 3

Desea recuperar las filas que un usuario ha seleccionado:

 C_OBJECT($userSelection;$rows)

 

 $userSelection:=WP Selection range(myWPArea)

 

 $rows:=WP Table get rows($userSelection)

Ver también

WP Insert table
WP Table append row
WP Table get cells
WP Table get columns