VP SET PRINT INFO

Home

4D v19

VP SET PRINT INFO


VP SET PRINT INFO ( vpAreaName ; printInfo {; sheet} )

Parameter	Typ	Beschreibung
vpAreaName	Text	Name des 4D View Pro Bereichs
printInfo	Objekt	Objekt mit den Druckattributen
sheet	Lange Ganzzahl	Nummer des Arbeitsblatts (ohne Angabe aktuelles Arbeitsblatt)

Beschreibung

Der Befehl VP SET PRINT INFO definiert die Attribute zum Drucken von vpAreaName..

In vpAreaName übergeben Sie den Namen des 4D View Pro Bereichs zum Drucken. Existiert der Name nicht, wird ein Fehler zurückgegeben.

Im Parameter printInfo können Sie ein Objekt mit Definitionen verschiedener Druckattribute übergeben. Die komplette Liste der verfügbaren Attribute finden Sie unter 4D View Pro Druckattribute.

Im optionalen Parameter sheet können Sie ein bestimmtes Arbeitsblatt zum Drucken übergeben (die Zählung beginnt bei 0). Ohne Angaben wird das aktuelle Arbeitsblatt verwendet. Mit folgender Konstante können Sie explizit das aktuelle Arbeitsblatt auswählen:

Konstante	Typ	Wert	Kommentar
vk current sheet	Lange Ganzzahl	-1	Bestimmt das aktuelle Arbeitsblatt des 4D View Pro Bereichs (Standard)

Beispiel

Der folgende Code druckt einen 4D View Pro Bereich in ein PDF Dokument:

C_OBJECT($printInfo)

//Objekt der Druckattribute deklarieren
$printInfo:=New object

//Druckattribute definieren
$printInfo.headerCenter:="&BS.H.I.E.L.D. &A Sales Per Region"
$printInfo.firstPageNumber:=1
$printInfo.footerRight:="page &P of &N"
$printInfo.orientation:=vk print page orientation landscape
$printInfo.centering:=vk print centering horizontal
$printInfo.columnStart:=0
$printInfo.columnEnd:=8
$printInfo.rowStart:=0
$printInfo.rowEnd:=24
$printInfo.showGridLine:=True

//Firmenlogo hinzufügen
$printInfo.headerLeftImage:=logo.png
$printInfo.headerLeft:="&G"

$printInfo.showRowHeader:=vk print visibility hide
$printInfo.showColumnHeader:=vk print visibility hide
$printInfo.fitPagesWide:=1
$printInfo.fitPagesTall:=1

//PDF Dokument drucken
VP SET PRINT INFO ("ViewProArea";$printInfo)

//PDF exportieren
VP EXPORT DOCUMENT("ViewProArea";"Sales2018.pdf";new object("formula";formula(alert("PDF ready!"))))

Das PDF sieht folgendermaßen aus:

Siehe auch

4D View Pro Druckattribute
VP Convert to picture
VP Get print info
VP PRINT