WP INSERT FORMULA

Home

4D v20 R7

WP INSERT FORMULA


WP INSERT FORMULA ( targetObj ; formula ; mode {; rangeUpdate} )

Parameter	Typ	Beschreibung
targetObj	Objekt	Range oder Element oder 4D Write Pro Dokument
formula	Objekt	Objekt Formel
mode	Zahl	Einfügemodus
rangeUpdate	Zahl	Fügt eingefügten Inhalt im Range ein oder nicht

Beschreibung

Der Befehl WP INSERT FORMULA fügt eine formula in targetObj gemäß dem Einfügemodus mode ein.

Im Parameter targetObj übergeben Sie:

ein Range oder
ein Element (Tabelle / Zeile / Zelle(n) / Absatz / Hauptteil / Kopfteil / Fußteil / Abschnitt / Unterabschnitt / eingebundenes Bild) oder
ein 4D Write Pro Dokument

Im Parameter formula übergeben Sie die auszuwertende 4D Formel. . Sie können übergeben:

entweder ein Formelobjekt, das mit dem Befehl Formula oder Formula from string erstellt wurde,
oder ein Objekt, das zwei Eigenschaften enthält:
Eigenschaft Typ Beschreibung
name String Name, der für die Formel im Dokument angezeigt werden soll
formula Objekt Das Formelobjekt, das mit dem Befehl Formula oder Formula from string erstellt wurde

Wenn Sie ein Objekt mit einem Formelnamen verwenden, wird dieser Name im Dokument anstelle der Formelreferenz angezeigt, wenn die Formeln als Referenz angezeigt werden, und im Formelhinweis, wenn sie als Wert oder Symbole angezeigt werden. Wenn die Eigenschaft name einen leeren String enthält oder ausgelassen wird, wird sie aus dem Objekt entfernt und die Formel wird standardmäßig angezeigt. Weitere Informationen finden Sie auf der Seite Formeln verwalten.

Im Parameter mode übergeben Sie eine der folgenden Konstanten für den Einfügemodus:

Konstante	Typ	Wert	Kommentar
wk append	Lange Ganzzahl	2	Fügt Inhalt am Ende des Ziels ein
wk prepend	Lange Ganzzahl	1	Fügt Inhalt am Anfang des Elements ein
wk replace	Lange Ganzzahl	0	Ersetzt Inhalt in Ziel

Ist targetObj ein Range, können Sie über den optionalen Parameter rangeUpdate eine der folgenden Konstanten übergeben, die definieren, ob die eingefügte formula im Ziel Range enthalten ist oder nicht:

Konstante	Typ	Wert	Kommentar
wk exclude from range	Lange Ganzzahl	1	Eingefügter Inhalt ist nicht im aktualisierten Range enthalten
wk include in range	Lange Ganzzahl	0	Eingefügter Inhalt ist im aktualisierten Range enthalten (Standard)

Ohne den Parameter rangeUpdate wird standardmäßig die eingefügte Formel formula im Ziel Range eingefügt.

Ist targetObj kein Range, wird rangeUpdate ignoriert.

Hinweis: Beachten Sie, dass das Formel-Objekt beim Aufruf im Kontext der Datenbank oder der Komponente ausgewertet wird, die es erstellt hat.

Beispiel 1

Alle Formeln für aktuelles Datum durch formatierte Strings ersetzen:

 C_COLLECTION($_formulas)

 C_OBJECT($find;$newFormula)

 

  // define the formula to find

 $find:=Formula(Current date)

 

  // define the replacement formula

 $newFormula:=Formula(String(Current date;System date long))

 

  // find all formulas in the document

 $_formulas:=WP Get formulas(WriteProArea)

 

  // query the collection from WP Get formulas

 $_formulas:=$_formulas.query("formula.source =:1";$find.source)&NBSP;&NBSP;

 

  // then replace each formula

 For each($formula;$_formulas)

    WP INSERT FORMULA($formula.range;$newFormula;wk replace)

 End for each

Beispiel 2

You want to use a formula name for the customer name:

  //add some data

 $data:=New object("customer";New object("lastname";"Smith";"firstname";"John"))

 WP SET DATA CONTEXT(WPArea;$data)

 

  //create a formula object with a name

 $o:=New object

 $o.formula:=Formula(This.data.customer.firstname+" "+This.data.customer.lastname)

 $o.name:="Customer name"

 

  //inserts as text

 $range:=WP Text range(WPArea;wk start text;wk end text)

 WP SET TEXT($range;"Dear ";wk append)

 WP INSERT FORMULA($range;$o;wk append)

Result:

Siehe auch

Formeln verwalten
WP COMPUTE FORMULAS
WP FREEZE FORMULAS
WP Get formulas