VP EXPORT DOCUMENT

4D v19

VP EXPORT DOCUMENT


VP EXPORT DOCUMENT ( vpAreaName ; rotaArquivo {; paramObj} )

Parâmetro	Tipo	Descrição
vpAreaName	Texto	nome de objeto de área de formulário 4D View Pro
rotaArquivo	Texto	Rota do documento
paramObj	Objeto	Opções de Exportação

Descrição

O comando VP EXPORT DOCUMENT exporta o objeto 4D View Pro adjunto a área 4D View Pro vpAreaName a um documento em disco de acordo com o parâmetro rotaArquivo e paramObj.

Em vpAreaName, passe o nome da área 4D View Pro. Se passar um nome que não existir, se devolve um erro.

Em rotaArquivo, passe a rota de destino e o nome do documento a exportar.Pode especificar o formato do documento ao incluir sua extensão, 4D View Pro (".4VP") Microsoft Excel (".xlsx") ou PDF (".pdf"), depois do nome do documento. Se só passar o nome do documento, se guardará no mesmo nível que o arquivo de estrutura 4D com a extensão padrão ".4VP"

O parâmetro opcional paramObj permite que se defina múltiplas propriedades para o objeto exportado 4D View Pro, assim como lançar um método de chamada quando a exportação tiver sido completada.

Propriedade

Tipo

Descrição

format

text

(opcional) Quando presente, determina o formato de arquivo exportado: ".4vp" (padrão), ".xlsx", ou ".pdf". Pode passar uma constante do tema Constantes 4D View Pro no parâmetro formato. Neste caso, 4D adiciona a extensão apropriada para o nome de arquivo se necessário.

Os formatos a seguir são compatíveis:

Constante	Valor	Comentário
vk 4D View Pro format	.4VP	Formato 4D View Pro (formato padrão)
vk MS Excel format	.xlsx	Formato Microsoft Excel
vk pdf format	.pdf	Formato PDF

Se o formato especificado não corresponder com a extensão no filePath, será adicionado ao final do filePath. Se um formato não for especificado e nenhuma extensão for fornecida em filePath, o formato padrão de arquivo é usado.

password

text

Microsoft Excel apenas (opcional) - Senha usada para proteger o documento MS Excel

formula

object

Um método de callback a ser lançado quando a exportação estiver completa. O método de callback deve ser usado com o comando Formula. Veja abaixo para saber mais.

valuesOnly

boolean

Especifica que apenas os valores das fórmulas (se houver) serão exportados.

includeFormatInfo

boolean

True para incluir informação de formatação, senão false (padrão é true). Informação de formatação é útil em alguns casos, por exemplo para exportar SVG. Por outro lado, configurar essa propriedade como false permite reduzir o tempo de exportação.

sheetIndex

number

PDF apenas (opcional) - Indice de folha a exportar (iniciando do 0). -2=todas as folhas visíveis (padrão), -1=apenas folha atual

pdfOptions

object

PDF apenas (opcional) - Opções para exportar pdf

Propriedade	Tipo	Descrição
creator	text	nome da aplicação que criou o documento original do qual está convertendo.
title	text	titulo do documento.
autor	texto	nome da pessoa que criou o documento.
keywords	text	keywords associadas com o document.
tema	texto	tema do documento.

todas

Toda propriedade personalizada que estará disponível através do parâmetro $3 no método de retrochamada.

[#/table]

Nota sobre o formato de Excel: ao exportar um documento 4D View Pro a um arquivo com formato de Microsoft Excel, algumas configurações podem ser perdidas. Por exemplo, Excel não admite métodos e fórmulas 4D. Pode verificar outras configurações com esta lista de GrapeCity.
Exportar nesse formato é executado de forma assincrônica, use a propriedade fórmula de paramObj para que o código seja executado depois da exportação.

Nota sobre o formato PDF: ao exportar um documento 4D View Pro em PDF, as fontes utilizadas no documento são integradas automaticamente no arquivo PDF. Apenas podem ser integradas fontes OpenType (arquivos .OTF ou .TTF) que tenham um mapa Unicode. Se não for encontrado um arquivo de fonte válido para uma fonte, se utiliza uma fonte predeterminada.
Exportar nesse formato é executado de forma assincrônica, use a propriedade fórmula do paramObj para qu eo código seja executado depois da exportação.

Quando tiver finalizado a operação de exportação, VP EXPORT DOCUMENT ativa automaticamente a execução de método estabelecido na propriedade formula de paramObj, se for usado.

Passar um método de chamada

Quando incluir o parâmetro opcional paramObj, o comando VP EXPORT DOCUMENT permite que use o comando Formula para chamar um método 4D que vai ser executado assim que a exportação tenha terminado. O método de chamado vai receber os valores abaixo em variáveis locais.:

Variável		Tipo	Descrição
$1		text	O nome do objeto 4D View Pro
$2		text	A rota de arquivo do objeto 4D View Pro exportado
$3		object	Uma referência ao comando paramObj
$4		object	Um objeto retornado pelo método com um estado de mensagem
	.success	boolean	True se exportado com sucesso, senão False.
	.errorCode	integer	Código de Erro. Pode ser retornado por 4D ou JavaScript.
	.errorMessage	text	Mensagem de erro. Pode ser retornado por 4D ou JavaScript.

Exemplo 1

Se quiser exportar o conteúdo da área "VPArea" a um documento 4D View Pro no disco:

 C_TEXT($docPath)

 

 $docPath:="C:\\Bases\\ViewProDocs\\MyExport.4VP"

 VP EXPORT DOCUMENT("VPArea";$docPath)

  //MyExport.4VP é salvo no disco

Exemplo 2

Se quiser exportar a folha atual em PDF:

 C_OBJECT($params)

 $params:=New object

 $params.format:=vk pdf format

 $params.sheetIndex:=-1

 $params.pdfOptions:=New object("title";"Annual Report";"author";Current user)

 VP EXPORT DOCUMENT("VPArea";"report.pdf";$params)

Exemplo 3

Se quiser exportar um documento 4D View Pro em formato ".xlsx" e chamar um método que vai lançar Microsoft Excel com o documento aberto assim que a exportação termine:

 $params:=New object

 $params.formula:=Formula(AfterExport)

 $params.format:=vk MS Excel format //".xlsx"

 $params.valuesOnly:=True

 

 VP EXPORT DOCUMENT("ViewProArea";"c:\\tmp\\convertedfile";$params)

AfterExport método:

 C_TEXT($1;$2)

 C_OBJECT($3;$4)

 $areaName:=$1

 $filePath:=$2

 $params:=$3

 $status:=$4

 

 If($status.success=False)

    ALERT($status.errorMessage)

 Else

    LAUNCH EXTERNAL PROCESS("C:\\Program Files\\Microsoft Office\\Office15\\excel "+$filePath)

 End if

Ver também

VP Export to object
VP Convert to picture
VP IMPORT DOCUMENT
VP PRINT