VP SET CUSTOM FUNCTIONS

4D v19


VP SET CUSTOM FUNCTIONS ( vp ; objFormula )

Parámetro	Tipo	Descripción
vp	Texto	Nombre del área 4D View Pro en el formulario
objFormula	Objeto	Objeto Fórmula

Descripción

El comando VP SET CUSTOM FUNCTIONS designa las fórmulas 4D que se pueden llamar directamente desde las fórmulas 4D View Pro. Como las funciones personalizadas no se almacenan en el documento, VP SET CUSTOM FUNCTIONS debe ejecutarse en el evento formulario On Load .

Las fórmulas especificadas por VP SET CUSTOM FUNCTIONS aparecen en un menú emergente cuando se ingresa la primera letra de su nombre. Ver Entrada de una fórmula, de una función o de una referencia.

Nota: si se llama a VP SET CUSTOM FUNCTIONS varias veces para la misma área, en la misma sesión, solo se tiene en cuenta la última llamada.

Pase el nombre del área 4D View Pro en vpAreaName. Si pasa un nombre que no existe, se devuelve un error.

En el parámetro objFormula, pase un objeto que contenga las fórmulas 4D que se pueden llamar desde fórmulas 4D View Pro, así también las propiedades adicionales. Cada propiedad customFunction pasada en objFormula se convierte en el nombre de una función en el área 4D View Pro.

Propiedad

Tipo

Descripción

<customFunction>

Objeto

Funciones personalizadas de objetos para definir en 4D View Pro

formula

Objeto

Objeto fórmula 4D (obligatorio). Ver Formula

parameters

Colección de objetos

Colección de parámetros (en el orden en que están definidos en la fórmula)

[ ].name

Texto

Nombre del parámetro a mostrar en 4D View Pro

[ ].type

Número

Tipo de parámetro. Tipos soportados:

Constante
Is Boolean
Is date
Is longint
Is object
Is real
Is text
Is time

Si se omite tipo o si se pasa el valor predeterminado (-1), el valor se envía automáticamente con su tipo, excepto los valores de fecha u hora que se envían como un objeto (ver la sección Parámetros).

Si tipo es Is object, el objeto tiene la misma estructura que el objeto devuelto por VP Get value.

summary

Texto

Descripción de la fórmula de texto para mostrar en 4D View Pro

minParams

Número

Número mínimo de parámetros

maxParams

Número

Número máximo de parámetros. Pasar un número mayor que la longitud de los parametros permite declarar parámetros "opcionales" con el tipo por defecto

ATENCIÓN

Si una formula tiene el mismo nombre que una función definida por el comando VP SET ALLOWED METHODS, se crea la formula y se ignora el método.
Tan pronto como se llama VP SET CUSTOM FUNCTIONS, los métodos permitidos por SET ALLOWED METHODS se ignoran en el área 4D View Pro.
Tan pronto como se llama VP SET CUSTOM FUNCTIONS, las funciones basadas en los comandos SET TABLE TITLES y SET FIELD TITLES se ignoran en el área 4D View Pro.

Ejemplo

Quiere utilizar los objetos Fórmula en un área 4D View Pro para añadir números, recuperar el apellido y el sexo de un cliente:

 Case of

    :(Form event code=On Load)

 

       var $o : Object

 

       $o:=New object

 

  // Definir la función “addnum“ de un método llamado "addnum"

       $o.addnum:=New object

       $o.addnum.formula:=Formula(addnum)

       $o.addnum.parameters:=New collection

       $o.addnum.parameters.push(New object("name";"num1";"type";Is longint))

       $o.addnum.parameters.push(New object("name";"num2";"type";Is longint))

 

  // Definir la función “ClientLastName“ de un campo de base de datos

       $o.ClientLastName:=New object

       $o.ClientLastName.formula:=Formula([Customers]lastname)

       $o.ClientLastName.summary:="Lastname of the current client"

 

  // Definir la función “label“ de una expresión 4D con un parámetro

       $o.label:=New object

       $o.label.formula:=Formula(ds.Customers.get($1).label)

       $o.label.parameters:=New collection

       $o.label.parameters.push(New object("name";"ID";"type";Is longint))

 

  // Definir la función “Title“ de una variable llamada "Title"

       $o.Title:=New object

       $o.Title.formula:=Formula(Title)

 

       VP SET CUSTOM FUNCTIONS("ViewProArea";$o)

 

 end case

Ver también

Referencias de campo
Referencias método proyecto
VP SET ALLOWED METHODS