Método base On Mobile App Action

4D v19.8


$1 -> Método base On Mobile App Action -> Resultado

Parámetro	Tipo	Descripción
$1	Objeto	Información pasada por la aplicación móvil
Resultado	Objeto	Estado de acción y sincronización de datos

Descripción

El Método base On Mobile App Action se encarga de administrar las acciones requeridas por la aplicación móvil para una sesión específica.

Nota: la aplicación móvil debe haber sido autenticada por Método base On Mobile App Authentication.

4D llama a este método base cuando una aplicación móvil envía una solicitud de acción.

Nota: para más información, consulte la documentación de 4D for iOS.

El método base recibe la información requerida de la aplicación móvil en el parámetro $1 (objeto), y debe devolver el estado de la acción en el parámetro $0 (objeto). Debe declarar e inicializar estos parámetros de la siguiente manera:

  //Método base On Mobile App Action

 C_OBJECT($0;$1)

  // ...Código para el método

 $0:=New object //No olvide crear el objeto a devolver

Las siguientes propiedades se reciben en el parámetro objeto $1:

Nombre de la propiedad	Tipo	Descripción
action		Texto	Nombre de acción
session		Objeto	Información de la sesión
	id	Texto	Identificador de sesión
	ip	Texto	IP de la sesión
application		Objeto	Información de la aplicación móvil
	id	Texto	ID de la aplicación
userInfo		Texto	Información usuario
context		Objeto	Parámetros de contexto para la acción solicitada
	dataClass	Texto	Nombre del dataclass 4D
	entity.primaryKey	Texto \| Entero largo	(opcional, devuelto si la acción está relacionada con una selección de entidades) Llave primaria de la entidad.
	entity.relationName	Texto	(opcional, se devuelve si la acción está relacionada con una entidad relacionada) Nombre de la relación Muchos a Uno
	parent.primaryKey	Texto \| Entero largo	((opcional, devuelta si la acción está relacionada con una entidad asociada) Llave primaria de la entidad padre.
	parent.relationName	Texto	((opcional, devuelta si la acción está relacionada con una entidad asociada) Nombre de la relación Uno a Muchos
	parent.dataClass	Texto	(opcional, devuelto si la acción está relacionada con una entidad asociada) Nombre de la clase de datos 4D padre.

Después de procesar la información, el método base debe devolver un objeto con las siguientes propiedades en $0:

Nombre de la propiedad	Tipo	Descripción
success	Booleano	True si la acción se ha procesado correctamente, en caso contrario False.
statusText	Texto	(Opcional) Mensaje a mostrar en la aplicación móvil. Si success=true, muestra el mensaje; si success= false, puede usarse para ofrecer al usuario una explicación
dataSynchro	Booleano	True si la selección de entidad o de la tabla necesita actualizarse, de lo contrario false. Si es True, la aplicación móvil activará automáticamente una sincronización de datos

Ejemplo

  // On Mobile App Action

  // 2 acciones son definidas: "done" y"postponeAll"

 

 C_OBJECT($0)

 C_OBJECT($1)

 

 C_OBJECT($o;$context;$request;$result)

 

 $request:=$1 //Información suministrada por la app móvil</p> <p>$context:=$request.context

 

 Case of

 

    :($request.action="done")

       $o:=New object(\

       "dataClass";$context.dataClass;\

       "ID";$context.entity.primaryKey;\

       "CompletePercentage";100)

 

       $result:=modifyStatus($o) //llamada al método proyecto para modificar el estado de la entidad

 

    :($request.action="postponeAll")

       $o:=New object("dataClass";$context.dataClass)

 

       $result:=postponeAll($o) //llamada al método proyecto para postponer todas las entidades del dataClass

 

    Else //Solicitud desconocida

       $result:=New object("success";False)

 

 End case

 

 $0:=$result  //Información devuelta por la app móvil

Ver también

Método base On Mobile App Authentication