VP SET SHEET OPTIONS

4D v19


VP SET SHEET OPTIONS ( vpAreaNome ; opcoesPlanilha {; folha} )

Parâmetro	Tipo	Descrição
vpAreaNome	String	Nome da área 4D View Pro
opcoesPlanilha	Objeto	Opções de planilha a estabelecer
folha	Inteiro longo	Indice planilha (planilha atual se omitido)

Descrição

O comando VP SET SHEET OPTIONS permite vários opções definidas da área vpAreaName.

Passe o nome da área 4D View Pro em vpAreaNome. Se passar um nome que não existir, um erro é retornado.

Passe um objeto contendo as definições para as opções a estabelecer no parâmetro opçõesPlanilha. Para ver a lista completa de opções disponíveis, veja 4D View Pro Sheet Options.

No parâmetro opcional folha, pode determinar uma planilha especifica (contagem começa em 0). Se omitido, a planilha atual é usada como padrão. Pode explicitamente selecionar planilha atual com a cosntante abaixo:

Constante	Valor	Comentário
vk current sheet	-1	Determina a folha atual de área 4D View Pro (padrão)

Exemplo 1

Para proteger todas as células exceto a faixa C5:D10:

  // Ativa proteção na planilha atual

 C_OBJECT($options)

 $options:=New object

 $options.isProtected:=True

 VP SET SHEET OPTIONS("ViewProArea";$options)

  // marca células C5:D10 como 'unlocked'

 VP SET CELL STYLE(VP Cells("ViewProArea";2;4;2;6);New object("locked";False))

Exemplo 2

É necessário proteger seu documento enquanto os usuários redimensionam linhas e colunas:

 C_OBJECT($options)

 $options:=New object

  // Ativa proteção

 $options.isProtected:=True

 $options.protectionOptions:=New object

  // Permite que o usuário redimensione linhas

 $options.protectionOptions.allowResizeRows=True;

  // Permite que o usuário redimensione colunas

 $options.protectionOptions.allowResizeColumns=True;

  // Aplica proteção para a planilha atual

 VP SET SHEET OPTIONS("ViewProArea";$options)

Exemplo 3

Se quiser personalizar as cores das abas da planilha, linhas congeladas, linhas da grade, seleção de fundo e borda da seleção:

 C_OBJECT($options)

 $options:=New object

  // Customize color of Sheet 1 tab

 $options.sheetTabColor:="Black"

 $options.gridline:=New object("color";"Purple")

 $options.selectionBackColor:="rgb(255,128,0,0.4)"

 $options.selectionBorderColor:="Yellow"

 $options.frozenlineColor:="Gold"

 VP SET SHEET OPTIONS("ViewProArea";$options;0)

 

  // Personalizar a cor de aba Sheet 2

 $options.sheetTabColor:="red"

 VP SET SHEET OPTIONS("ViewProArea";$options;1)

 

  // Personalizar a cor da aba Sheet 3

 $options.sheetTabColor:="blue"

 VP SET SHEET OPTIONS("ViewProArea";$options;2)

Resultado:

Exemplo 4

Se quiser esconder as linhas de grade assim como os cabeçalhos de linha e coluna

 C_OBJECT($options)

 $options:=New object

 $options.gridline:=New object()

 $options.gridline.showVerticalGridline:=False

 $options.gridline.showHorizontalGridline:=False

 $options.rowHeaderVisible:=False

 $options.colHeaderVisible:=False

 VP SET SHEET OPTIONS("ViewProArea";$options)

Aqui o resultado

Ver também

4D View Pro Sheet Options
VP Get sheet options