collection.extract( )

4D v19.8


collection.extract ( rutaProp {; rutaObj}{; rutaProp2 ; rutaObj2 ; ... ; rutaPropN ; rutaObjN}{; opcion}) -> Resultado

Parámetro	Tipo	Descripción
rutaProp	Texto	Ruta de la propiedad del objeto cuyos valores deben extraerse a la nueva colección
rutaObj	Texto	Ruta de la propiedad objetivo o nombre de propiedad
opcion	Entero largo	ck keep null: incluye propiedades nulas en la colección devuelta (ignorada por defecto). El parámetro ignorado si se pasó rutaObj.
Resultado	Collection	Nueva colección que contiene valores extraídos

Descripción

La función collection.extract( ) crea y devuelve una nueva colección que contiene los valores rutaProp extraídos de la colección original de objetos.

Nota: este comando no modifica la colección original.

El contenido de la colección devuelta depende del parámetro rutaObj:

Si se omite el parámetro rutaObj, collection.extract( ) llena la nueva colección con los valores de rutaProp de la colección original.
De forma predeterminada, los elementos para los que rutaProp es null o indefinido se ignoran en la colección resultante. Puede pasar la constante ck keep null en el parámetro opcion para incluir estos valores como elementos null en la colección devuelta.

Si se pasan uno o más parámetros rutaObj, collection.extract( ) llena la nueva colección con las propiedades rutaProp y cada elemento de la nueva colección es un objeto con las propiedades rutaObj llenas con las propiedades rutaProp. Los valores nulos se mantienen (el parámetro opcion se ignora con esta sintaxis).

Ejemplo 1

 C_COLLECTION($c)

 $c:=New collection

 $c.push(New object("name";"Cleveland"))

 $c.push(New object("zip";5321))

 $c.push(New object("name";"Blountsville"))

 $c.push(42)

 $c2:=$c.extract("name") // $c2=[Cleveland,Blountsville]

 $c2:=$c.extract("name";ck keep null) //$c2=[Cleveland,null,Blountsville,null]

Ejemplo 2

 C_COLLECTION($c)

 $c:=New collection

 $c.push(New object("zc";35060))

 $c.push(New object("name";Null;"zc";35049))

 $c.push(New object("name";"Cleveland";"zc";35049))

 $c.push(New object("name";"Blountsville";"zc";35031))

 $c.push(New object("name";"Adger";"zc";35006))

 $c.push(New object("name";"Clanton";"zc";35046))

 $c.push(New object("name";"Clanton";"zc";35045))

 $c2:=$c.extract("name";"City") //$c2=[{City:null},{City:Cleveland},{City:Blountsville},{City:Adger},{City:Clanton},{City:Clanton}]

 $c2:=$c.extract("name";"City";"zc";"Zip") //$c2=[{Zip:35060},{City:null,Zip:35049},{City:Cleveland,Zip:35049},{City:Blountsville,Zip:35031},{City:Adger,Zip:35006},{City:Clanton,Zip:35046},{City:Clanton,Zip:35045}]

Ver también

collection.map( )
entitySelection.extract( )