VP EXPORT DOCUMENT

4D v19

VP EXPORT DOCUMENT


VP EXPORT DOCUMENT ( vpAreaName ; filePath {; paramObj} )

Paramètre	Type	Description
vpAreaName	Texte	Nom de la zone 4D View Pro dans le formulaire
filePath	Texte	Chemin d'accès du document
paramObj	Objet	Options d'export

Description

La commande VP EXPORT DOCUMENT exporte l'objet 4D View Pro attaché à la zone 4D View Pro vpAreaName vers un document sur disque en fonction des paramètres filePath et paramObj.

Dans vpAreaName, passez le nom de la zone 4D View Pro. Si vous passez un nom inexistant, une erreur est retournée.

Dans filePath, passez le chemin de destination et le nom du document que vous souhaitez exporter. Vous pouvez préciser le format du document en incluant son extension, 4D View Pro (".4VP") ou Microsoft Excel (".xlsx"), pi PDF (".pdf") après le nom du document. Si vous passez simplement le nom du document, il sera sauvegardé au même niveau que le fichier de structure 4D avec l'extension par défaut ".4VP".

Le paramètre optionnel paramObj vous permet de définir plusieurs propriétés de l'objet 4D View Pro exporté et de lancer une méthode callback (ou méthode de rétro-appel) lorsque l'export est terminé.

Propriété

Type

Description

format

texte

(optionnel) Désigne le format du fichier exporté : ".4vp" (par défaut), ou ".xlsx", ou ".pdf". Vous pouvez passer une constante du thème Constantes 4D View Pro dans le paramètre format. Dans ce cas, 4D ajoute l'extension appropriée au nom du fichier, si nécessaire.

Les formats suivants sont pris en charge :

Constante	Valeur	Comment
vk 4D View Pro format	.4VP	Format 4D View Pro (format par défaut)
vk MS Excel format	.xlsx	Format Microsoft Excel
vk pdf format	.pdf	Format PDF

Si le format précisé ne correspond pas à l'extension dans le filePath, il sera ajouté à la fin du filePath. Si un format n'est pas précisé et si aucune extension n'est fournie dans filePath, le format de fichier par défaut est utilisé.

password

texte

Microsoft Excel uniquement (optionnel) - Mot de passe utilisé pour protéger le document MS Excel.

formula

objet

Méthode callback (ou méthode de rétro-rappel) à lancer lorsque l'export est terminé. L'utilisation d'une méthode callback est nécessaire lorsque l'export est asynchrone (ce qui est le cas pour les formats PDF et Excel) si vous avez besoin d'un code à exécuter après l'export. La méthode callback doit être utilisée avec la commande Formula (voir ci-dessous pour plus d'informations).

valuesOnly

booléen

Précise que seules les valeurs issues de formules (le cas échéant) seront exportées.

includeFormatInfo

booléen

Vrai pour inclure les informations de formatage, sinon faux (vrai par défaut). Les informations de formatage sont utiles dans certains cas, par exemple pour un export en SVG. Par ailleurs, mettre cette propriété à faux permet de réduire la durée de l'export.

sheetIndex

numérique

PDF uniquement (optionnel) - Indice de la feuille à exporter (commençant par 0). -2=toutes les feuilles visibles (par défaut), -1=feuille courante uniquement

pdfOptions

objet

PDF uniquement (optionnel) - Options pour l'export en PDF

Propriété	Type	Description
creator	texte	nom de l'application qui a créé le document original à partir duquel il a été converti.
title	texte	titre du document.
author	texte	nom de la personne ayant créé ce document.
keywords	texte	mots-clés associés au document.
subject	texte	suje du document.

Tous

Toute propriété personnalisée qui sera disponible avec le paramètre $3 dans la méthode de rétro-appel (callback).

Notes sur le format Excel :
- Lors de l'export d'un document 4D View Pro en un fichier au format Microsoft Excel, certains paramètres peuvent être perdus. Par exemple, les méthodes et formules 4D ne sont pas prises en charge par Excel. Vous pouvez vérifier les autres paramètres avec cette liste proposée par GrapeCity.
- L'export dans ce format est exécuté de manière asynchrone, utilisez la propriété formule de paramObj pour le code à exécuter après l'export.

Notes sur le format PDF :
- Lors de l'export d'un document 4D View Pro en un fichier au format PDF, les polices utilisées dans le document sont automatiquement intégrées dans le fichier PDF. Seules les polices OpenType (fichiers .OTF ou .TTF) contenant une carte Unicode peuvent être intégrées. Si aucun fichier de polices valide n'est trouvé pour une police, une police par défaut est utilisée à sa place.
- L'export dans ce format est exécuté de manière asynchrone, utilisez la propriété formule de paramObj pour le code à exécuter après l'export.

Une fois que l'export est terminé, VP EXPORT DOCUMENT exécute automatiquement la méthode paramétrée dans la propriété formula de paramObj, le cas échéant.

Passer une méthode callback

Lorsque vous passez le paramètre optionnel paramObj, la commande VP EXPORT DOCUMENT vous permet d'utiliser la commande Formula pour appeler une méthode 4D qui sera exécutée une fois que l'export sera terminé. La méthode callback recevra les valeurs suivantes en variables locales :

Variable		Type	Description
$1		texte	Nom de l'objet 4D View Pro
$2		texte	Chemin d'accès de l'objet 4D View Pro exporté
$3		objet	Référence au paramObj de la commande
$4		objet	Objet retourné par la méthode avec un message de statut
	.success	booléen	Vrai si l'export est réussi, Faux s'il ne l'est pas.
	.errorCode	entier	Code d'erreur. Peut être retourné par 4D ou JavaScript.
	.errorMessage	texte	Message d'erreur. Peut être retourné par 4D ou JavaScript.

Exemple 1

Vous souhaitez exporter le contenu de la zone "VPArea" vers un document 4D View Pro sur le disque :

 C_TEXT($docPath)

 $docPath:="C:\\ViewProDocs\\MyExport.4VP"

 VP EXPORT DOCUMENT("VPArea";$docPath)

   //MyExport.4VP est sauvegardé sur le disque

Exemple 2

Vous souhaitez exporter la feuille courante au format PDF :

 C_OBJECT($params)

 $params:=New object

 $params.format:=vk pdf format

 $params.sheetIndex:=-1

 $params.pdfOptions:=New object("title";"Rapport annuel";"author";Current user) 

 VP EXPORT DOCUMENT("VPArea";"report.pdf";$params)

Exemple 3

Vous souhaitez exporter un document 4D View Pro au format ".xlsx" et appeler une méthode qui lance Microsoft Excel avec le document ouvert une fois que l'export est terminé :

 $params:=New object

 $params.formula:=Formula(AfterExport)

 $params.format:=vk MS Excel format //".xlsx"

 $params.valuesOnly:=True

 

 VP EXPORT DOCUMENT("ViewProArea";"c:\\tmp\\convertedfile";$params)

Méthode AfterExport :

 C_TEXT($1;$2)

 C_OBJECT($3;$4)

 $areaName:=$1

 $filePath:=$2

 $params:=$3

 $status:=$4

 

 If($status.success=False)

    ALERT($status.errorMessage)

 Else

    LAUNCH EXTERNAL PROCESS("C:\\Program Files\\Microsoft Office\\Office15\\excel "+$filePath)

 End if

Voir aussi

VP Convert to picture
VP Export to object
VP IMPORT DOCUMENT
VP PRINT