VP SET SHEET OPTIONS

4D v19


VP SET SHEET OPTIONS ( nomAreaVP ; opcionesHoja {; hoja} )

Parámetro	Tipo	Descripción
nomAreaVP	Cadena	Nombre del área 4D View Pro
opcionesHoja	Objeto	Opciones de hoja a configurar
hoja	Entero largo	Índice de hoja (hoja actual si se omite)

Descripción

El comando VP SET SHEET OPTIONS permite definir varias opciones aplicadas a una hoja del área nomAreaVP.

Pase el nombre del área 4D View Pro en nomAreaVP. Si pasa un nombre que no existe, se devuelve un error.

Pase un objeto que contenga definiciones para las opciones a definir en el parámetro opcionesHoja. Para ver la lista completa de las opciones disponibles, consulte Opciones hoja 4D View Pro.

En el parámetro opcional hoja, puede designar una hoja de cálculo específica (el conteo comienza en 0). Si se omite, la hoja de cálculo actual se utiiza de manera predeterminada. Puede seleccionar explícitamente la hoja de cálculo actual con la siguiente constante:

Constante	Valor	Comentario
vk current sheet	-1	Designa la hoja actual del área 4D View Pro (por defecto)

Ejemplo 1

Desea proteger todas las celdas excepto el rango C5:D10:

  // Activar protección en la hoja actual

 C_OBJECT($options)

 $options:=New object

 $options.isProtected:=True

 VP SET SHEET OPTIONS("ViewProArea";$options)

  // marca celdas C5:D10 como 'desbloqueadas'

 VP SET CELL STYLE(VP Cells("ViewProArea";2;4;2;6);New object("locked";False))

Ejemplo 2

Debe proteger su documento mientras sus usuarios pueden cambiar el tamaño de las líneas y columnas:

 C_OBJECT($options)

 $options:=New object

  // Activar protección

 $options.isProtected:=True

 $options.protectionOptions:=New object

  // Permitir al usuario cambiar el tamaño de las líneas

 $options.protectionOptions.allowResizeRows=True;

  // Permitir al usuario cambiar el tamaño de las columnas

 $options.protectionOptions.allowResizeColumns=True;

  // Aplicar protección en la hoja actual

 VP SET SHEET OPTIONS("ViewProArea";$options)

Ejemplo 3

Desea personalizar los colores de las pestañas, de las líneas congeladas, de las líneas de cuadrícula, del fondo de selección y del borde de selección:

 C_OBJECT($options)

 $options:=New object

  // Personaliza el color de la pestaña  de la hoja 1

 $options.sheetTabColor:="Black"

 $options.gridline:=New object("color";"Purple")

 $options.selectionBackColor:="rgb(255,128,0,0.4)"

 $options.selectionBorderColor:="Yellow"

 $options.frozenlineColor:="Gold"

 VP SET SHEET OPTIONS("ViewProArea";$options;0)

 

  // Personaliza el color de la pestaña de la hoja 2

 $options.sheetTabColor:="red"

 VP SET SHEET OPTIONS("ViewProArea";$options;1)

 

  // Personaliza el color de la pestaña de la hoja 3

 $options.sheetTabColor:="blue"

 VP SET SHEET OPTIONS("ViewProArea";$options;2)

Resultado:

Ejemplo 4

Desea ocultar las líneas de cuadrícula, así como los encabezados de línea y columna.

 C_OBJECT($options)

 $options:=New object

 $options.gridline:=New object()

 $options.gridline.showVerticalGridline:=False

 $options.gridline.showHorizontalGridline:=False

 $options.rowHeaderVisible:=False

 $options.colHeaderVisible:=False

 VP SET SHEET OPTIONS("ViewProArea";$options)

El resultado es el siguiente:

Ver también

Opciones hoja 4D View Pro
VP Get sheet options