dataStore.startRequestLog( )

4D v19.8


dataStore.startRequestLog ( {file \| reqNum} )

Paramètre	Type	Description
file \| reqNum	Objet, Entier long	fichier \| numReq

Description

La méthode dataStore.startRequestLog( ) lance l'enregistrement les requêtes ORDA clientes.

Cette méthode doit être appelée sur un 4D distant, sinon elle ne fait rien. Elle est conçue à des fins de débogage dans les configurations client/serveur.

L'enregistrement des requêtes ORDA peut être envoyé à un fichier ou à la mémoire, en fonction du paramètre que vous avez passé dans la méthode :

Si vous avez passé un objet fichier créé à l'aide de la commande File, les données de l'enregistrement sont contenues dans ce fichier sous forme de collection d'objets (format JSON). Chaque objet représente une requête.
Si le fichier n'existe pas encore, il est créé. Sinon, s'il existe déjà, les nouvelles données du fichier y sont annexées.
Si la méthode dataStore.startRequestLog( ) est appelée avec fichier durant un enregistrement préalablement lancé dans la mémoire, l'enregistrement de la mémoire est stoppé et vidé.
Note : Un caractère ] doit être ajouté manuellement à la fin du fichier pour effectuer une validation JSON.

Si vous avez passé un numéro dans le paramètre numReq (entier long), l'enregistrement dans la mémoire est vidé (le cas échéant) et un nouvel enregistrement est lancé. Il gardera en mémoire les requêtes numReq jusqu'à atteindre le numéro; auquel cas les entrées précédentes sont vidées (pile FIFO).
Si la méthode dataStore.startRequestLog( ) est appelée avec un numReq durant un enregistrement préalablement lancé dans un fichier, l'enregistrement du fichier est stoppé.

Si vous n'avez passé aucun paramètre, l'enregistrement est lancé dans la mémoire. Si la méthode dataStore.startRequestLog( ) a été préalablement appelée avec un reqNum (avant un stopRequestLog( )), les données enregistrées sont empilées dans la mémoire jusqu'au prochain enregistrement ou au prochain appel de stopRequestLog().

Pour plus de détails sur le format d'enregistrement des requêtes ORDA, veuillez consulter la section Requêtes ORDA clientes.

Exemple 1

Vous souhaitez enregistrer des requêtes ORDA clientes dans un fichier et utiliser le numéro de séquence de l'enregistrement :

 C_OBJECT($e;$file)

 $file:=File("/LOGS/ORDARequests.txt") //Dossier logs

 

 SET DATABASE PARAMETER(Enreg requêtes client;1) //pour déclencher le numéro de séquence de l'enregistrement

 ds.startRequestLog($file)

 $e:=ds.Persons.get(30001) //envoyer une requête

 ds.stopRequestLog()

 SET DATABASE PARAMETER(Enreg requêtes client;0)

Exemple 2

Vous souhaitez enregistrer des requêtes ORDA clientes dans la mémoire :

 C_OBJECT($es)

 C_COLLECTION($log)

 

 ds.startRequestLog(3) //garde 3 requêtes dans la mémoire

 

 $es:=ds.Persons.query("name=:1";"Marie")

 $es:=ds.Persons.query("name IN :1";New collection("Marie"))

 $es:=ds.Persons.query("name=:1";"So@")

 

 $log:=ds.getRequestLog()

 ALERT("La plus longue requête a duré : "+String($log.max("durée"))+" ms")

Voir aussi

dataStore.getRequestLog( )
dataStore.stopRequestLog( )