WP Table get rows

Home

4D v20 R7

WP Table get rows


WP Table get rows ( targetObj ) \| ( TabelleRef ; StartZeile {; AnzZeilen} ) -> Funktionsergebnis

Parameter	Typ	Beschreibung
targetObj	Objekt	Range oder Element oder 4D Write Pro Dokument
TabelleRef	Objekt	Referenz auf Tabelle
StartZeile	Lange Ganzzahl, String	Position der ersten Zeile
AnzZeilen	Lange Ganzzahl	Anzahl der zu erhaltenden Zeilen
Funktionsergebnis	Objekt	Neuer Ausschnitt mit den gewählten Zeilen

Beschreibung

Der Befehl WP Table get rows gibt ein neues Zeile Range-Objekt zurück, das eine Auswahl von Zeilen aus targetObj oder tableRef enthält.

Passen Sie entweder:

targetObj:
- einen Range, oder
- ein Element (Zeile / Absatz / Hauptteil / Kopfteil / Fußteil / Inline-Bild / Abschnitt / Unterabschnitt), oder
- ein 4D Write Pro Dokument

Wenn sich targetObj nicht mit einer Tabelle oder einem Textbereich überschneidet, in dem eine Auswahl von Zeilen abgerufen werden kann, gibt der Befehl Null zurück.

ODER

tableRef: der Verweis auf die Tabelle, deren Zeilen Sie abrufen möchten.
startRow: verweist auf die erste zurückzugebende Tabellenzeile, und
(optional) numRows - gibt an, wie viele Zeilen zurückgegeben werden sollen. Wenn numRows weggelassen wird, wird die einzelne startRow-Zeile zurückgegeben.

Wenn startRow plus numRows die Anzahl der Zeilen in tableRef überschreitet oder wenn startRow größer ist als die Anzahl der Zeilen in tableRef, enthält der zurückgegebene Range die maximal möglichen Zeilen.

ODER

tableRef: der Verweis auf die Tabelle, deren Kopfteil(e) Sie abrufen möchten.
wk header rows: um anzugeben, dass Sie Kopfteile abrufen möchten.

In diesem Fall gibt der Befehl einen Range zurück, der die wiederholten Kopfteile enthält (falls übergeben, wird der Parameter numRows ignoriert). Der Befehl gibt Null zurück, wenn es keine definierten Kopfteile gibt.

Beispiel 1

Sie möchten eine bestimmte Hintergrundfarbe für die ersten beiden Zeilen einer Tabelle festlegen und den Rahmen der dritten Zeile ändern:

 var $wpTable;$wpRange;$wpRow1;$wpRow2;$wpRow3;$wpRow4;$wpRow5;$rows;$rows2 : Object

 $wpRange:=WP Text range(WParea;wk start text;wk end text)

 

 $wpTable:=WP Insert table($wpRange;wk append)

 $wpRow1:=WP Table append row($wpTable;"Paul";"Smith";25)

 $wpRow2:=WP Table append row($wpTable;"John";"Richmond";40)

 $wpRow3:=WP Table append row($wpTable;"Mary";"Trenton";18)

 $wpRow4:=WP Table append row($wpTable;"Christopher";"Lee";53)

 $wpRow5:=WP Table append row($wpTable;"Henry";"Cartier";42)

 

 $rows:=WP Table get rows($wpTable;1;2)

 WP SET ATTRIBUTES($rows;wk background color;0x00E0F0FF)

 $rows2:=WP Table get rows($wpTable;3)

 WP SET ATTRIBUTES($rows2;wk border style;wk solid)

 WP SET ATTRIBUTES($rows2;wk border width;4)

Beispiel 2

Einen Ausschnitt ab der 10. Zeile bis zum Ende erhalten:

WP Table get rows(tableRef;10;MAXLONG)

Beispiel 3

Sie möchten die Zeilen abrufen, die ein User ausgewählt hat:

 var $userSelection;$rows : Object

 

 $userSelection:=WP Selection range(myWPArea)

 

 $rows:=WP Table get rows($userSelection)

Beispiel 4

Das folgende Beispiel:

Ruft die ersten beiden Zeilen der ersten Tabelle in WParea ab.
Legt sie als Kopfteil-Zeilen fest.
Legt ihre Textfarbe auf weiß und ihre Hintergrundfarbe auf schwarz fest.

 var $table;$range : Objekt

 

 $table:=WP Get elements(WParea;wk type table)[0]  // Wählen Sie die erste Tabelle in WParea

 

 WP SET ATTRIBUTES($table;wk header row count;2) // Setzen Sie die ersten beiden Zeilen als Kopfteile

 

 $range:=WP Table get rows($table;wk header rows) // Holt die oben definierten Kopfteile

 

 WP SET ATTRIBUTES($range;wk text color;"white";wk background color;"#000") // Text und Hintergrundfarbe für die Kopfteile festlegen

Siehe auch

WP Insert table
WP Table append row
WP Table get cells
WP Table get columns