dataStore.startRequestLog()

Home

4D v19.8


dataStore.startRequestLog() ( {file \| reqNum} )

Parameter	Typ	Beschreibung
file \| reqNum	Objekt, Lange Ganzzahl	Objekt Datei oder Anzahl der im Speicher verbleibenden Anfragen

Beschreibung

Die Methode dataStore.startRequestLog() startet das Logbuch der ORDA Anfragen auf der Client Seite.

Die Methode muss auf einem remote 4D aufgerufen werden, sonst führt sie nichts aus. Sie wurde zum Debuggen in Client/Server Konfigurationen eingerichtet.

Das Logbuch ORDA client requests wird je nach dem übergebenen Parameter an eine Datei oder zum Speicher gesendet:

Haben Sie ein Objekt file übergeben (erstellt mit dem Befehl File), werden die Daten des Logbuchs als Collection von Objekten in diese Datei geschrieben (JSON Format). Jedes Objekt stellt eine Anfrage dar.
Existiert die Datei noch nicht, wird sie angelegt. Ist sie bereits vorhanden, werden die neuen protokollierten Daten angehängt.
Wird dataStore.startRequestLog() mit file aufgerufen, wenn bereits ein Logbuch im Speicher gestartet wurde, wird das Logbuch im Speicher gestoppt und geleert.
Hinweis: Für eine JSON Validierung müssen Sie das Zeichen ] manuell an das Ende der Datei anhängen.

Haben Sie eine Zahl im Parameter reqNum (Lange Ganzzahl) übergeben, wird das Logbuch im Speicher geleert (sofern vorhanden) und ein neues Logbuch initialisiert. Es behält die Anfragen reqNum bis zur angegebenen Anzahl im Speicher, dann wird die älteste entfernt (FIFO Stack).
Wird dataStore.startRequestLog() mit einer Nummer reqNum aufgerufen und ist bereits ein Logbuch in einer Datei gestartet, stoppt das Protokollieren der Datei.

Haben Sie keinen Parameter übergeben, startet das Logbuch im Speicher. Wurde dataStore.startRequestLog() zuvor mit einer Nummer reqNum (vor einem stopRequestLog( )) aufgerufen, werden die Daten des Logbuchs im Speicher gestapelt, bis das Logbuch geleert oder stopRequestLog() aufgerufen wird.

Weitere Informationen dazu finden Sie im Abschnitt ORDA Client Anfragen.

Beispiel 1

ORDA Client Anfragen mit Sequenznummer in einer Datei protokollieren:

 C_OBJECT($e;$file)

 $file:=File("/LOGS/ORDARequests.txt") //Ordner für das Logbuch

 

 SET DATABASE PARAMETER(Client Log Recording;1) //Globale Sequenznumer des Logbuchs auslösen

 ds.startRequestLog($file)

 $e:=ds.Persons.get(30001) //Eine Anfrage senden

 ds.stopRequestLog()

 SET DATABASE PARAMETER(Client Log Recording;0)

Beispiel 2

ORDA Client Anfragen im Speicher protokollieren:

 C_OBJECT($es)

 C_COLLECTION($log)

 

 ds.startRequestLog(3) //3 Anfragen im Speicher halten

 

 $es:=ds.Persons.query("name=:1";"Marie")

 $es:=ds.Persons.query("name IN :1";New collection("Marie"))

 $es:=ds.Persons.query("name=:1";"So@")

 

 $log:=ds.getRequestLog()

 ALERT("The longest request lasted: "+String($log.max("duration"))+" ms")

Siehe auch

dataStore.getRequestLog()
dataStore.stopRequestLog()