ds

4D v19.8

ds


ds {( localID )} -> Résultat

Paramètre	Type	Description
localID	Texte	Local ID of the remote datastore to return
Résultat	DataStore	Nouvelle référence de datastore

Description

La commande ds retourne une nouvelle référence vers le datastore correspondant à la base de données 4D courante ou à la base désignée par localID

Si vous omettez le paramètre localID (ou si vous passez une chaîne vide ""), la commande renvoie une référence au datastore correspondant à la base de données 4D locale (ou à la base 4D Server en cas d'ouverture d'une base de données distante sur 4D Server). Le datastore s'ouvre automatiquement et est disponible directement via ds.

Vous pouvez également obtenir une référence sur un datastore distant ouvert en passant son identifiant local (local ID) dans le paramètre localID. Le datastore doit avoir été préalablement ouvert avec la commande Open datastore par la base de données courante (hôte ou composant). L'identifiant local est défini lors de l'utilisation de cette commande.

Note : L'utilisation de ds nécessite que votre base soit conforme aux spécifications de ORDA telles que définies dans la section Prérequis pour ORDA.

Si aucun datastore nommé localID n'est trouvé, la commande renvoie Null.

L'utilisation de ds nécessite que la base de données cible soit conforme à ORDA, comme indiqué dans la section Prérequis pour ORDA. Les règles suivantes s'appliquent :

Le datastore référence uniquement les tables comportant une clé primaire simple. Les tables sans clé primaire ou avec une clé primaire composite ne sont pas référencées.
Les attributs de type BLOB ne sont pas gérés via le datastore.

Pour plus d'informations sur l'implémentation du datastore, veuillez vous reporter à la section Datastores.

Exemple 1

Utilisation du datastore courant de la base 4D :

$result:=ds.Employés.query("prénom = :1";"S@")

Exemple 2

 C_OBJECT($connectTo;$frenchStudents;$foreignStudents;$firstFrench;$firstForeign)

 

 $connectTo:=New object("type";"4D Server";"hostname";"192.168.18.11:8044")

 $frenchStudents:=Open datastore($connectTo;"french")

 

 $connectTo.hostname:="192.168.18.11:8050"

 $foreignStudents:=Open datastore($connectTo;"foreign")

  //...

  //...

 $firstFrench:=getFirst("french";"Students")

 $firstForeign:=getFirst("foreign";"Students")

  //méthode getFirst 

  //getFirst(localID;dataclass) -> entity

  // ---------------------

 C_TEXT($dataClassName;$2;$localId;$1)

 C_OBJECT($0)

 

 $localId:=$1

 $dataClassName:=$2

 $0:=ds($localId)[$dataClassName].all().first()

Voir aussi

Environnement 4D
Open datastore