WP SET ATTRIBUTES

Home

4D v20 R7

WP SET ATTRIBUTES


WP SET ATTRIBUTES ( targetObj ; attribName ; attribValue {; attribName2 ; attribValue2 ; ... ; attribNameN ; attribValueN} )

Parameter	Typ	Beschreibung
targetObj	Objekt	Range, Element oder 4D Write Pro Dokument
attribName	Text	Name des zu setzenden Attributs
attribValue	Text, Zahl, Objekt, Collection, Bild, Datum	Neuer Attributwert

Beschreibung

Der Befehl WP SET ATTRIBUTES setzt den Wert jedes Attributs in einem Range, Element oder 4D Write Pro Dokument. Dieser Befehl gibt Ihnen Zugriff auf die verschiedenen internen Attribute von 4D Write Pro: Zeichen, Absatz, Dokument, Tabelle oder Bild.

Im Parameter targetObj übergeben Sie:

Range oder
Element (Tabelle, Zeile, Absatz, verankertes Bild, Bild im Textfluss, Haupt-, Kopf-, Fußteil, Abschnitt, Unterabschnitt, Stilvorlage) oder
4D Write Pro Dokument

In attribName übergeben Sie den Namen des Attributs für das Ziel, in attribValue den neu zu setzenden Wert. Weitere Informationen dazu finden Sie im Abschnitt 4D Write Pro Attribute.

Sie können beliebig viele Paare attribName / attribValue übergeben.

Hinweis: Müssen Sie mehrere Attribute für dasselbe Ziel setzen, ist es optimaler, einen einzelnen Aufruf von WP SET ATTRIBUTES mit allen Attribut/Werte Paaren zu setzen, als WP SET ATTRIBUTES mehrere Male aufzurufen.

Beispiel 1

In diesem 4D Write Pro Bereich haben Sie ein Wort ausgewählt:

Führen Sie folgenden Code aus:

 $range:=WP Get selection(*;"WParea") //ausgewählten Bereich erhalten

 

  // Schattenversatz für das gewählte Wort in pt setzen

 WP SET ATTRIBUTES($range;wk text shadow offset;1)

  //Füllen für dieses Wort setzen

 WP SET ATTRIBUTES($range;wk padding;1)

  //einen Rahmen mit 10 pt setzen

 WP SET ATTRIBUTES($range;wk border style;wk solid;wk border width;10)

  //Rahmenfarbe definieren

 WP SET ATTRIBUTES($range;wk border color;"blau";wk border color bottom;"#00FA9A";wk border color right;"#00FA9A")

erhalten Sie dieses Ergebnis:

Beispiel 2

Dieses Beispiel zeigt die Verwendung der Konstanten wk inside und wk outside:

 $wpRange:=WP Get selection(writeProdoc)

 WP SET ATTRIBUTES($wpRange;wk border style+wk inside;wk dotted)

 WP SET ATTRIBUTES($wpRange;wk border style+wk outside;wk solid)

 WP SET ATTRIBUTES($wpRange;wk border color+wk outside;"#00FA9A")

Wurde der ganze Inhalt ausgewählt, erhalten Sie dieses Ergebnis:

Beispiel 3

Sie wollen ein Hintergrundbild für das Dokument setzen:

 C_OBJECT(WParea)

 WParea:=WP New

 

 READ PICTURE FILE("C:\\Pictures\\boats.jpg";$picture)

 

 WP SET ATTRIBUTES(WParea;wk background image;$picture)

Das Ergebnis ist:

Sie wollen ein Hintergrundbild setzen, das den gesamten druckbaren Bereich ausfüllt:

 C_OBJECT(WParea)

 WParea:=WP New

 

 READ PICTURE FILE("C:\\Pictures\\boats.jpg";$picture)

 

 WP SET ATTRIBUTES(WParea;wk background image;$picture)

 WP SET ATTRIBUTES(WParea;wk background clip;wk paper box)

 WP SET ATTRIBUTES(WParea;wk background origin;wk paper box)

Das Ergebnis ist:

Hinweis: Die Konstante wk paper box ist nur für Dokumente und Abschnitte verwendbar.

Beispiel 4

Tabulatoren mit verschiedenen Abständen und führenden Zeichen für den letzten Tab setzen:

 $tab1:=New object()

 $tab1[wk type]:=wk left

 $tab1[wk offset]:="3cm"

 $tab1[wk leading]:=""

 

 $tab2:=New object()

 $tab2[wk type]:=wk center

 $tab2[wk offset]:="8cm"

 $tab2[wk leading]:=""

 

 $tab3:=New object()

 $tab3[wk type]:=wk right

 $tab3[wk offset]:="12cm"

 $tab3[wk leading]:="."

 

 $_tabs:=New collection($tab1;$tab2;$tab3)

 WP SET ATTRIBUTES(wpArea;wk tabs;$_tabs)

Das Ergebnis ist:

Siehe auch

4D Write Pro Attribute
WP GET ATTRIBUTES
WP RESET ATTRIBUTES