Datenbankmethode On Mobile App Action

Home

4D v19.8


$1 -> Datenbankmethode On Mobile App Action -> Funktionsergebnis

Parameter	Typ	Beschreibung
$1	Objekt	Von der mobilen App übergebene Information
Funktionsergebnis	Objekt	Status der Aktion & Datensynchronisation

Beschreibung

Die Datenbankmethode On Mobile App Action verwaltet Aktionen, die von der mobilen App für eine bestimmte Sitzung angefordert werden.

Hinweis: Die mobile App muss zuvor über die Datenbankmethode On Mobile App Authentication authentifiziert werden.

4D ruft diese Datenbankmethode auf, wenn eine mobile App eine Anfrage für eine Aktion sendet.

Hinweis: Weitere Informationen dazu finden Sie unter der 4D for iOS documentation.

Die Datenbankmethode empfängt die angeforderte Information von der mobilen App in Parameter $1 (object) und gibt den Status der Aktion im Parameter $0 (object) zurück. Sie müssen diese Parameter wie folgt deklarieren und initialisieren:

  //Datenbankmethode On Mobile App Action

 C_OBJECT($0;$1)

  // ...Code für die Methode

 $0:=New object //vergessen Sie nicht, das Objekt zum Zurückgeben zu erstellen

Der Parameter Objekt $1 empfängt folgende Eigenschaften:

Name der Eigenschaft		Typ	Beschreibung
action		Text	Name der Aktion
session		Objekt	Sitzungsinformation
	id	Text	Identifier der Sitzung
	ip	Text	IP der Sitzung
application		Objekt	Mobile Application Information
	id	Text	ID der Application
userInfo		Text	Benutzerinformation
context		Objekt	Kontextparameter für die angeforderte Aktion
	dataClass	Text	Name der 4D Dataclass
	entity.primaryKey	Text \| Lange Ganzzahl	(optional) Wird zurückgegeben, wenn sich die Aktion auf eine ausgewählte Entity bezieht. Primärschlüssel der Entity
	entity.relationName	Text	(optional) Wird zurückgegeben, wenn sich die Aktion auf eine verknüpfte Entity bezieht. Name der Viele-zu-Eine Verknüpfung
	parent.primaryKey	Text \| Lange Ganzzahl	(optional) Wird zurückgegeben, wenn sich die Aktion auf eine verknüpfte Entity bezieht. Primärschlüssel der parent Entity
	parent.relationName	Text	(optional) Wird zurückgegeben, wenn sich die Aktion auf eine verknüpfte Entity bezieht. Name der Eine-zu-Viele Verknüpfung
	parent.dataClass	Text	(optional) Wird zurückgegeben, wenn sich die Aktion auf eine verknüpfte Entity bezieht. Name der parent 4D Dataclass

Nach Bearbeiten der Angaben gibt die Datenbankmethode in $0 ein Objekt mit folgenden Eigenschaften zurück:

Name der Eigenschaft	Typ	Beschreibung
success	Boolean	Wahr, wenn die Aktion erfolgreich bearbeitet wurde. Sonst Falsch
statusText	Text	(Optional) Meldung zur Anzeige auf der mobilen App. Wenn success=true, Erfolgsmeldung anzeigen; wenn success=false, kann der Benutzer eine Meldung mit Erklärung erhalten
dataSynchro	Boolean	Wahr, wenn die Entity oder Table Selection erneuert werden muss, sonst falsch. Bei Wahr löst die mobile App automatisch eine Synchronisation der Daten aus.

Beispiel

  // On Mobile App Action

  // 2 Aktionen sind definiert: "done" und "postponeAll"

 

 C_OBJECT($0)

 C_OBJECT($1)

 

 C_OBJECT($o;$context;$request;$result)

 

 $request:=$1 //von der mobilen App gelieferte Information

 $context:=$request.context

 

 Case of

 

    :($request.action="done")

       $o:=New object(\

       "dataClass";$context.dataClass;\

       "ID";$context.entity.primaryKey;\

       "CompletePercentage";100)

 

       $result:=modifyStatus($o) //Ihre Projektmethode aufrufen, um den Status der Entity ändern

 

    :($request.action="postponeAll")

       $o:=New object("dataClass";$context.dataClass)

 

       $result:=postponeAll($o) //Ihre Projektmethode aufrufen, um alle Entities der dataClass zurückzustellen

 

    Else //Unbekannte Anfrage

       $result:=New object("success";False)

 

 End case

 

 $0:=$result  //an die mobile App zurückgegebene Information

Siehe auch

Datenbankmethode On Mobile App Authentication