LISTE FENETRES

4D v20 R7

LISTE FENETRES


LISTE FENETRES ( fenêtres {; *} )

Paramètre	Type	Description
fenêtres	Tableau	Tableau des numéros de référence des fenêtres
*	Opérateur	Si omis, ignorer fenêtres flottantes Si spécifié, tenir compte des fenêtres flottantes

Description

La commande LISTE FENETRES remplit le tableau fenêtres avec les numéros de référence des fenêtres actuellement ouvertes dans tous les process (process moteur et process utilisateur). Seules les fenêtres "visibles" (i.e. non cachées) sont retournées.

Si vous ne passez pas le paramètre optionnel *, les fenêtres flottantes sont ignorées.

Exemple

La méthode projet suivante place en "mosaïque" toutes les fenêtres ouvertes (à l'exception des fenêtres flottantes et des boîtes de dialogue) :

  ` Méthode projet Mosaïque

 

 LISTE FENETRES($alWnd)

 $vlLeft:=10

 $vlTop:=80 ` Laissons de la place à la barre d'outils

 Boucle($vlWnd;1;Taille tableau($alWnd))

    Si(Type fenetre($alWnd{$vlWnd})#Fenêtre modale)

       COORDONNEES FENETRE($vlWL;$vlWT;$vlWR;$vlWB;$alWnd{$vlWnd})

       $vlWR:=$vlLeft+($vlWR-$vlWL)

       $vlWB:=$vlTop+($vlWB-$vlWT)

       $vlWL:=$vlLeft

       $vlWT:=$vlTop

       CHANGER COORDONNEES FENETRE($vlWL;$vlWT;$vlWR;$vlWB;$alWnd{$vlWnd})

       $vlLeft:=$vlLeft+10

       $vlTop:=$vlTop+25

    Fin de si

 Fin de boucle

Note : Cette méthode pourrait être améliorée par l'ajout de tests sur la taille de la fenêtre principale (sous Windows) ou sur la taille et l'emplacement du ou des écran(s) (sous Mac OS).

Voir aussi

Process de la fenetre
Type fenetre