WP Table get rows

4D v20 R7

WP Table get rows


WP Table get rows ( objTarget ) \| ( refTabla ; lineaIni {; numLíneas} ) -> Resultado

Parámetro	Tipo	Descripción
objTarget	Objeto	Rango o elemento o documento 4D Write Pro
refTabla	Objeto	Referencia de tabla
lineaIni	Entero largo, Cadena	Posición de la primera línea
numLíneas	Entero largo	Número de líneas a obtener
Resultado	Objeto	Nuevo rango de tablas que contiene las filas seleccionadas

Descripción

El comando WP Table get rows devuelve un nuevo objeto rango línea que contiene una selección de las líneas de objTarget o de refTabla.

Pase:

objTarget:
- un rango, o
- un elemento (fila / párrafo / cuerpo / encabezado / pie de página / imagen en línea / sección / subsección), o
- un documento 4D Write Pro

Si objTarget no se cruza con una tabla o rango de texto donde se puede recuperar una selección de filas, el comando devuelve Null.

refTabla: la referencia de la tabla cuya selección de filas desea obtener.
lineaIni: apunta a la primera fila de la tabla a devolver y
(opcional) numLineas - especifica cuántas filas se devuelven. Si se omite numLineas, se devuelve la fila lineaIni.

Si lineaIni más numLineas exceden el número de filas en refTabla, o si lineaIni es mayor que el número de filas en refTabla, el rango devuelto contiene el máximo número de filas posible.

refTabla: la referencia de la tabla cuya(s) línea(s) de encabezado desea obtener.
wk header rows: para indicar que se desea obtener las líneas de encabezado

En ese caso, el comando devuelve un rango de líneas que contiene las líneas de encabezado repetidas (si se pasa, se ignora el parámetro numFilas). El comando devuelve Null si no hay filas de encabezado definidas.

Ejemplo 1

Desea definir un color de fondo específico para las dos primeras líneas de una tabla y modificar el borde de la tercera línea:

 var $wpTable;$wpRange;$wpRow1;$wpRow2;$wpRow3;$wpRow4;$wpRow5;$rows;$rows2 : Object

 $wpRange:=WP Text range(WParea;wk start text;wk end text)

 

 $wpTable:=WP Insert table($wpRange;wk append)

 $wpRow1:=WP Table append row($wpTable;"Paul";"Smith";25)

 $wpRow2:=WP Table append row($wpTable;"John";"Richmond";40)

 $wpRow3:=WP Table append row($wpTable;"Mary";"Trenton";18)

 $wpRow4:=WP Table append row($wpTable;"Christopher";"Lee";53)

 $wpRow5:=WP Table append row($wpTable;"Henry";"Cartier";42)

 

 $rows:=WP Table get rows($wpTable;1;2)

 WP SET ATTRIBUTES($rows;wk background color;0x00E0F0FF)

 $rows2:=WP Table get rows($wpTable;3)

 WP SET ATTRIBUTES($rows2;wk border style;wk solid)

 WP SET ATTRIBUTES($rows2;wk border width;4)

Ejemplo 2

Para obtener un rango de líneas desde el 10 hasta el final:

WP Table get rows(tableRef;10;MAXLONG)

Ejemplo 3

Desea recuperar las líneas que un usuario ha seleccionado:

 var $userSelection;$rows : Object

 

 $userSelection:=WP Selection range(myWPArea)

 

 $rows:=WP Table get rows($userSelection)

Ejemplo 4

El siguiente ejemplo:

Obtiene las dos primeras líneas de la primera tabla de WParea.
Las define como líneas de encabezado.
Define su color de texto en blanco y su color de fondo en negro.

 var $table;$range : Object

 

 $table:=WP Get elements(WParea;wk type table)[0]  // Selecciona la primera tabla en WParea

 

 WP SET ATTRIBUTES($table;wk header row count;2) // Define las dos primeras líneas como líneas de encabezado

 

 $range:=WP Table get rows($table;wk header rows) // Obtiene las líneas de encabezado definidas anteriormente

 

 WP SET ATTRIBUTES($range;wk text color;"white";wk background color;"#000") // Define el texto y el color de fondo de las líneas de encabezado

Ver también

WP Insert table
WP Table append row
WP Table get cells
WP Table get columns