WP Table get cells

Home

4D v20 R7

WP Table get cells


WP Table get cells ( targetObj ) \| ( TabelleRef ; StartSpalte ; StartZeile {; AnzSpalten{; AnzZeilen}} ) -> Funktionsergebnis

Parameter	Typ	Beschreibung
targetObj	Objekt	Range oder Element oder 4D Write Pro Dokument
TabelleRef	Objekt	Referenz auf Tabelle
StartSpalte	Lange Ganzzahl	Position der ersten Spaltenzelle
StartZeile	Lange Ganzzahl	Position der ersten Spaltenzeile
AnzSpalten	Lange Ganzzahl	Anzahl der zu erhaltenden Spalten
AnzZeilen	Lange Ganzzahl	Anzahl der zu erhaltenden Zeilen
Funktionsergebnis	Objekt	Neuer Zellenausschnitt

Beschreibung

Die Funktion WP Table get cells gibt ein neues Objekt Zellen-Range mit der Zellenauswahl von TabelleRef zurück, definiert durch StartSpalte, StartZeile, AnzSpalten und AnzZeilen.

Sie können folgendes übergeben:

targetObj:
- ein Range oder
- ein Element (Zeile / Absatz / Hauptteil / Kopfteil / Fußteil / eingebundenes Bild / Abschnitt / Unterabschnitt) oder
- ein 4D Write Pro Dokument

Ist targetObj ein Tabellen- oder Text-Range, der keine Zellenauswahl enthält, gibt der Befehl Null zurück.

oder

StartSpalte und StartZeile - definieren die Koordinaten der linken oberen Ecke der ersten zu erhaltenden Zelle
(optional) AnzSpalten und AnzZeilen - geben jeweils die Anzahl Spalten und Zeilen für den Zellen-Range an

Ohne den Parameter AnzZeilen wird eine einzelne Zeile zurückgegeben. Werden AnzSpalten und AnzZeilen weggelassen, enthält der zurückgegebene Range eine einzelne Zelle.

Übersteigt die Summe von StartSpalte plus AnzSpalte bzw. StartZeile plus AnzZeilen die Anzahl von Spalten/Zeilen in TabelleRef, oder ist StartSpalte bzw. StartZeile größer als die Anzahl Spalten/Zeilen in TabelleRef, enthält der zurückgegebene Range die max. möglichen Spalten/Zeilen.

Beispiel 1

Die Attribute eines Zellen-Range ändern:

 C_OBJECT($wpTable;$wpRange;$wpRow1;$wpRow2;$wpRow3;$wpRow4;$wpRow5;$cells)

 $wpRange:=WP Create range(WParea;wk start text;wk end text)

 

 $wpTable:=WP Insert table($wpRange;wk append)

 $wpRow1:=WP Table append row($wpTable;"Paul";"Smith";25)

 $wpRow2:=WP Table append row($wpTable;"John";"Richmond";40)

 $wpRow3:=WP Table append row($wpTable;"Mary";"Trenton";18)

 $wpRow4:=WP Table append row($wpTable;"Christopher";"Lee";53)

 $wpRow5:=WP Table append row($wpTable;"Henry";"Cartier";42)

 

 $cells:=WP Table get cells($wpTable;2;2;2;2)

 WP SET ATTRIBUTES($cells;wk background color;0x00E0E0E0)

 WP SET ATTRIBUTES($cells;wk text color;"blue")

 WP SET ATTRIBUTES($cells;wk border color;0x00E000E0)

 WP SET ATTRIBUTES($cells;wk text align;wk center)

Ergebnis:

Beispiel 2

Ein Zellen-Range ab der Zelle "5x7" bis zum Ende der Zeile erhalten:

$cellRange:=WP Table get cells(tableRef;5;7;MAXLONG;1)

Ein Zellen-Range ab der Zelle "5x7" bis zum Ende der Spalte erhalten:

$cellRange:=WP Table get cells(tableRef;5;7;1;MAXLONG)

Ein Zellen-Range ab der Zelle "5x7" bis zum Ende der Tabelle erhalten:

$cellRange:=WP Table get cells(tableRef;5;7;MAXLONG;MAXLONG)

Beispiel 3

Vom Benutzer ausgewählte Zellen herausfinden.

 C_OBJECT($userSelection;$cells)

 

 $userSelection:=WP Selection range(myWPArea)

 

 $cells:=WP Table get cells($userSelection)

Siehe auch

WP Table get columns
WP Table get rows