entitySelection.drop()

Home

4D v19.8


entitySelection.drop() ( {mode} ) -> Funktionsergebnis

Parameter	Typ	Beschreibung
mode	Lange Ganzzahl	dk stop dropping on first error: Stoppt die Ausführung der Methode bei der ersten nicht löschbaren Entity
Funktionsergebnis	EntitySelection	Leere Entity-Selection, wenn erfolgreich; sonst Entity-Selection mit den nicht löschbaren Entities

Beschreibung

Die Methode entitySelection.drop() löscht die Entities, die zur Entity-Selection gehören. Die Entity-Selection bleibt im Speicher.

Hinweis: Löschen von Entities ist dauerhaft und lässt sich nicht rückgängig machen. Wir empfehlen daher, diese Aktion in einer Transaktion aufzurufen, um eine Rollback Option zu haben.

Wird beim Ausführen von entitySelection.drop() eine gesperrte Entity gefunden, wird sie nicht gelöscht. Standardmäßig bearbeitet die Methode alle Entities der Entity-Selection und gibt nicht-löschbare Entities in der Entity-Selection zurück. Soll die Methode bei der ersten gefundenen nicht-löschbaren Entity stoppen, übergeben Sie im Parameter mode die Konstante dk stop dropping on first error.

Beispiel

Beispiel ohne die Option dk stop dropping on first error:

 C_OBJECT($employees;$notDropped)

 $employees:=ds.Employee.query("firstName=:1";"S@")

 $notDropped:=$employees.drop() // $notDropped ist eine Entity-Selection mit allen nicht gelöschten Entities

 If($notDropped.length=0) //Löschen ist erfolgreich, alle Entities wurden gelöscht

    ALERT("You have dropped "+String($employees.length)+" employees") //Die gelöschte Entity-Selection bleibt im Speicher

 Else

    ALERT("Problem during drop, try later")

 End if

Beispiel mit der Option dk stop dropping on first error:

 C_OBJECT($employees;$notDropped)

 $employees:=ds.Employee.query("firstName=:1";"S@")

 $notDropped:=$employees.drop(dk stop dropping on first error) //$notDropped ist eine Entity-Selection mit der ersten nicht gelöschten Entity

 If($notDropped.length=0) //Löschen ist erfolgreich, alle Entities wurden gelöscht

    ALERT("You have dropped "+String($employees.length)+" employees") //Die gelöschte Entity-Selection bleibt im Speicher

 Else

    ALERT("Problem during drop, try later")

 End if

Siehe auch

entitySelection.add()