GET PICTURE METADATA

4D v20 R7


GET PICTURE METADATA ( image ; nomMeta ; contenuMeta {; nomMeta2 ; contenuMeta2 ; ... ; nomMetaN ; contenuMetaN} )

Paramètre	Type	Description
image	Image	Image dont vous souhaitez lire les métadonnées
nomMeta	Texte	Nom ou chemin du bloc à lire
contenuMeta	Variable	Contenu de la métadonnée

Description

La commande GET PICTURE METADATA permet de lire le contenu de métadonnées (ou méta-balises) présentes dans image (champ ou une variable image 4D). Pour plus d’informations sur les métadonnées, reportez-vous à la description de la commande SET PICTURE METADATA.

Passez dans le paramètre nomMeta une chaîne désignant le type de métadonnée à récupérer. Vous pouvez passer :

une constante du thème "Noms des métadonnées images" contenant un chemin de balise,
le nom d’un bloc complet de métadonnées ("TIFF", "EXIF", "GPS" ou "IPTC"),
une chaîne vide ("").

Passez dans le paramètre contenuMeta la variable destinée à recevoir les métadonnées.

Si vous avez passé un chemin de balise dans nomMeta, contenuMeta contient directement la valeur à lire. La valeur sera convertie dans le type de la variable (si le type de la variable n'est pas défini, le type texte est utilisé par défaut). Les variables de type texte seront formatées en XML (norme XMP). Vous pouvez passer un tableau lorsque la métadonnée contient plus d’une valeur (c’est le cas notamment pour les balises IPTC keywords).
Si vous avez passé un nom de bloc ou une chaîne vide dans nomMeta, contenuMeta doit être une référence d’élément DOM XML valide. Dans ce cas, le contenu du bloc désigné (ou de tous les blocs si vous avez passé une chaîne vide dans nomMeta) est recopié dans l’élément référencé.

Exemple 1

Utilisation d’arbres DOM

 $xml:=DOM Create XML Ref("Root") //Création d'un arbre XML DOM

 

     //Réception des métadonnées TIFF

 $_Xml_TIFF:=DOM Create XML element($xml;"/Root/TIFF")

 GET PICTURE METADATA(vPicture;"TIFF";$_Xml_TIFF)

 

     //Réception des métadonnées GPS

 $_Xml_GPS:=DOM Create XML element($xml;"/Root/GPS")

 GET PICTURE METADATA(vPicture;"GPS";$_Xml_GPS)

Exemple 2

Utilisation de variables

 C_DATE($dateAsDate)

 GET PICTURE METADATA(vImage;TIFF date time;$dateAsDate)  //retourne uniquement la date car "$dateAsDate" est de type Date

 

 C_TEXT($dateAsText)

 GET PICTURE METADATA(vImage;TIFF date time;$dateAsText)  //retourne uniquement la date mais au format XML

 

 C_INTEGER($urgency)

 GET PICTURE METADATA(vImage;IPTC urgency;$urgency)

Exemple 3

Réception de balises à valeurs multiples dans des tableaux

 ARRAY TEXT($tTkeywords;0)

 GET PICTURE METADATA(vImage;IPTC keywords;$tTkeywords)

Après exécution de la commande, tTkeywords contient par exemple :

 $tTkeywords{1}="france"

 $tTkeywords{2}="europe"

Exemple 4

Réception de balises à valeurs multiples dans une variable texte

 C_TEXT($vTmots;0)

 GET PICTURE METADATA(vImage;IPTC keywords;$vTmots)

Après exécution de la commande, vTmots contient par exemple "france;europe".

Variables et ensembles système

La variable système OK retourne 1 si la récupération des métadonnées s’est bien passée, et 0 si une erreur se produit ou si au moins une des balises n’est pas trouvée. Dans tous les cas, les valeurs lisibles sont retournées.

Voir aussi

GET PICTURE KEYWORDS
Noms des métadonnées images
SET PICTURE METADATA
Valeurs des métadonnées images