REGENERER TABLE MANQUANTE

4D v20 R7


REGENERER TABLE MANQUANTE ( nomTable )

Paramètre	Type	Description
nomTable	Texte	Nom de table manquante à regénérer

Description

La commande REGENERER TABLE MANQUANTE reconstruit la table manquante dont vous avez passé le nom dans le paramètre nomTable. Lorsqu’une table manquante est reconstruite, elle devient visible dans l’éditeur de Structure et ses données sont de nouveau accessibles.

Les tables manquantes sont des tables dont les données sont présentes dans le fichier de données mais qui n’existent pas au niveau de la structure. Vous pouvez identifier les tables manquantes éventuellement présentes dans l’application à l’aide de la commande LIRE NOMS TABLES MANQUANTES.

Si la table désignée par le paramètre nomTable n’est pas une table manquante de la base, la commande ne fait rien.

Exemple

Cette méthode regénère toutes les tables manquantes éventuellement présentes dans la base :

 TABLEAU TEXTE($tMissingTables;0)

 LIRE NOMS TABLES MANQUANTES($tMissingTables)

 $SizeArray:=Taille tableau($tMissingTables)

 Si($SizeArray#0)

  // Remplir le tableau avec les noms de toutes les tables de la base

    TABLEAU TEXTE(tabTables;Lire numero derniere table)

    Si(Lire numero derniere table>0)    //S’il y a bien des tables

       Boucle($vlTables;Taille tableau(tabTables);1;-1)

          Si(Est un numero de table valide($vlTables))

             tabTables{$vlTables}:=Nom de la table($vlTables)

          Sinon

             SUPPRIMER DANS TABLEAU(tabTables;$vlTables)

          Fin de si

       Fin de boucle

    Fin de si

    Boucle($i;1;$SizeArray)

       Si(Chercher dans tableau(tabTables;$tMissingTables{$i})=-1)

          CONFIRMER("Regénérer la table"+$tMissingTables{$i}+" ?")

          Si(OK=1)

             REGENERER TABLE MANQUANTE($tMissingTables{$i})

          Fin de si

       Sinon

          ALERTE("Impossible de régénérer la table "+$tMissingTables{$i}+" car il y a déjà une table de ce nom dans la base.")

       Fin de si

    Fin de boucle

 Sinon

    ALERTE("Pas de tables à regénérer.")

 Fin de si

Voir aussi

LIRE NOMS TABLES MANQUANTES