VP SET CUSTOM FUNCTIONS

Home

4D v19


VP SET CUSTOM FUNCTIONS ( vpAreaName ; formulaObj )

Parameter	Typ	Beschreibung
vpAreaName	Text	Name des Formularobjekts 4D View Pro Area
formulaObj	Objekt	Objekt Formel

Beschreibung

Der Befehl VP SET CUSTOM FUNCTIONS gibt die 4D Formeln an, die sich direkt aus 4D View Pro Formeln aufrufen lassen. Da eigene Funktionen nicht im Dokument gespeichert werden, muss VP SET CUSTOM FUNCTIONS im Formularereignis On Load ausgeführt werden.

Die von VP SET CUSTOM FUNCTIONS angegebenen Formeln erscheinen in einem PopUp Menü, wenn der erste Buchstabe des Namens eingegeben wird. Weitere Informationen dazu finden Sie im Abschnitt Eine Formel, Funktion oder Referenz eingeben.

Hinweis: Wird VP SET CUSTOM FUNCTIONS während derselben Arbeitssitzung mehrmals für den gleichen Bereich aufgerufen, wird nur der letzte Aufruf berücksichtigt.

In vpAreaName übergeben Sie den Namen des 4D View Pro Bereichs. Existiert der übergebene Name nicht, wird ein Fehler zurückgegeben.

Im Parameter formulaObj übergeben Sie ein Objekt mit den 4D Formeln, die sich aus 4D View Pro Formeln aufrufen lassen, sowie zusätzliche Eigenschaften. Jede in formulaObj übergebene Eigenschaft customFunction wird zum Namen einer Funktion im 4D View Pro Bereich.

Eigenschaft

Typ

Beschreibung

<customFunction>

Objekt

Eigene Funktionen zum Definieren in 4D View Pro

formula

Objekt

4D Objekt Formel (zwingend). Siehe unter Formula

parameters

Collection der Objekte

Collection der Parameter (in der Reihenfolge, wie sie in der Formel definiert sind)

[ ].name

Text

Parametername zum Anzeigen in 4D View Pro

[ ].type

Zahl

Parametertyp. Unterstützte Typen:

Konstante
Is Boolean
Is date
Is longint
Is object
Is real
Is text
Is time

Ohne Angabe oder bei Standardwert (-1) wird automatisch der Wert mit seinem Typ gesendet, außer bei Datums- und Zeitwerten, die als Objekt gesendet werden (siehe Abschnitt Parameter).
Beim Typ Is object hat das Objekt dieselbe Struktur wie das von VP Get value zurückgegebene Objekt.

summary

Text

Formelbeschreibung zur Anzeige in 4D View Pro

minParams

Zahl

Min. Anzahl der Parameter

maxParams

Zahl

Max. Anzahl der Parameter. Bei Angabe einer Zahl höher als die Länge von parameters lassen sich "optionale" Parameter mit Standardtyp deklarieren.

WARNUNG

Hat eine formula denselben Namen wie eine über den Befehl VP SET ALLOWED METHODS definierte Funktion, wird formula erstellt und die Methode ignoriert.
Bei Aufruf von VP SET CUSTOM FUNCTIONS werden die über SET ALLOWED METHODS zugelassenen Methoden im 4D View Pro Bereich ignoriert.
Bei Aufruf von VP SET CUSTOM FUNCTIONS werden auf den Befehlen SET TABLE TITLES und SET FIELD TITLES basierende Funktionen im 4D View Pro Bereich ignoriert.

Beispiel

In einem 4D View Pro Bereich über Formel Objekte Nummern hinzufügen, Nachname und Anrede eines Kunden aufrufen:

 Case of

    :(Form event code=On Load)

 

       var $o : Object

 

       $o:=New object

 

  // Define “addnum“ function from a method named "addnum"

       $o.addnum:=New object

       $o.addnum.formula:=Formula(addnum)

       $o.addnum.parameters:=New collection

       $o.addnum.parameters.push(New object("name";"num1";"type";Is longint))

       $o.addnum.parameters.push(New object("name";"num2";"type";Is longint))

 

  // Define “ClientLastName“ function from a database field

       $o.ClientLastName:=New object

       $o.ClientLastName.formula:=Formula([Customers]lastname)

       $o.ClientLastName.summary:="Lastname of the current client"

 

  // Define “label“ function from a 4D expression with one parameter

       $o.label:=New object

       $o.label.formula:=Formula(ds.Customers.get($1).label)

       $o.label.parameters:=New collection

       $o.label.parameters.push(New object("name";"ID";"type";Is longint))

 

  // Define “Title“ function from a variable named "Title"

       $o.Title:=New object

       $o.Title.formula:=Formula(Title)

 

       VP SET CUSTOM FUNCTIONS("ViewProArea";$o)

 

 end case

Siehe auch

Feldreferenzen
Referenzen auf Projektmethoden
VP SET ALLOWED METHODS