VP SET CUSTOM FUNCTIONS

4D v19


VP SET CUSTOM FUNCTIONS ( vpAreaNome ; formulaObj )

Parâmetro	Tipo	Descrição
vpAreaNome	Texto	nome do objeto área formulário 4D View Pro
formulaObj	Objeto	Objeto fórmula

Descrição

O comando VP SET CUSTOM FUNCTIONS determina as fórmulas 4D que podem ser chamadas diretamente de fórmulas 4D View Pro. Como funções personalizadas não são armazenadas no documento, VP SET CUSTOM FUNCTIONS deve ser executado em evento formulárioOn Load .

As fórmulas especificadas por VP SET CUSTOM FUNCTIONS aparece em um menu pop up quando a primeira letra do nome é digitada. Ver Digitar uma Fórmula, Função ou uma Referência.

Nota: Se VP SET CUSTOM FUNCTIONS for chamado múltiplas vezes para a mesma área, na mesma sessão, só a última chamada é levada em consideração.

Passe o nome da área 4D View Pro em vpAreaNome. Se passar um nome que não existir, um erro é retornado.

No parâmetro formulaObj, passar um objeto contendo as fórmulas 4D que podem ser chamadas das fórmulas 4D View Pro, assim como propriedades adicionais. Cada funçãoPersonalizada passada em formulaObj vira o nome da função na área 4D View Pro.

Propriedade

Tipo

Descrição

<customFunction>

Object

Funções personalizadas para definir em 4D View Pro

formula

Object

Objeto 4D formula (obrigatório). Ver Formula

parameters

Collection of objects

Coleção de parâmetros (na ordem que são definidos na fórmula)

[ ].name

Text

Nome de parâmetros a exibir em 4D View Pro

[ ].type

Number

Tipo de parâmetros. Tipos aceitos:

Constante
Is Boolean
Is date
Is longint
Is object
Is real
Is text
Is time

Se tipo for omitido ou se o valor padrão (-1) for passado, o valor é automaticamente enviado com seu tipo, exceto valores data ou hora que são enviados como um objeto (ver Parâmetros).

Se tipo for Is object, o objeto tem a mesma estrutura que o objeto retornado por VP Get value.

summary

Text

Descrição de Fórmula a exibir em 4D View Pro

minParams

Number

Número mínimo de Parâmetros

maxParams

Number

Número máximo de parâmetros. Passar um número maior que o tamanho que parametros permite declar parâmetros "opcional" com o tipo normal.

AVISO

Se um formula tem o mesmo nome que uma função definida pelo comando VP SET ALLOWED METHODS, a fórmula é criada e o método ignorado.
Assim que VP SET CUSTOM FUNCTIONS for chamado, os métodos permitidos por SET ALLOWED METHODS são ignorados na área 4D View Pro.
Assim que VP SET CUSTOM FUNCTIONS for chamada, as funções baseadas nos comandos SET TABLE TITLES e SET FIELD TITLES são ignorados na áread 4D View Pro.

Exemplo

Se quiser usasr objetos fórmula em uma área 4D View Pro para adicionar números, encontrar o sobrenome e gênero de um cliente:

 Case of

    :(Form event code=On Load)

 

       var $o : Object

 

       $o:=New object

 

  // Define a função “addnum“ de um método chamado "addnum"

       $o.addnum:=New object

       $o.addnum.formula:=Formula(addnum)

       $o.addnum.parameters:=New collection

       $o.addnum.parameters.push(New object("name";"num1";"type";Is longint))

       $o.addnum.parameters.push(New object("name";"num2";"type";Is longint))

 

  // Define a função “ClientLastName“ de um campo database

       $o.ClientLastName:=New object

       $o.ClientLastName.formula:=Formula([Customers]lastname)

       $o.ClientLastName.summary:="Lastname of the current client"

 

  // Define a função etiqueta “label“ a partir de uma expressão 4D com um parâmetro

       $o.label:=New object

       $o.label.formula:=Formula(ds.Customers.get($1).label)

       $o.label.parameters:=New collection

       $o.label.parameters.push(New object("name";"ID";"type";Is longint))

 

  // Define a função “Title“ a partir de uma variável chamada "Title"

       $o.Title:=New object

       $o.Title.formula:=Formula(Title)

 

       VP SET CUSTOM FUNCTIONS("ViewProArea";$o)

 

 end case

Ver também

Field references
Project method references
VP SET ALLOWED METHODS